I can't seem to find the solution to my problem, I've been stuck at this for hours.
I'm usings Oracle AQs:
Dbms_Aqadm.Create_Queue_Table(Queue_Table => 'ITEM_EVENT_QT',
Queue_Payload_Type => 'ITEM_EVENT',
Multiple_Consumers => TRUE);
Dbms_Aqadm.Create_Queue(Queue_Name => 'ITEM_EVENT_QUEUE',
Queue_Table => 'ITEM_EVENT_QT',
Max_Retries => 5,
Retry_Delay => 0,
Retention_Time => 432000, -- 5 DAYS
Dependency_Tracking => FALSE,
COMMENT => 'Item Event Queue');
-- START THE QUEUE
Dbms_Aqadm.Start_Queue('ITEM_EVENT_QUEUE');
-- GRANT QUEUE PRIVILEGES
Dbms_Aqadm.Grant_Queue_Privilege(Privilege => 'ALL',
Queue_Name => 'ITEM_EVENT_QUEUE',
Grantee => 'PUBLIC',
Grant_Option => FALSE);
END;
Here's one of my subscribers:
Dbms_Aqadm.Add_Subscriber(Queue_Name => 'ITEM_EVENT_QUEUE',
Subscriber => Sys.Aq$_Agent('ITEM_SUBSCRIBER_1',
NULL,
NULL),
rule => 'tab.user_data.header.thread_no = 1');
Dbms_Aq.Register(Sys.Aq$_Reg_Info_List(Sys.Aq$_Reg_Info('ITEM_EVENT_QUEUE:ITEM_SUBSCRIBER_1',
Dbms_Aq.Namespace_Aq,
'plsql://ITEM_API.GET_QUEUE_FROM_QUEUE',
HEXTORAW('FF'))),1);
The subscriber registration:
Whenever a certain event occurs on my DB, I'm using a trigger to add "the event" to my AQ by calling the following procedure from my ITEM_API package:
PROCEDURE ADD_EVENT_TO_QUEUE(I_EVENT IN ITEM_EVENT,
O_STATUS_CODE OUT VARCHAR2,
O_ERROR_MSG OUT VARCHAR2) IS
ENQUEUE_OPTIONS DBMS_AQ.ENQUEUE_OPTIONS_T;
MESSAGE_PROPERTIES DBMS_AQ.MESSAGE_PROPERTIES_T;
MESSAGE_HANDLE RAW(16);
EVENT ITEM_EVENT;
HEADER_PROP HEADER_PROPERTIES;
BEGIN
EVENT := I_EVENT;
EVENT.SEQ_NO := ITEM_EVENT_SEQ.NEXTVAL;
ENQUEUE_OPTIONS.VISIBILITY := DBMS_AQ.ON_COMMIT;
ENQUEUE_OPTIONS.SEQUENCE_DEVIATION := NULL;
MESSAGE_PROPERTIES.PRIORITY := 1;
MESSAGE_PROPERTIES.DELAY := DBMS_AQ.NO_DELAY;
MESSAGE_PROPERTIES.EXPIRATION := DBMS_AQ.NEVER;
HEADER_PROP := HEADER_PROPERTIES(1);
EVENT.HEADER := HEADER_PROP;
DBMS_AQ.ENQUEUE(QUEUE_NAME => 'ITEM_EVENT_QUEUE',
ENQUEUE_OPTIONS => ENQUEUE_OPTIONS,
MESSAGE_PROPERTIES => MESSAGE_PROPERTIES,
PAYLOAD => EVENT,
MSGID => MESSAGE_HANDLE);
EXCEPTION
WHEN OTHERS THEN
ERROR_HANDLER.LOG_ERROR(NULL,
EVENT.ITEM,
EVENT.SEQ_NO,
SQLCODE,
SQLERRM,
O_STATUS_CODE,
O_ERROR_MSG);
RAISE;
END ADD_EVENT_TO_QUEUE;
And it's working because when I check my AQ table, I can find "the event", however my dequeue method is not dequeing, as you can see in the image bellow, there's no DEQ_TIME.
Here's my dequeue method, also from my ITEM_API package:
PROCEDURE GET_QUEUE_FROM_QUEUE(CONTEXT RAW,
REGINFO SYS.AQ$_REG_INFO,
DESCR SYS.AQ$_DESCRIPTOR,
PAYLOAD RAW,
PAYLOADL NUMBER) IS
R_DEQUEUE_OPTIONS DBMS_AQ.DEQUEUE_OPTIONS_T;
R_MESSAGE_PROPERTIES DBMS_AQ.MESSAGE_PROPERTIES_T;
V_MESSAGE_HANDLE RAW(16);
I_PAYLOAD ITEM_EVENT;
L_PROC_EVENT BOOLEAN;
O_TARGETS CFG_EVENT_STAGE_TBL;
O_ERROR_MSG VARCHAR2(300);
O_STATUS_CODE VARCHAR2(100);
BEGIN
R_DEQUEUE_OPTIONS.MSGID := DESCR.MSG_ID;
R_DEQUEUE_OPTIONS.CONSUMER_NAME := DESCR.CONSUMER_NAME;
R_DEQUEUE_OPTIONS.DEQUEUE_MODE := DBMS_AQ.REMOVE;
--R_DEQUEUE_OPTIONS.WAIT := DBMS_AQ.NO_WAIT;
DBMS_AQ.DEQUEUE(QUEUE_NAME => DESCR.QUEUE_NAME,
DEQUEUE_OPTIONS => R_DEQUEUE_OPTIONS,
MESSAGE_PROPERTIES => R_MESSAGE_PROPERTIES,
PAYLOAD => I_PAYLOAD,
MSGID => V_MESSAGE_HANDLE);
IF I_PAYLOAD IS NOT NULL THEN
L_PROC_EVENT := PROCESS_EVENT(I_PAYLOAD,
O_TARGETS,
O_STATUS_CODE,
O_ERROR_MSG);
END IF;
EXCEPTION
WHEN OTHERS THEN
ERROR_HANDLER.LOG_ERROR(NULL,
NULL,
NULL,
SQLCODE,
SQLERRM,
O_STATUS_CODE,
O_ERROR_MSG);
RAISE;
END GET_QUEUE_FROM_QUEUE;
Am I doing something wrong? How can I fix this? I think there might be a problem with my subscriber registration, but I'm not sure.
EDIT: I've just figured out that if I remove the subscribers and the register, and then re-add them, they'll dequeue all messages. Howerver if another event gets enqueued, it stays there indefinetly (or until I remove and add the subscribers again):
The record with state 0 and no DEQ_TIME is the new one.
Do I need a scheduler or something like that?
EDIT: I've added a scheduler propagation to my AQ:
DBMS_AQADM.SCHEDULE_PROPAGATION('ITEM_EVENT_QUEUE');
and even added the next_time field:
DBMS_AQADM.SCHEDULE_PROPAGATION('ITEM_EVENT_QUEUE', SYSDATE + 30/86400);
Still doesn't work. Any suggestions? I guess the AQ Notifications aren't working, and my callback procedure is never called. How can I fix this?
EDIT: I've removed my procedure from the package just for testing purposes, so my team mates can compile the ITEM_API package (I don't know if recompiling the package, may or may not have impacts on the dequeue process).
Still doesn't work.
Create a code block and run the following:
DECLARE
dequeue_options DBMS_AQ.dequeue_options_t;
message_properties DBMS_AQ.message_properties_t;
message_handle RAW (16);
I_PAYLOAD ITEM_EVENT;
no_messages exception;
msg_content VARCHAR2 (4000);
PRAGMA EXCEPTION_INIT (no_messages, -25228);
BEGIN
dequeue_options.wait := DBMS_AQ.NO_WAIT;
dequeue_options.consumer_name := 'ITEM_SUBSCRIBER_1';
dequeue_options.navigation := DBMS_AQ.FIRST_MESSAGE;
LOOP
DBMS_AQ.DEQUEUE (queue_name => 'ITEM_EVENT_QUEUE',
dequeue_options => dequeue_options,
message_properties => message_properties,
payload => I_PAYLOAD,
msgid => message_handle
);
END LOOP;
EXCEPTION
WHEN no_messages
THEN
DBMS_OUTPUT.PUT_LINE ('No more messages left');
END;
Let me know what happens to your enqueued messages.
You should have a table where you're dequing the data.
Can you also try adding the enqueud table in the agent and then specify the agent to the dequeue table.
DECLARE
aSubscriber sys.aq$_agent;
BEGIN
aSubscriber := sys.aq$_agent('ITEM_SUBSCRIBER_1',
'ITEM_EVENT_QUEUE',
0);
dbms_aqadm.add_subscriber
( queue_name => 'ITEM_EVENT_QUEUE'
,subscriber => aSubscriber);
END;
/
We faced a related problem (at least related to the title), we couldn't dequeue messages with a delay. The messages in the queue stayed the state "WAITING". And were not changed to "READY".
The Oracle AQ monitoring process that is responsable for changing the state from "WAITING" to "READY" (after the delay is expired) wasn't working properly.
For us a database restart fixed this issue.
I faced the same problem, but it was solved after changing these 2 DB parameters:
job_queue_processes (must be > than 0)
aq_tm_processes (autotuning)
Hope it helps.
Related
I am trying to write a proof of concept to test sending/receiving messages between 2 Oracle database using AQ.
Source database : 12.1.0.2 SRCDB
Destination database: 19.14.0.0, DESTDB
We want to send a message from SRCDB to DESTDB, such that when DESTDB gets the message it automatically invokes a PLSQL stored procedure to dequeue and process.
So, start on the SRCDB I do the following:
CREATE OR REPLACE TYPE the_mesg AS OBJECT ( mesg VARCHAR2(20) );
/
`
BEGIN
DBMS_AQADM.CREATE_QUEUE_TABLE(
queue_table => 'the_que_tab',
queue_payload_type => 'the_mesg',
multiple_consumers => TRUE -- Mesg only consumed once ???
);
END;
/
-- create queue
BEGIN
DBMS_AQADM.CREATE_QUEUE(
queue_name => 'the_que',
queue_table => 'the_que_tab' );
END;
/
-- Add remote subscriber
DECLARE
reginfo SYS.AQ$_REG_INFO;
reginfolist SYS.AQ$_REG_INFO_LIST;
BEGIN
DBMS_AQADM.ADD_SUBSCRIBER(
queue_name => 'the_que',
subscriber => SYS.AQ$_AGENT( name => 'the)_sub',
address => 'the_remuser.the_que#destdb',
protocol => 0 ),
queue_to_queue => FALSE );
END;
/
-- Add propogation schedule
BEGIN
DBMS_AQADM.SCHEDULE_PROPAGATION(
queue_name => 'the_que',
latency => 0,
start_time => SYSDATE,
next_time => 'SYSDATE',
destination => 'destdb',
destination_queue => 'the_remuser.the_que' );
DBMS_LOCK.SLEEP(10);
END;
/
-- start queue
BEGIN
DBMS_AQADM.START_QUEUE(
queue_name => 'the_que',
enqueue => TRUE,
dequeue => TRUE );
DBMS_LOCK.SLEEP(10);
END;
/
-- propagation schedule
BEGIN
DBMS_AQADM.ENABLE_PROPAGATION_SCHEDULE(
queue_name => 'the_que',
destination => 'destdb',
destination_queue => 'the_remuser.the_que');
END;
/
-- Create send mesg wrapper procedure
CREATE OR REPLACE PROCEDURE send_mesg ( p_msg IN VARCHAR2 ) AS
l_enq_options SYS.DBMS_AQ.enqueue_options_t;
l_mesg_props SYS.DBMS_AQ.message_properties_t;
l_mesg_handle RAW(16);
l_mesg the_mesg;
BEGIN
l_mesg := the_mesg( p_msg );
DBMS_AQ.enqueue (
queue_name => 'the_que',
enqueue_options => l_enq_options,
message_properties => l_mesg_props,
payload => l_mesg,
msgid => l_mesg_handle );
COMMIT;
END;
/
-- Send mesg
EXEC send_mesg ( 'hello' );
Here, the queue's enqueue/dequeue settings are enabled, and there is an entry for the message in the queue table.
Then on the destdb:
CREATE OR REPLACE TYPE the_mesg AS OBJECT (
mesg VARCHAR2(20)
);
/
BEGIN
DBMS_AQADM.CREATE_QUEUE_TABLE(
queue_table => 'the_que',
queue_payload_type => 'the_mesg' );
END;
/
BEGIN
DBMS_AQADM.CREATE_QUEUE(
queue_name => 'the_que',
queue_table => 'the_que_tab' );
END;
/
DECLARE
reginfo SYS.AQ$_REG_INFO;
reginfolist SYS.AQ$_REG_INFO_LIST;
BEGIN
reginfo := SYS.AQ$_REG_INFO( 'the_remuser.the_que',
1,
'PLSQL://recv_mesg',
HEXTORAW('FF') );
reginfolist := SYS.AQ$_REG_INFO_LIST ( reginfo );
DBMS_AQ.REGISTER ( reg_list => reginfolist,
reg_count => 1 );
END;
/
BEGIN
DBMS_AQADM.START_QUEUE( queue_name => 'the_que',
dequeue => TRUE );
END;
/
CREATE TABLE mesg_table_aq_demo
(
cdate DATE DEFAULT SYSDATE,
mesg VARCHAR2(32) NOT NULL
);
CREATE OR REPLACE PROCEDURE recv_mesg
(
context IN RAW,
reginfo IN SYS.AQ$_REG_INFO,
descr IN SYS.AQ$_DESCRIPTOR,
payload IN RAW,
payload1 IN NUMBER
)
IS
l_deq_options DBMS_AQ.dequeue_options_t;
l_mesg_props DBMS_AQ.message_properties_t;
l_mesg_handle RAW(16);
l_mesg the_mesg;
no_messages EXCEPTION;
PRAGMA EXCEPTION_INIT ( no_messages, -25228 );
BEGIN
l_deq_options.msgid := descr.msg_id;
l_deq_options.consumer_name := descr.consumer_name;
LOOP
DBMS_AQ.dequeue ( queue_name => 'the_que',
dequeue_options => l_deq_options,
message_properties => l_mesg_props,
payload => l_mesg,
msgid => l_mesg_handle );
INSERT INTO mesg_table_aq_demo ( cdate, mesg )
VALUES ( SYSDATE, l_mesg.mesg );
COMMIT;
END LOOP;
EXCEPTION
WHEN no_messages THEN
NULL;
WHEN OTHERS THEN
RAISE;
END;
/
When I run this by enqueuing a message on the SRCDB the message is not propagated to the DESTDB.
No errors, although sometimes (as a result of desperate hacking) I see the following on the source user_queue_schedules:
ORA-25226: dequeue failed, queue SRCUSER.THE_QUE is not enabled for dequeue
Even though it looks like it is.
What am I doing wrong?
Is is possible to set message state to DBMS_AQ.EXPIRED without reaching retry_count?
From oracle documentation dbms_aq.message_properties_t.state:
Specifies the state of the message at the time of the dequeue. This
parameter cannot be set at enqueue time. The possible states follow:
DBMS_AQ.READY: The message is ready to be processed.
DBMS_AQ.WAITING: The message delay has not yet been reached.
DBMS_AQ.PROCESSED: The message has been processed and is retained.
DBMS_AQ.EXPIRED: The message has been moved to the exception queue.
However when i try to dequeue message with state := DBMS_AQ.EXPIRED it's state after dequeue is still DBMS_AQ.PROCESSED.
declare
procedure mark_as_expired(p_queue_name in varchar2, p_msgid in raw) is
l_dequeue_options DBMS_AQ.DEQUEUE_OPTIONS_T;
l_message_properties DBMS_AQ.MESSAGE_PROPERTIES_T;
l_dummy_payload obj_dummy;
l_dummy_msgid raw(16);
begin
l_dequeue_options.msgid := p_msgid;
l_dequeue_options.wait := DBMS_AQ.NO_WAIT;
l_dequeue_options.navigation := DBMS_AQ.FIRST_MESSAGE;
l_message_properties.state := DBMS_AQ.EXPIRED;
dbms_aq.dequeue(
queue_name => sys_context('USERENV', 'CURRENT_USER')||'.'||p_queue_name,
dequeue_options => l_dequeue_options,
message_properties => l_message_properties,
payload => l_dummy_payload,
msgid => l_dummy_msgid);
end;
begin
mark_as_expired('QUEUE_NAME', 'BE3228C90B3239BBE0534980CB0AE63E');
end;
I have a schema that owns some queues and an application that connects to that schema and uses the queues. For security reasons I want to create a user schema that can access the queue and I want the application to use the user schema from now on.
I gave queue privileges to the user like this:
BEGIN
FOR Q IN (SELECT * FROM ALL_QUEUES WHERE owner = 'OWNER_SCHEMA')
LOOP
DBMS_AQADM.GRANT_QUEUE_PRIVILEGE('ALL', 'OWNER_SCHEMA.' || Q.NAME, 'USER_SCHEMA', FALSE);
END LOOP;
END;
The problem is that the application fails cause it tries to access a queue owned by the user schema, which does not exist.
I tried to manually enqueue a message using the USER schema:
DECLARE
msg SYS.AQ$_JMS_TEXT_MESSAGE;
queue_options DBMS_AQ.ENQUEUE_OPTIONS_T;
msg_props DBMS_AQ.MESSAGE_PROPERTIES_T;
msg_id RAW(16);
BEGIN
msg := SYS.AQ$_JMS_TEXT_MESSAGE.CONSTRUCT();
msg.set_text('
{
"someKey": "someValue"
}
');
DBMS_AQ.ENQUEUE( queue_name => 'SOME_QUEUE'
, enqueue_options => queue_options
, message_properties => msg_props
, payload => msg
, msgid => msg_id);
COMMIT;
END;
and it failed with the following error:
ORA-24010: QUEUE USER_SCHEMA.SOME_QUEUE does not exist
ORA-06512: at "SYS.DBMS_AQ", line 185
ORA-06512: at line 18
but when I try to enqueue the message using also the USER schema but reference the queue from the OWNER schema it worked (queue_name => 'SCHEMA_OWNER.SOME_QUEUE'). This worked:
DECLARE
msg SYS.AQ$_JMS_TEXT_MESSAGE;
queue_options DBMS_AQ.ENQUEUE_OPTIONS_T;
msg_props DBMS_AQ.MESSAGE_PROPERTIES_T;
msg_id RAW(16);
BEGIN
msg := SYS.AQ$_JMS_TEXT_MESSAGE.CONSTRUCT();
msg.set_text('
{
"someKey": "someValue"
}
');
DBMS_AQ.ENQUEUE( queue_name => 'SCHEMA_OWNER.SOME_QUEUE'
, enqueue_options => queue_options
, message_properties => msg_props
, payload => msg
, msgid => msg_id);
COMMIT;
END;
I tried to create a synonym for the queue but get the same result.
The only thing that makes the application work is adding one more config property that is the schema owner so that the app can use the schema user to connect, but then use the schema owner to reference the queue, but this is not the desired solution, cause there are a lot of envs and the config file for all envs would need to be changed.
Is there a way to reference the queue directly with the USER schema?
I'm currently trying to implement a similar version of oracle's APEX_MAIL package. I have everything working, but I can't make the job work unless I modify it.
The job APEX_MAIL uses is called ORACLE_APEX_MAIL_QUEUE
BEGIN
DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'job_action', value => 'APEX_040000.WWV_FLOW_MAIL.PUSH_QUEUE');
DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'number_of_arguments', value => '2');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE(
job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"',
argument_position => 1,
argument_value => '');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE(
job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"',
argument_position => 2,
argument_value => '');
END;
/
So I go to the package to see what the code does. I'm was assuming push queue would send out emails in the queue. Instead, it calls the same job again!
PROCEDURE PUSH_QUEUE( P_SMTP_HOSTNAME IN VARCHAR2 DEFAULT NULL,
P_SMTP_PORTNO IN VARCHAR2 DEFAULT NULL )
IS
BEGIN
PUSH_QUEUE_BACKGROUND;
END PUSH_QUEUE;
PROCEDURE PUSH_QUEUE_BACKGROUND
IS
BEGIN
SYS.DBMS_SCHEDULER.RUN_JOB( JOB_NAME => 'ORACLE_APEX_MAIL_QUEUE', USE_CURRENT_SESSION => FALSE );
EXCEPTION
WHEN OTHERS THEN
IF SQLCODE <> -27478 THEN
RAISE;
END IF;
END PUSH_QUEUE_BACKGROUND;
So basically this job does nothing, but I switch it to call PUSH_QUEUE_IMMEDIATE which does what I think it should do.
PROCEDURE PUSH_QUEUE_IMMEDIATE( P_FORCE_YN IN VARCHAR2 DEFAULT 'N')
IS
L_STATUS NUMBER;
L_LOCK_HDL VARCHAR2(128);
E_DB_SHUTDOWN EXCEPTION;
PRAGMA EXCEPTION_INIT(E_DB_SHUTDOWN, -1089);
BEGIN
WWV_FLOW_DEBUG.ENABLE_DBMS_OUTPUT;
SYS.DBMS_LOCK.ALLOCATE_UNIQUE( LOCKNAME => 'APEX_MAIL_QUEUE_LOCK', LOCKHANDLE => L_LOCK_HDL);
L_STATUS := SYS.DBMS_LOCK.REQUEST( LOCKHANDLE => L_LOCK_HDL,
LOCKMODE => SYS.DBMS_LOCK.X_MODE,
TIMEOUT => 0,
RELEASE_ON_COMMIT => FALSE );
WWV_FLOW_DEBUG.INFO('APEX Mail Lock status: ' || L_STATUS );
IF L_STATUS = 0 THEN
FOR C1 IN ( SELECT ID, MAIL_SEND_COUNT, LAST_UPDATED_ON
FROM WWV_FLOW_MAIL_QUEUE
ORDER BY MAIL_SEND_COUNT, LAST_UPDATED_ON) LOOP
BEGIN
WWV_FLOW_DEBUG.INFO( 'Pushing email: ' || C1.ID );
IF (C1.MAIL_SEND_COUNT = 0) OR (NVL(P_FORCE_YN,'N') = 'Y') OR
(C1.MAIL_SEND_COUNT > 0 AND (POWER(2,C1.MAIL_SEND_COUNT)/(60*24) + C1.LAST_UPDATED_ON) < SYSDATE) THEN
BACKGROUND( P_ID => C1.ID );
END IF;
WWV_FLOW_DEBUG.INFO( 'Pushed email: ' || C1.ID );
EXCEPTION
WHEN OTHERS THEN
WWV_FLOW_DEBUG.LOG_EXCEPTION;
IF L_LOCK_HDL IS NOT NULL THEN
L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
END IF;
END;
END LOOP;
END IF;
IF L_LOCK_HDL IS NOT NULL THEN
L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
END IF;
EXCEPTION WHEN E_DB_SHUTDOWN THEN
NULL;
END PUSH_QUEUE_IMMEDIATE;
I'm trying to copy APEX_MAIL to a point, but if I do, I won't have a working job. Can anyone point out if APEX_MAIL changes what the job does after an application setting change or any other change?
Thanks in advance!
APEX_MAIL.PUSH_QUEUE is usable in your own code to send your mail (in the queue) out immediate. The job normally calls PUSH_QUEUE_IMMEDIATE. I don't know if your setting ever was a bug in the installation or something wrong on your site.
Thus fact, it calls PUSH_QUEUE_IMMEDIATE in a separate session as APEX_040000 job.
Since everyone can request an immediate send of all the jobs in the queue, it makes sure via SYS.DBMS_LOCK.REQUEST only one session will actually do the transmit.
AQ$_MESSAGES_EXCEPTIONFirst of all I know there's this question: How to clear a queue in Oracle AQ but it doesn't have an answer.
I have a lot of messages(500k) in the exception queue in the Oracle AQ(I didn't know expired messages are moved to another queue so I didn't create a consumer for those). What I need now is to be able to delete those messages fast. I've read that it's not a good idea to clear the queue table via delete, because it could lead to inconsistent state. So I've put together following procedure, but it only clears about 50 messages/second
EXECUTE dbms_aqadm.start_queue(queue_name => 'AQ$_MESSAGES_EXCEPTION',
enqueue => FALSE, dequeue => TRUE);
DECLARE
dequeue_options DBMS_AQ.dequeue_options_t;
message_properties DBMS_AQ.message_properties_t;
message_handle RAW(16);
message SYS.AQ$_JMS_MESSAGE;
no_messages EXCEPTION;
pragma exception_init (no_messages, -25228);
BEGIN
dequeue_options.wait := DBMS_AQ.NO_WAIT;
dequeue_options.navigation := DBMS_AQ.FIRST_MESSAGE;
LOOP
DBMS_AQ.DEQUEUE(
queue_name => 'AQ$_MESSAGES_EXCEPTION',
dequeue_options => dequeue_options,
message_properties => message_properties,
payload => message,
msgid => message_handle);
DBMS_OUTPUT.put_line ('Message: ' || message_handle || ' dequeued');
END LOOP;
EXCEPTION
WHEN no_messages THEN
DBMS_OUTPUT.put_line (' ---- NO MORE MESSAGES ---- ');
WHEN others then
DBMS_OUTPUT.put_line ('Exception queue not started for dequeue.');
END;
/
It seems really slow considering it's running on the database machine. This procedure takes about three hours with 500k messages. Can I do it in some more effective manner?
EDIT:
I tried the dequeue_array from the link here: http://www.oracle-developer.net/display.php?id=319
But I can't create the tables, so I'm trying to create an array to "store" the results.
Here's what I've got:
DECLARE
type messages_type is varray(500) of SYS.AQ$_JMS_MESSAGE;
messages messages_type;
dequeue_options DBMS_AQ.dequeue_options_t;
msg_properties DBMS_AQ.message_properties_array_t;
msg_ids DBMS_AQ.MSGID_ARRAY_T;
x_timeout EXCEPTION;
no_messages EXCEPTION;
dequeue_batch PLS_INTEGER := 500;
pragma exception_init (no_messages, -25228);
BEGIN
messages := messages_type();
msg_properties := DBMS_AQ.MESSAGE_PROPERTIES_ARRAY_T();
msg_properties.EXTEND(dequeue_batch);
msg_ids := DBMS_AQ.MSGID_ARRAY_T();
dequeue_options.wait := 5;
LOOP
DBMS_AQ.DEQUEUE_ARRAY(
queue_name => 'AQ$_MESSAGES_EXCEPTION',
dequeue_options => dequeue_options,
array_size => dequeue_batch,
message_properties_array => msg_properties,
payload_array => messages,
msgid_array => msg_ids);
...
I'm getting this error:
wrong number or types of arguments in call to 'DEQUEUE_ARRAY'
I think the problem is in the messages array, but I don't know what to do to make it work. Also, according to oracle doc(http://docs.oracle.com/cd/B19306_01/appdev.102/b14258/d_aq.htm#i1000850), there should be another parameter:
error_array OUT error_array_t
But the explanation for this parameter is "Currently not implemented". What does it mean? Can it be left out? Should it be set to null? This is really confusing and google doesn't help here :(
If you really want to dequeue, you could probably use the dequeue_array(n) function. That should be much faster.
but the link you provide does have the solution :
-- purge queue
DECLARE
po_t dbms_aqadm.aq$_purge_options_t;
BEGIN
dbms_aqadm.purge_queue_table('MY_QUEUE_TABLE', NULL, po_t);
END;
Otherwise, since this exception queue is created automatically,
I guess you could just drop it, but I am not sure if that is safe
BEGIN
DBMS_AQADM.STOP_QUEUE(
queue_name => 'demo_queue'
);
DBMS_AQADM.DROP_QUEUE(
queue_name => 'demo_queue'
);
DBMS_AQADM.DROP_QUEUE_TABLE(
queue_table => 'demo_queue_table'
);
END;
You can use procedure "purge_queue_table" (as #Stephane said) from dbms_aqadm package but with "purge_condition" parameter specified , with this parameter you can select which messages you delete :
Example :
declare
purge_options dbms_aqadm.aq$_purge_options_t;
begin
purge_options.block := false;
purge_options.delivery_mode := dbms_aqadm.persistent;
dbms_aqadm.purge_queue_table
(queue_table => 'vista.svig_std_tab',
purge_condition => 'qtview.queue = ''AQ$_SVIG_STD_TAB_E'' and qtview.enq_time < to_date(''01.06.2014 00:00:00'',''dd.mm.yyyy hh24:mi:ss'') ',
purge_options => purge_options
);
end;
/
This example deletes messages that are from the specified exception queue and are older than the specified date. It also does this in a much quicker fashion than using "dbms_aq.dequeue" procedure.