How to display results in a dedicated buffer? - elisp

Question

If my current buffer is foo, and I run C-x C-b (aka list-buffers), my Emacs window splits in two, with foo occupying one of the two resulting windows, and a dedicated *Buffer List* buffer occupying the other one. At the end of this operation, foo remains the active buffer, and point remains were it was before C-x C-b was executed.
I want to write an interactive function that displays a multi-page output in a similar way: split window if necessary, bring up a dedicated buffer, leave the active buffer as it was before the function was run.
The best I've managed to do is a function with the following structure:
(defun my-func ()
(interactive)
(let ((this-buffer (current-buffer))
(other-buffer (get-buffer-create "*my-func's Dedicated Buffer*")))
(switch-to-buffer-other-window other-buffer)
(erase-buffer)
(insert (compute-pages-and-pages-of-stuff))
(beginning-of-buffer)
(switch-to-buffer-other-window this-buffer)))
This works, more or less, but I thought that Emacs already had built-in syntax to streamline such code.
IOW, I thought there was a special form analogous to the (fictional) WITH-BUFFER-OTHER-WINDOW in the snippet below:
(defun my-func ()
(interactive)
(let ((other-buffer (get-buffer-create "*my-func's Dedicated Buffer*")))
(WITH-BUFFER-OTHER-WINDOW other-buffer
(erase-buffer)
(insert (compute-pages-and-pages-of-stuff))
(beginning-of-buffer))))
or maybe even
(defun my-func ()
(interactive)
(let ((other-buffer (get-buffer-create "*my-func's Dedicated Buffer*")))
(WITH-BUFFER-OTHER-WINDOW other-buffer
(compute-pages-and-pages-of-stuff))))
I've tried forms like save-excursion and save-current-buffer, but they don't reproduce the desired behavior.
Is there a built-in way to carry out the operation described above?

Answer 1

This is the shortest you can get by leveraging the built-ins display-buffer and with-current-buffer:
(defun my-func ()
(interactive)
(let ((buffer (get-buffer-create "*my-func's Dedicated Buffer*")))
(with-current-buffer buffer
(erase-buffer)
(insert (compute-pages-and-pages-of-stuff))
(goto-char (point-min)))
(display-buffer buffer)))
If you use this pattern so much that it starts annoying you, feel free to define a helper macro:
(defmacro my-setup-and-display-buffer (name &rest body)
(declare (indent 1))
(let ((buffer (make-symbol "buffer")))
`(let ((,buffer (get-buffer-create ,name)))
(with-current-buffer ,buffer
,#body)
(display-buffer ,buffer))))
(my-setup-and-display-buffer "*my-func's Dedicated Buffer*"
(erase-buffer)
(insert (compute-pages-and-pages-of-stuff))
(goto-char (point-min)))