How to draw without replacement to fill in data set - random

Question

I am generating a data set where I first want to randomly draw a number for each observation from a discrete distribution, fill in var1 with these numbers. Next, I want to draw another number from the distribution for each row, but the catch is that the number in var1 for this observation is not eligible to be drawn anymore. I want to repeat this a relatively large number of times.
To hopefully make this make more sense, suppose that I start with:
id
1
2
3
...
999
1000
Suppose that the distribution I have is ["A", "B", "C", "D", "E"] that happen with probability [.2, .3, .1, .15, .25].
I would first like to randomly draw from this distribution to fill in var. Suppose that the result of this is:
id var1
1 E
2 E
3 C
...
999 B
1000 A
Now E is not eligible to be drawn for observations 1 and 2. C, B, and A are ineligible for observations 3, 999, and 1000, respectively.
After all the columns are filled in, we may end up with this:
id var1 var2 var3 var4 var5
1 E C B A D
2 E A B D C
3 C B A E D
...
999 B D C A E
1000 A E B C D
I am not sure of how to approach this in Stata. But one way to fill in var1 is to do something like:
gen random1 = runiform()
replace var1 = "A" if random1<.2
replace var1 = "B" if random1>=.2 & random1<.5
etc....
Note that sticking with the (scaled) probabilities after creating var1 is desirable, but is not required for me.

Answer 1

Here's a solution that works in long form to select from the distribution. As values are selected, they are flagged as done and the next selection is made from the groups that contain the remaining values. Probabilities are scaled at each pass.
version 14
set seed 3241234
* Example generated by -dataex-. To install: ssc install dataex
clear
input byte ip str1 y double p
1 "A" .2
2 "B" .3
3 "C" .1
4 "D" .15
5 "E" .25
end
local nval = _N
* the following should be true
isid y
expand 1000
bysort y: gen id = _n
sort id ip
gen done = 0
forvalues i = 1/`nval' {
// scale probabilities
bysort id done (ip): gen double ptot = sum(p) // this is a running sum
by id done: gen double phigh = sum(p / ptot[_N])
by id done: gen double plow = cond(_n == 1, 0, phigh[_n-1])
// random number in the range of (0,1) for the group
bysort id done (ip): gen double x = runiform()
// pick from the not done group; choose first x to represent group
by id done: gen pick = !done & inrange(x[1], plow, phigh)
// put the picked obs at the end and create the new var
bysort id (pick ip): gen v`i' = y[_N]
// we are done for the obs that was picked
bysort id: replace done = 1 if _n == _N
drop x pick ptot phigh plow
}
bysort id: keep if _n == 1