Creating Excel range given start cell and row/column offset, in Applescript - applescript

Question

I am trying to use Applescript to insert values into cells in an Excel worksheet. The values are held in an Applescript variable as a list of lists (see example code). I've already worked out that if I insert this variable into a range of the correct size (rows and columns) it comes in correctly with everything in the right place.
Unfortunately, the amount of data I'm inserting can vary, so rather than hard-coding the range size I need to calculate it from the number of items in the list. I'm using the list size to work out an offset from the starting cell, and then trying to create a range that spans from the starting cell to the calculated cell offset.
Cut down to a minimum, the code is as follows:
set myList to {{"Red", "Grapefruit", "1", ""}, {"Julie", "Heron", "2", "*"}}
tell application "Microsoft Excel"
set myStartCell to range ("B18") of sheet 1 of active workbook
set myEndCell to get offset myStartCell row offset ((count myList) -1) column offset ((count item 1 of myList) -1)
set myRange to range {myStartCell, myEndCell} of sheet 1 of active workbook
set value of myRange to myList
end tell
With the above code, I receive the error message 'The object you are trying to access does not exist', relating to the line
set myRange to range {myStartCell, myEndCell} of sheet 1 of active workbook
In VBA, similar code would be as follows:
With ThisWorkbook.Worksheets(1)
Dim myStartCell As Range
Dim myEndCell As Range
Dim myRange As Range
Set myStartCell = Range("B18").Cells
Set myEndCell = myStartCell.Offset(rowOffset:=1, columnOffset:=3).Cells
Set myRange = .Range(myStartCell, myEndCell)
End With
How can I use Applescript to fulfil the same function as the VBA line
Set myRange = .Range(myStartCell, myEndCell)
? Or is there a better way to create a range given the starting cell and the number of rows and columns?

Answer 1

You can use the get address command.
set myRange to range ("B18:" & (get address myEndCell)) of sheet 1 of active workbook
set value of myRange to myList
Or
set myRange to range ((get address myStartCell) & ":" & (get address myEndCell)) of sheet 1 of active workbook
set value of myRange to myList

Answer 2

Creating a range in Excel from row and column numbers is a pain. This uses a handler to convert numbers to letters
set myList to {{"Red", "Grapefruit", "1", ""}, {"Julie", "Heron", "2", "*"}}
set numberOfColumns to (count item 1 of myList) - 1
set numberOfRows to (count myList) - 1
tell application "Microsoft Excel"
set myStartCell to range "B18" of active sheet
set myEndCell to get offset myStartCell row offset numberOfRows column offset numberOfColumns
set columnLetter to my excelColumnToLetters(first column index of myEndCell)
set myRange to range ("B18:" & columnLetter & first row index of myEndCell)
set value of myRange to myList
end tell
-- converts the column number to the letter equivalent
to excelColumnToLetters(column)
set letters to {}
repeat while column > 0
set remainder to column mod 26
if remainder = 0 then set remainder to 26
set beginning of letters to (remainder + 64)
set column to (column - remainder) div 26
end repeat
return string id letters
end excelColumnToLetters