pl/sql stored update procedure in oracle apex - oracle

Question

I observed some really weird update problem with my pl/sql stored procedure here's the code:
create or replace procedure "UPDATECURRENTOFFICE"
(trans_pk IN NUMBER,
office_pk IN NUMBER)
is
BEGIN
UPDATE TRANSACTION
SET TRANSACTION.OFFICE_PK_CURRENT = office_pk
WHERE TRANSACTION.TRANS_PK = trans_pk;
end;​
it ends up updating every record in the table instead of just only one record. im using this pl/sql procedure inside a process with a process point of submit - after computations and validation.. Im new with apex, and I find it really hard making online systems with it. please help me T.T

Answer 1

Change the parameter name.
The sql parser inside PL/SQL for the query
UPDATE TRANSACTION
SET TRANSACTION.OFFICE_PK_CURRENT = office_pk
WHERE TRANSACTION.TRANS_PK = trans_pk;
recognizes trans_pk as the column trans_pk not the pl/sql variable. So the WHERE condition is read as WHERE TRANS_PK=TRANS_PK witch means WHERE TRANS_PK IS NOT NULL
The following should work
create or replace procedure "UPDATECURRENTOFFICE"
(inp_trans_pk IN NUMBER,
office_pk IN NUMBER)
is
BEGIN
UPDATE TRANSACTION
SET TRANSACTION.OFFICE_PK_CURRENT = office_pk
WHERE TRANSACTION.TRANS_PK = inp_trans_pk;
end;​

Answer 2

The problem here is that you have a column in your table and a parameter to your stored procedure both called TRANS_PK. You may have written your parameter trans_pk, but in Oracle, identifiers (such as parameter names) are case-insensitive.
It happens that in your query, the name trans_pk is recognised as a column name rather than a parameter name. So your query will update every row where the TRANS_PK value equals the TRANS_PK value. This will be every row in the table, unless there are any rows where TRANS_PK is not NULL. However, given the name of this column I suspect it's part of the primary key of the TRANSACTION table and so won't contain any NULL values.
If you use a prefix for function/procedure parameter names, such as p_, this problem goes away. Here's a fixed version of your stored procedure:
create or replace procedure "UPDATECURRENTOFFICE"
(p_trans_pk IN NUMBER,
p_office_pk IN NUMBER)
is
BEGIN
UPDATE TRANSACTION
SET TRANSACTION.OFFICE_PK_CURRENT = p_office_pk
WHERE TRANSACTION.TRANS_PK = p_trans_pk;
end;​

Answer 3

You could rename the parameter, but best practice is to always use aliases when using SQL in PL/SQL, e.g.:
create or replace procedure "UPDATECURRENTOFFICE"
(trans_pk IN NUMBER,
office_pk IN NUMBER)
is
BEGIN
UPDATE TRANSACTION
SET TRANSACTION.OFFICE_PK_CURRENT = UPDATECURRENTOFFICE.office_pk
WHERE TRANSACTION.TRANS_PK = UPDATECURRENTOFFICE.trans_pk;
end;​
This code is resilient to unexpected changes to the table structure.