Using variable as a label control name - vb6

Question

In VB 6 How can I refer to control label using a variable instead of a fixed name such as LUH01 (as below) which does not allow a Loop.
Frm_Dispo_Prof_Grille.LUH01.BackColor = &HFF00&

Answer 1

You can refer to it via the Controls Collection:
Frm_Dispo_Prof_Grille.Controls("LUH01").BackColor = &HFF00&
Be careful, however. If you need to refer to a property/method that is not one of the standard/built-in ones, you'll have to cast the control to a type:
Dim lbl as Label
Set lbl = Frm_Dispo_Prof_Grille.Controls("LUH01")
lbl.BackColor = &HFF00

Answer 2

I think you want to create a control array
You can do that by creating 1 control, and set its Index property to 0 (instead of empty)
You can then Load new controls and use them all in a loop
For example to load some command buttons and position them in a loop:
'1 form with :
' 1 command button: name=Command1 index=0
'Number of command buttons to use in the loop
Private Const NRBUTTONS As Integer = 5
Option Explicit
Private Sub Form_Load()
Dim intIndex As Integer
'change the caption of the default button
Command1(0).Caption = "Button 0"
For intIndex = 1 To NRBUTTONS - 1
'load an extra command button
Load Command1(intIndex)
'change the caption of the newly loaded button
Command1(intIndex).Caption = "Button " & CStr(intIndex)
'newly load command buttons are invisible by deafult
'make the new command button visible
Command1(intIndex).Visible = True
Next intIndex
End Sub
Private Sub Form_Resize()
'arrange all loaded command buttons via a loop
Dim intIndex As Integer
Dim sngWidth As Single
Dim sngHeight As Single
sngWidth = ScaleWidth
sngHeight = ScaleHeight / NRBUTTONS
For intIndex = 0 To NRBUTTONS - 1
Command1(intIndex).Move 0, intIndex * sngHeight, sngWidth, sngHeight
Next intIndex
End Sub