How to click a button that's only visible when hovered over? - macos

Question

I'm tinkering with an applescript that would clear notifications from Notification Center. At this point cannot figure out a way to click the clear button.
You see, the button only appears if cursor is hovering on the row of the app, or rows below that belongs to this app. I do:
tell application "System Events" to tell process "SystemUIServer" ¬
to click menu bar item "Notification Center" of menu bar 2
tell application "System Events" to tell process "Notification Center" ¬
to value of attribute "AXChildren" of UI element 1 of row 2 of table 1 of ¬
scroll area 1 of window "NotificationTableWindow"
Result:
{static text "iTunes" of UI element "iTunes" of row 2 of table 1 of ¬
scroll area 1 of window "NotificationTableWindow" of application process ¬
"NotificationCenter" of application "System Events"}
But if I strategically place the cursor beforehand, I get:
{static text "iTunes" of (ditto), button 1 of (ditto)}
button 1 is what I'm searching for. So far I tried three ways that didn't work out, listed from dumb to less dumb:
1) Keyboard Navigation
I tried to navigate down the list with key code 125. This doesn't make the button visible. While there, I tried a myriad of Delete combos. Nothing seems to delete notification entries.
2) click at (x,y) from System Events
On a 1280x800 screen, the button has an AXFrame of:
{x=1256.00 y=77.00 w=16.00 h=16.00}
which gives it a center of {1264, 85}, so:
tell application "System Events" to tell process "Notification Center"
click at {1264, 85}
value of attribute "AXChildren" of UI element 1 of row 2 of table 1 of ¬
scroll area 1 of window "NotificationTableWindow"
end tell
This, unsurprisingly, doesn't work.
3) select from System Events
tell application "System Events" to tell process "Notification Center" to ¬
tell window "NotificationTableWindow" to tell scroll area 1 to tell table 1 ¬
to tell row 2
select UI element 1
value of attribute "AXChildren" of UI element 1
end tell
Still, I only get static text 1 that is the app name. button 1 that is the clear button is nowhere to be found.
Does anyone know how to click this button - a button that only appears when hovered over?

Answer 1

I can't answer your question (the GUI Scripting, I'm not on Yosemite), but :
To clear all notifications (works on Maverick, I don't know on Yosemite), this script delete notifications from the database in "~/Library/Application Support/NotificationCenter" folder :
set notifCenterFolder to (path to application support from user domain as text) & "NotificationCenter:"
tell application "System Events" to set tDB to POSIX path of (first file of folder notifCenterFolder whose name extension is "db")
do shell script "/usr/bin/sqlite3 " & (quoted form of tDB) & " 'DELETE FROM notifications' && osascript -e 'quit application \"NotificationCenter\" ' && killall usernoted"
--
To clear notifications for a specific application (iTunes as example):
set iTunesPath to "/Applications/iTunes.app"
set notifCenterFolder to (path to application support from user domain as text) & "NotificationCenter:"
tell application "System Events" to set tDB to POSIX path of (first file of folder notifCenterFolder whose name extension is "db")
do shell script "/usr/bin/sqlite3 " & (quoted form of tDB) & " 'delete FROM notifications where app_id = (select app_id FROM app_source where last_known_path = \"" & iTunesPath & "\")' && osascript -e 'quit application \"NotificationCenter\" ' && killall usernoted"
--
On Yosemite, this file is in another folder --> /var/folder/... see this answer
Use this AppleScript on Yosemite :
do shell script "cd `getconf DARWIN_USER_DIR`com.apple.notificationcenter/db/ && /usr/bin/sqlite3 db 'DELETE FROM notifications' && osascript -e 'quit application \"NotificationCenter\" ' && killall usernoted"