Create shortcut with environment variable in working directory - installation

Question

Currently I'm creating a shortcut as so:
SetShellVarContext all
SetOutPath "$INSTDIR"
CreateShortCut "$SMPROGRAMS\MyApp.lnk" "$INSTDIR\MyApp.exe"
I would like to change the working directory of this shortcut from C:\Program Files\MyApp to %UserProfile%.
The tricky part is that I don't want %UserProfile% to be expanded, I want to keep it as an environment variable, so the program starts in the profile directory of current user.
Can I achieve this with NSIS? If not, what would be the simplest workaround?
Reference: CreateShortcut

Answer 1

NSIS calls IShellLink::SetWorkingDirectory on the shortcut with the path set by SetOutPath ($OutDir).
It is possible to set $OutDir to something that is not a valid path and then call CreateShortcut:
Push $OutDir ; Save
StrCpy $OutDir "%UserProfile%"
CreateShortcut "$temp\test1.lnk" "$sysdir\Calc.exe"
Pop $OutDir ; Restore
It does work but is perhaps bending the rules a bit. You can also do it without relying on undocumented NSIS quirks:
!define CLSCTX_INPROC_SERVER 1
!define STGM_READWRITE 2
!define IID_IPersistFile {0000010b-0000-0000-C000-000000000046}
!define CLSID_ShellLink {00021401-0000-0000-c000-000000000046}
!define IID_IShellLinkA {000214ee-0000-0000-c000-000000000046}
!define IID_IShellLinkW {000214f9-0000-0000-c000-000000000046}
!ifdef NSIS_UNICODE
!define IID_IShellLink ${IID_IShellLinkW}
!else
!define IID_IShellLink ${IID_IShellLinkA}
!endif
!include LogicLib.nsh
Function Lnk_SetWorkingDirectory
Exch $9 ; New working directory
Exch
Exch $8 ; Path
Push $0 ; HRESULT
Push $1 ; IShellLink
Push $2 ; IPersistFile
System::Call 'OLE32::CoCreateInstance(g "${CLSID_ShellLink}",i 0,i ${CLSCTX_INPROC_SERVER},g "${IID_IShellLink}",*i.r1)i.r0'
${If} $0 = 0
System::Call `$1->0(g "${IID_IPersistFile}",*i.r2)i.r0`
${If} $0 = 0
System::Call `$2->5(wr8,i${STGM_READWRITE})i.r0` ; Load
${If} $0 = 0
System::Call `$1->9(tr9)i.r0` ; SetWorkingDirectory
${If} $0 = 0
System::Call `$2->6(i0,i0)i.r0` ; Save
${EndIf}
${EndIf}
System::Call `$2->2()` ; Release
${EndIf}
System::Call `$1->2()` ; Release
${EndIf}
StrCpy $9 $0
Pop $1
Pop $0
Pop $8
Exch $9
FunctionEnd
Section
CreateShortcut "$temp\test2.lnk" "$sysdir\Calc.exe"
Push "$temp\test2.lnk"
Push "%UserProfile%"
Call Lnk_SetWorkingDirectory
Pop $0
DetailPrint HRESULT=$0 ; 0 = success
SectionEnd
It should be noted that IShellLink::SetWorkingDirectory does not say anything about supporting unexpanded environment variables but they do seem to work.