Changing the bounds of a window - macos

Question

I need help with Apple script. I don't expert in this matter. The script is this:
(*
This Apple script will resize any program window to an exact size and the window is then moved to the center of your screen.
Specify the program name, height and width below and run the script.
Written by Amit Agarwal on December 10, 2013
*)
set theApp to "Finder"
set appHeight to 412
set appWidth to 678
tell application "Finder"
set screenResolution to bounds of window of desktop
end tell
set screenWidth to item 3 of screenResolution
set screenHeight to item 4 of screenResolution
tell application theApp
activate
reopen
set yAxis to (screenHeight - appHeight) / 2 as integer
set xAxis to (screenWidth - appWidth) / 2 as integer
set the bounds of the first window to {xAxis, yAxis, appWidth + xAxis, appHeight + yAxis}
tell application "Finder" to set the sidebar width of every Finder window to 142
end tell
I would like to resize Finder, but without center it in the screen. Is it possible?

Answer 1

The logic is, you get the current bounds of the front window. The first two items in the bounds are the starting horizontal point on the x axis and the starting vertical point on the y axis. (in other words, the first two items are the coordinates of the top left corner)
Once you have those, you set new bounds, keeping the first two items in the bounds description the same, and then adding the desired width and height to the second two points to resize the window.
set theApp to "Finder"
set appHeight to 412
set appWidth to 678
tell application theApp
activate
set {startHoriz, startVert, endHoriz, endVert} to bounds of the first window
set the bounds of the first window to {startHoriz, startVert, startHoriz + appWidth, startVert + appHeight}
end tell
tell application "Finder" to set the sidebar width of every Finder window to 142
If you wanted to move the window all the way to the left, you could change the startHoriz to 1 before setting the bounds of the window.