How to call a stored function whose name is returned by another stored function in Oracle plsql? - oracle

Question

I tried to make some version management for the salary computing in our payroll application.
I made a stored function for each formula version according to the legislation that applies at any given time, and then I stored the names of these functions in a table, together with the starting validity date of each function.
Then I made a function that retrieves the name (and returns this name as varchar) of the function applicable for a formula at a given time.
In the view that makes all the computing, I tried to call this function to retrieve the name of the function and use this returned name to call the formula function. All this is made in a select instruction.
I'm trying to call a function whose name is returned by the other function, like:
(function1(param1, param2, ...))(paramx, paramy, ...)
but this doesn't work.
Is there any way to use the name returned by function1 to call the function with that name and with input (parameters paramx, paramy, ...) ?

Answer 1

Functions are not first-class objects which can be returned from other functions, and the name of the function contained in a variable is not the actual code which can be executed. However, you can probably do what you're trying to do by using dynamic SQL:
DECLARE
param1 NUMBER;
param2 VARCHAR2(2000);
function_name VARCHAR2(2000);
paramx NUMBER;
paramy VARCHAR2(2000);
plsql_block VARCHAR2(2000);
result NUMBER; -- assumes the function returns a NUMBER
BEGIN
param1 := 123; -- or whatever is appropriate
param2 := 'abc'; -- or whatever is appropriate
function_name := function1(param1, param2);
-- assume that function_name now contains 'some_function'
paramx := 456; -- or whatever is appropriate
paramy := 'def'; -- or whatever is appropriate
plsql_block:= 'BEGIN :r := ' || function_name || '(:px, :py); END;';
-- plsql_block should now contain 'BEGIN :r := some_function(:px, :py); END;'
EXECUTE IMMEDIATE plsql_block USING IN OUT result, paramx, paramy;
DBMS_OUTPUT.PUT_LINE('result = ' || result);
END;
Best of luck.

Answer 2

If all the functions you might have to call are known and exist when the master function is compiled, then you can use the variable you have to decide which to call. As a very rough outline:
create function master_salary(p_date date)
return number as
l_function_name all_objects.object_name%type;
begin
l_function_name := choose_function(p_date);
case l_function
when 'function_a' then
return function_a;
when 'function_b' then
return function_b(some_arg);
when 'function_c' then
return function_c(some_arg, another_arg);
else
raise_application_error(-20001, 'Unknown function ' || l_function_name);
end case;
end;
/
This avoids dynamic SQL and lets you have functions with different numbers and/or types of arguments, and it's easier to follow what is happening.
If you're adding more functions on the fly then you probably shouldn't be - at least not outside some kind of source control and release mechanism, which would allow you to maintain the master function in step. You could, as a fall back, have the default case try to execute whatever function name you have dynamically (as Bob Jarvis shows) if it isn't one you're expecting; but you'd need consistent argument numbers and data types, and it potentially opens up a vulnerability if the table you get the function name from could be modified.