AutoHotKey: Run code on Window Event (Close) - events

Question

I work with a local application which when ESCAPE is pressed, the current window is closed. I wanted to avoid that so I made a script with AutoHotKey that detects the name of the window within the app and, if I press ESCAPE, the window doesn't close (Unless I press the X).
#IfWinActive ahk_class name_of_app_class_here
Escape::return
Now I would like to apply a code for when that window is closed (by pressing the X) but I cuoldn't find any solution for that in the forum or in the help.
Example:
#IfWinActive ahk_class name_of_app_class_here
OnWindowClose
`Do_something`
Hope it is well explained.
Thanks!

Answer 1

The code below should do what you want to achieve:
;tested on Notepad (Windows 7)
;note: may not work correctly if aero mode is on
;note: if you click a Notepad window that is *not* the active window, it will be closed
;note: some programs don't return the standard NCHITTEST value for a close button,
;a workaround is to compare the cursor position against the window coordinates
#IfWinActive, ahk_class Notepad
LButton::
WinGet, hWnd, ID, A
WinGetClass, vWinClass, ahk_id %hWnd%
if vWinClass not in Notepad
Return
CoordMode, Mouse, Screen
MouseGetPos, vPosX, vPosY, hWnd2
if (hWnd = hWnd2)
{
SendMessage, 0x84, 0, vPosX|(vPosY<<16), , ahk_id %hWnd% ;WM_NCHITTEST
vNCHITTEST := ErrorLevel ;(8 min, 9 max, 20 close)
if (vNCHITTEST = 20)
{
MsgBox can't close me! ;put your code here
Return
}
}
SendInput {LButton Down}
KeyWait, LButton
SendInput {LButton Up}
Return
#IfWinActive
Note:
The code posted in the link below, achieves something related, catching close buttons for all windows, not just for one program, whether they are active or inactive.
Is it possible to catch the close button and minimize the window instead? AutoHotKey