bash - append specific column of multiple files to a new file - bash

Question

I have many files in a folder. All files have same format:
file A:
090722 12:15 - 12:45 2342
090722 12:30 - 13:00 73
090722 12:45 - 13:15 543
...
file B:
090722 12:15 - 12:45 874
090722 12:30 - 13:00 32
090722 12:45 - 13:15 2543
...
and so on ... The first part is always the same and should print only once a time.
Would like to get an ouput like this:
090722 12:15 - 12:45 2342 874 values_fileC values_fileD ...
090722 12:30 - 13:00 73 32 values_fileC values_fileD ...
090722 12:45 - 13:15 543 2543 values_fileC values_fileD ...
...
I've tried something like:
paste files* > final.txt
That work's fine, but don't know how to add only the columns with the values from the files?
Some ideas failed:
paste files* | awk '{ print $5 }' > final.txt
for f in files*; do cat $f | awk '{print $5}'; done > final.txt

Answer 1

Try this:
awk -F' ' '{a[$1" "$2" "$3" "$4]=a[$1" "$2" "$3" "$4]"\t"$5}END{for(i in a) print i a[i]}' file*
Output:
090722 12:15 - 12:45 2342 874
090722 12:45 - 13:15 543 2543
090722 12:30 - 13:00 73 32
Update:
awk -F' ' '{a[$1" "$2" "$3" "$4]=a[$1" "$2" "$3" "$4]"\t"$5}END{for(i in a) print i a[i]}' file* | sort -t " " -k 2,2n
Output:
090722 12:15 - 12:45 2342 874
090722 12:30 - 13:00 73 32
090722 12:45 - 13:15 543 2543

Answer 2

One option would be to use awk to combine the fields:
awk '{
key = $1 FS $2 FS $3 FS $4; if (NR == FNR) a[NR] = key; out[key] = out[key] FS $5
} END { for(i = 1; i <= FNR; ++i) print a[i], out[a[i]] }' file*
Laid out as a script (which you could run with awk -f script.awk file*):
{
key = $1 FS $2 FS $3 FS $4 # build key using first four fields
if (NR == FNR) a[NR] = key # record order in which fields appear
out[key] = out[key] FS $5 # build output array using fifth field
}
END {
# loop through and print keys, values
for(i = 1; i <= FNR; ++i) print a[i], out[a[i]]
}
This makes the assumption that each file contains the same number of records.
I can think of two ways to achieve a fixed width output. If you're sure that the values being combined will only vary in length within the range of one tab stop, then the simplest solution is just to use a \t instead of FS in this line:
out[key] = out[key] "\t" $5 # build output array using fifth field
Otherwise you could use sprintf to pad each value to a length of your choice:
out[key] = out[key] sprintf("%6s", $5)
You can left-align the fields using -6 instead of 6.