How to start a process when another process starts in Windows? - windows

Question

I'm trying to create a way that will check if a certain program is running - and if it is, launch another program.
This is my progress in BAT
#ECHO OFF
:LOOP
tasklist /nh /fi "imagename eq steam.exe" | find /i "steam.exe" >nul && START "" "C:\Program Files\TeamSpeak 3 Client\ts3client_win64.exe" || goto :LOOP
And I created a VBS that basically starts the BAT at Windows startup (this is only to make sure the batch file runs without a visible console window):
Set WshShell = CreateObject("WScript.Shell" )
WshShell.Run chr(34) & "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\if Steam running then TS.bat" & Chr(34), 0
Set WshShell = Nothing
My problem is that doing so, i get a incredibly high CPU usage (20 to 60% with a I5-4670k).
Have i done something wrong? Or can I improve the code anyhow? I was thinking about slowing the time where windows checks for the process (i.e. wait 2 sec then check) but I'm really new to coding and I don't have any idea on how to do so.
I know my English isn't perfect, excuse me.
EDIT: If it helps, my PC is running on Windows 10.

Answer 1

i get a incredibly high CPU usage
You need to give your computer a break between the checks. The timeout command interrupts batch execution for a configurable number of seconds:
#echo off
setlocal
set "FIND_STEAM=tasklist /nh /fi "imagename eq steam.exe" ^| find /i "steam.exe" ^> NUL"
set "START_TS=start "C:\Program Files\TeamSpeak 3 Client\ts3client_win64.exe""
:LOOP
timeout 5 > NUL
%FIND_STEAM% && %START_TS% || goto LOOP
EDIT
Here is bells-and-whistles sophisticated way of reacting to the start and termination of a process in Windows using VBScript.
It works with the WMI, a powerful framework that can do all kinds of things in Windows. Here we use it to listen to process creation and process termination events. (listening to events is a lot more efficient than polling all processes every second or so):
Option Explicit
Dim WMIService, ProcessNew, ProcessEnd
Dim computer, query, teamspeakPID
' create a WMI service object and ProcessNew / ProcessEnd event sinks
computer = "."
Set WMIService = GetObject("winmgmts:\\" & computer & "\root\CIMV2")
Set ProcessNew = WScript.CreateObject("WbemScripting.SWbemSink", "ProcessNew_")
Set ProcessEnd = WScript.CreateObject("WbemScripting.SWbemSink", "ProcessEnd_")
' we will be waiting for Win32_Process creation events and notify event sink "ProcessNew"
WMIService.ExecNotificationQueryAsync ProcessNew, _
"SELECT * FROM __InstanceCreationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'"
' we will also be waiting for Win32_Process deletion events and notify event sink "ProcessEnd"
WMIService.ExecNotificationQueryAsync ProcessEnd, _
"SELECT * FROM __InstanceDeletionEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'"
' main loop: nothing to do, we just sit and wait
While True
Wscript.Sleep(500)
Wend
' function that handles "process created" events
Sub ProcessNew_OnObjectReady(latestEvent, asyncContext)
Dim process
If LCase(latestEvent.TargetInstance.Name) = "steam.exe" Then
' start TeamSpeak
Set process = GetObject("winmgmts:Win32_Process")
process.Create "C:\Program Files\TeamSpeak 3 Client\ts3client_win64.exe", null, null, teamspeakPID
End If
End Sub
' function that handles "process ended" events
Sub ProcessEnd_OnObjectReady(latestEvent, asyncContext)
Dim processList, process
If LCase(latestEvent.TargetInstance.Name) = "steam.exe" Then
' kill TeamSpeak (but only the one we started earlier)
Set processList = WMIService.ExecQuery("SELECT * FROM Win32_Process WHERE Name = 'ts3client_win64.exe' AND ProcessId = " & teamspeakPID)
For Each process in processList
process.Terminate()
Next
End If
End Sub
As an exercise you can try to extend this so that it only starts TS when it's not already running.
Further reading:
Technet "Doctor Scripto's Script Shop" column
WMI asynchronous event monitoring with VBScript
Out of Sync: The Return of Asynchronous Event Monitoring
MSDN
The Win32_Process Class
Create method of the Win32_Process class
Terminate method of the Win32_Process class
SWbemServices.ExecNotificationQueryAsync method