get last month first date and last date in batch file - windows

Question

I am creating a batch file to execute some exe file. In that exe i need to specify first date(mm/dd/yyyy) and last day(mm/dd/yyyy) of last month.
#echo off
start "Testing" "c:\Program Files\app-cmd\bin\admincmd\imagelist -d 08/01/2015 -e 01/09/2015 > c:\test.txt"
Imagelist is an exe file where I need to pass value in -d and -e parameter.
I will add this script in schedule task so, it will run as schedule.
I can't use powershell as machine is win server 2003.
Please advise.

Answer 1

Assuming the date format on your system is MM/DD/YYYY as shown by date /t command:
#echo off
setlocal enableDelayedExpansion
for /f "delims=/ tokens=1,3" %%a in ("%date%") do set month=%%a& set year=%%b
if %month:~0,1%==0 set month=%month:~1%
set /a month-=1 && if !month!==0 set month=12&set /a year-=1
if not !month!==2 (
set /a last_day="31 - (month - 1) %% 7 %% 2"
) else (
set /a y4="year %% 4" & if !y4!==0 (
set /a y100="year %% 100" & if not !y100!==0 set is_leap_year=1
set /a y400="year %% 400" & if !y400!==0 set is_leap_year=1
)
if "!is_leap_year!"=="1" (set last_day=29) else set last_day=28
)
set month=0!month!
start "Testing" "c:\Program Files\app-cmd\bin\admincmd\imagelist" ^
-d !month:~-2!/01/!year! -e !month:~-2!/!last_day!/!year! > c:\test.txt
The code detects leap years as (year % 4 == 0) && ((year % 100 != 0) || (year % 400 == 0)) for February and uses 31 - (month - 1) % 7 % 2 for other months.

Answer 2

You can try with
#echo off
setlocal enableextensions
call :getLastMonthLimits start end
echo %start% - %end%
goto :eof
:getLastMonthLimits startDateReturnVar endDateReturnVar
setlocal enableextensions disabledelayedexpansion
for %%t in ("%temp%\%~nx0.%random%%random%%random%.rpt") do (
for /f "tokens=4,7" %%a in ('
^>nul makecab /f nul /d RptFileName^="%%~ft" /V0
^& type "%%~ft" ^| find "MakeCAB Report:"
') do (
set /a "jan=1,feb=2,mar=3,apr=4,may=5,jun=6,jul=7,aug=8,sep=9,oct=10,nov=11,dec=12"
set /a "m=(%%a+10) %% 12 + 1", "y=%%b-m/12", "d=30+((m+m/8) %% 2)", "m+=100"
if /i %%a==mar set /a "d=d-2 +(3-y %% 4)/3 -(99-y %% 100)/99 +(399-y %% 400)/399"
set /a "d+=100"
)
) & del "%%~ft"
endlocal & set "%~1=%m:~-2%/01/%y%" & set "%~2=%m:~-2%/%d:~-2%/%y%"
goto :eof
This uses a simplified version of the getDate function by carlos to get the date in a locale independent format (I prefer to use robocopy for it, but it is not a native tool in 2003). The rest are just arithmetic operations to calculate the month limits.
edited For the robocopy version (instead of the makecab to retrieve the date in locale independent format), just in case someone could need it
#echo off
call :getLastMonthLimits start end
echo %start% - %end%
goto :eof
:getLastMonthLimits startDateReturnVar endDateReturnVar
setlocal enableextensions disabledelayedexpansion
for /f "tokens=1-2 delims=/ " %%a in ('robocopy "|" . /njh ^| find "|"') do (
set /a "m=((1%%b-100)+10) %% 12 + 1", "y=%%a-m/12", "d=30+((m+m/8) %% 2)", "m+=100"
if %%b==03 set /a "d=d-2 +(3-y %% 4)/3 -(99-y %% 100)/99 +(399-y %% 400)/399"
set /a "d+=100"
)
endlocal & set "%~1=%m:~-2%/01/%y%" & set "%~2=%m:~-2%/%d:~-2%/%y%"
goto :eof