Why am I getting a syntax error with this CMD script? - windows

Question

I'm trying to write a simple CMD script to automate the build of my repo. Here is the script in its entirety:
#echo off
setlocal
goto main
:: Functions
:buildSubdir
pushd %1
for /f %%projectFile in ('dir /b /s project.json') do (
dnu restore "%%projectFile"
dnu build "%%projectFile"
dnu pack "%%projectFile"
)
popd
goto :EOF
:main
:: Check for dnu
where dnu > NUL 2>&1
if %ERRORLEVEL% NEQ 0 (
echo dnu wasn't found in your PATH! 1>&2
echo See http://docs.asp.net/en/latest/getting-started/installing-on-windows.html for instructions on installing the DNX toolchain on your PC. 1>&2
exit /b %ERRORLEVEL%
)
:: Do the actual work
cd %~dp0
call :buildSubdir src
call :buildSubdir test
Basically, what it does is try to find all the files named project.json in a few select directories (src and test), and execute dnu restore, dnu build, and dnu pack on them.
For some reason, I seem to be getting a syntax error on the line where I enter a for /f loop, saying something about %projectFile not being recognized. Here's a gist of the full output from my terminal when I remove the #echo off statement and re-run the script.
Can anyone tell me why this is happening, and what I can do to fix it? Thanks.
edit: Just changed it to this:
for /f %%p in ('dir /b /s project.json') do (
set projectFile=%%p
dnu restore "%projectFile%"
dnu build "%projectFile%"
dnu pack "%projectFile%"
)
Still doesn't seem to be working, although the error messages are different now. Here's a gist of the new output. (Note how %projectFile% is set to the empty string.)

Answer 1

for /f "delims=" %%p in ('dir /b /s /a-d project.json') do (
dnu restore "%%p"
dnu build "%%p"
dnu pack "%%p"
)
The directory name is assigned to %%p so since that's all you're using, you have no need to assign it further.
The delims= ensures that the entire line is assigned to %%p - otherwise, %%p will be assigned the first token using the default delimiter set, the practical outcome of which is to truncate the name at the first space.
See
for /?
from the prompt for docco.
The /a-d removes any directorynames from the dir output (just in case there is a directory name matching the mask supplied - small possibility though that might be)
If you'd wanted to manipulate the name in %%p rather than just use it as-is, you'd have needed to use either delayedexpansion or called another routine to do the manipulation. The basis of this characteristic is thedelayedexpansion trap- batch will substitute the *parse-time* value of any%var%it finds in a code-block (parenthesised series of statements) for%var% before executing, so since %projectFile% was undefined at the start of the for loop, batch will replace it with nothing which is its value at that time.
For documentation, see many, many articles here related to delayedexpansion or read the scant documentation in
set /?

Answer 2

With the For construct, you use letters as variables: a-z and A-Z (it is important to note that the letters are case-sensitive) in the For construct. There are a number of ways you can use FOR and I would start here - http://ss64.com/nt/for_f.html
You can also FOR /? to get help as needed.
I think you are looking for this:
#echo off
setlocal
goto main
:: Functions
:buildSubdir
pushd %1
for /f %%p in ('dir /b /s project.json') do (
dnu restore "%%p"
dnu build "%%p"
dnu pack "%%p"
)
popd
goto :EOF
:main
:: Check for dnu
where dnu > NUL 2>&1
if %ERRORLEVEL% NEQ 0 (
echo dnu wasn't found in your PATH! 1>&2
echo See http://docs.asp.net/en/latest/getting-started/installing-on-windows.html for instructions on installing the DNX toolchain on your PC. 1>&2
exit /b %ERRORLEVEL%
)
:: Do the actual work
cd %~dp0
call :buildSubdir src
call :buildSubdir test