How to print Ada.Real_Time.Time variable - time

Question

How to print Ada.Real_Time.Time variable?
procedure Main is
test : TValue :=
(value => 0.7,
timeStamp => Clock,
status => (Valid => False, Unknown => True)
);
begin
-- print of Test.value
Put(Item => Test.value ,Fore => 5, Aft => 3, Exp => 0);
-- here I want a print of timestamp
end Main;
I want to print timeStamp to console, how to do it? I tried to convert it to String or Integer, but with no success

Answer 1

The important section to read is LRM D.8, which defines package Ada.Real_Time. Specifically it is worth noting paragraph 19, which says that the epoch is not specified by the language. This means that for printing Ada.Real_Time.Time variables, you have to define an epoch yourself. One such epoch could be the starting time of the application you are testing:
with Ada.Real_Time;
package Real_Time_IO is
...
private
Epoch : constant Ada.Real_Time.Time := Ada.Real_Time.Clock;
end Real_Time_IO;
Now you can calculate time spans since the application started:
package body Real_Time_IO is
function Since_Start return Ada.Real_Time.Time_Span is
begin
return Ada.Real_Time.Clock - Epoch;
end Since_Start;
...
If we only need to use this package up to 24 hours after application start, we can be lazy and just convert the Since_Start result to the type Duration, and then to a string:
function Since_Start return Duration is
begin
return Ada.Real_Time.To_Duration (Since_Start);
end Since_Start;
function Since_Start return String is
begin
return Duration'Image (Since_Start);
end Since_Start;
... and I hope you know how to print strings. :-)

Answer 2

After some research, here is a short example of how to print a Real_Time.Time
with Ada.Real_Time; use Ada.Real_Time;
with Ada.Calendar;
with Ada.Calendar.Formatting;
with Ada.Text_IO; use Ada.Text_IO;
procedure PrintRT is
The_Clock : Ada.Real_Time.Time := Ada.Real_Time.Clock;
-- Convert to Time_Span
As_Time_Span : Ada.Real_Time.Time_Span := The_Clock - Time_Of(0, Time_Span_Zero);
-- Epoch ?
Epoch : constant Ada.Calendar.Time := Ada.Calendar.Time_Of(1970, 01, 01);
Dur : Duration := Ada.Real_Time.To_Duration(As_Time_Span);
begin
Put_Line(Ada.Calendar.Formatting.Image(Ada.Calendar."+"(Epoch, Dur)));
end PrintRT;
The only way to get a Time_Span is to use the "-" operator between two times.
As Seconds_Count represents the number of seconds from the Epoch, you can build a Time from it using Time_Of.
Then converting it to duration allows you to find the correct date.

Answer 3

There’s no conversion between Real_Time.Time and Calendar.Time because Real_Time is monotonically increasing (until it overflows, of course; you should be able to expect at least 50 years’ worth, ARM D.8(30)) while Calendar may be affected by daylight savings, NTP updates etc.
Would Ada.Real_Time.Delays.To_Duration help? (this is a non-standard GNAT package).
I tried
function To_Duration (T : Ada.Real_Time.Time) return Duration is
use type Ada.Real_Time.Time;
begin
return Ada.Real_Time.To_Duration (T - Ada.Real_Time.Time_First);
end To_Duration;
but it failed (Mac OS X, desktop; might well work better over an RTOS) with
raised CONSTRAINT_ERROR : a-reatim.adb:94 overflow check failed
Failing that, you could use Unchecked_Conversion to some unsigned type of the same size as Real_Time.Time.