vertical lines from data in file in time series plot using gnuplot - bash

Question

I am currently working on a project to plot the development of humidity and temperature at my place. Therefore I am using a raspberry pi 2 with Raspbian Jessie and a DHT-22.
In the end it comes down to a file per day, that stores the measurements all 30 seconds. The file is named like this; 2016-01-30_Temp_Hum_data and contains the following data
2016-01-30-19:30:03 22.0 50.2
2016-01-30-19:30:34 22.0 50.2
2016-01-30-19:31:04 22.0 50.3
2016-01-30-19:31:35 22.0 50.3
2016-01-30-19:32:05 22.0 50.2
whereas the first part is the timestamp, the second value separated by a space is the temperature, followed by the humidity.
Now I plot this with the following script that is called by a for-loop in a bash file that iterates over all data files that I described above.
!/usr/bin/gnuplot
reset
# This command works for a linux computer. In linux, you need to specify the exact location of
# the font you want to use
set terminal png notransparent rounded giant font "/usr/share/fonts/msttcore/arial.ttf" 24 \
size 2600,960
# nomirror means do not put tics on the opposite side of the plot
set xtics nomirror
set ytics nomirror
# Line style for axes
# Define a line style (we're calling it 80) and set
# lt = linetype to 0 (dashed line)
# lc = linecolor to a gray defined by that number
set style line 80 lt 0 lc rgb "#808080"
# Line style for lines
set style line 1 lt 1 lc rgb "#A00000" lw 4
set style line 2 lt 1 lc rgb "#00A000" lw 4
# Add line at 70
# Draw a line from the right end of the graph to the left end of the graph at
# the y value of 70
# The line should not have an arrowhead
# Linewidth = 4
# Linecolor = black
# It should be in front of anything else drawn
set arrow from graph 0,first 70 to graph 1, first 70 nohead lw 2 lc rgb "#500000" front
set arrow from graph 0,first 50 to graph 1, first 50 nohead lw 2 lc rgb "#005000" front
set arrow from graph 0,first 20 to graph 1, first 20 nohead lw 2 lc rgb "#005000" front
# Put a label 80% hum at 80% the width of the graph and y = -2 (it will be just above the line drawn)
set label "70%" at graph 0.8, first 72
set label "50%" at graph 0.8, first 48
set label "20°C" at graph 0.8, first 22
# Define data
set xdata time
set timefmt "%Y-%m-%d-%H:%M:%S"
set format x "%H"
set xlabel "time"
set ylabel "values"
set yrange [10:80]
heading="Kueche Temperatur und Luftfeuchtigkeit " . timestamp
set title heading
set key reverse Left outside
set grid
set style data lines
plot datafile using 1:2 ls 1 title "",datafile using 1:3 ls 2 title ""
It is working quite well like this, but now I made a node everytime I start cooking or the washing machine and made a file like this:
2016-01-30-15:00:00 cooking
2016-01-22-19:00:00 washing machine
2016-01-23-12:30:00 washing machine
Now I would like to add the following functionality. If there is an entry in the cooking/washing file that falls into the x range of the plot, I want a vertical line from the bottom to the top of the plot with a note that says "cooking" or "washing machine.
Unfortunately I don't even get a vertical line at some point. I tried
set arrow from 15,0 to 15,100 nohead lw 2 lc rgb "#500000" front
and
set arrow from 2016-01-30-19:00:00,0 to 2016-01-30-19:00:00,100 no head lw 2 lc rgb "#500000" front
as well as several other examples I found online, but nothing worked.
Can someone help me in finding a way to
At least draw a vertical line on my time series plot
Or even better, tell me how I can automatically detect if there is a point in the additional file that falls into the x range of the actual plot and add vertical lines according to that file?
Thanks in advance!!

Answer 1

I am not going to reproduce your entire script here, but focus on the part that you are asking about - adding the vertical lines.
I will add the labels at the top of the graph, and doing this will require adding an little bit of extra top margin to make them fit. If you place them in the graph itself, you don't need this extra top margin. Additionally, drawing the vertical lines is made much easier as you have fixed the yrange. We could still make this work without doing that, but we would either need to create a plot, figure out the yrange it used, and then draw the new plot using that computed yrange, or use the stats command to figure it out (we actually will need the stats command later to figure out the xrange). We avoid this by having the fixed yrange.
The minimal set-up that I'll need to demonstrate this is the following:
set xdata time
set timefmt "%Y-%m-%d-%H:%M:%S"
set format x "%m/%d"
set yrange [10:80]
set tmargin at screen .9
unset key
When you weave this into your full script, you can add the additional details (title, axis labels, etc). I also changed the x-axis labels to make it clear that the lines are drawn in the correct place (you will use your original labels). You may need to adjust the offset of the title to avoid a collision between the line labels and the title.
Finally, we can plot the vertical lines and labels with (you'll want to combine this with your existing plot command)
plot datafile u 1:(10):(0):(70) with vectors nohead,\
"" u 1:(80):2 with labels offset 0,char 1.1 rotate by 45
We use the vectors style (help vectors) which expects four values: x, y, x_delta, and y_delta. As we want vertical lines, we set x_delta to 0 and as we range from the bottom (y=10) to the top (y=80) we can set y to 10 and y_delta to 70 (80-10).
The labels are, of course, much simpler. Here we place the label at the top of the graph (moved up by 1.1 characters to place it above the graph) and rotated to avoid overlapping labels.
Unfortunately, there is a problem here. The range from your vertical line file may mess up the range determined from the original file. This can be fixed by using the stats command and then fixing the range. The stats command does not like time series data, but we can manually parse the time series as the first step (before set xdata time).
If we put the following two commands at the very top of the script
stats datafile u (strptime("%Y-%m-%d-%H:%M:%S",strcol(1))) nooutput
set xrange[STATS_min:STATS_max]
it will fix the xrange according to the range in datafile, so we don't have this problem.
Your original example data does not have any overlap with the data you provided for drawing the vertical lines. In order to demonstrate this, I added one extra line to the beginning of your data file,
2016-01-30-12:30:03 30.0 70.2
to force there to be an overlap. Thus taking your original script, adding these extra commands (stats and xrange) at the beginning, and adding the two new plot commands to your existing plot command (which now reads
plot datafile1 using 1:2 ls 1 title "",\
"" using 1:3 ls 2 title "", \
datafile2 u 1:(10):(0):(70) with vectors nohead title "",\
"" u 1:(80):2 with labels offset 0,char 1.1 rotate by 45 title ""
), we obtain
I did not use your set terminal command here, so fonts may look different. You will probably have to do some adjustments of sizes and offsets to produce a final plot that you are happy with, but this adds your original requirements. I also did not add the extra margin here, as the title automatically did that. However, if you need to move the title up to avoid the labels (which I didn't in this example), you will probably have to add some extra margin.