Issue with VBS Join Domain on Win 7 - vbscript

Question

I have the below vbs to join a Win 7 PC to the domain. On running it does not error but gives no output and does not join domain.
Can anyone see the issue and perhaps suggest how I can add error capturing?
'On Error Resume Next
strDomain = "domain.local"
strPassword = "password"
strUser = "user"
strOU = "OU=OU1,OU=OU2,OU=OU3,OU=OU with spaces in name,DC=domain,DC=local"
Const JOIN_DOMAIN = 1
Const ACCT_CREATE = 2
Const ACCT_DELETE = 4
Const WIN9X_UPGRADE = 16
Const DOMAIN_JOIN_IF_JOINED = 32
Const JOIN_UNSECURE = 64
Const MACHINE_PASSWORD_PASSED = 128
Const DEFERRED_SPN_SET = 256
Const INSTALL_INVOCATION = 262144
Set objNetwork = CreateObject("WScript.Network")
strComputer = objNetwork.ComputerName
' Join Domain
Set objComputer = GetObject("winmgmts:{impersonationLevel=Impersonate}!\\" & _
strComputer & "\root\cimv2:Win32_ComputerSystem.Name='" & _
strComputer & "'")
ReturnValue = objComputer.JoinDomainOrWorkGroup(strDomain, _
strPassword, strDomain & "\" & strUser, strOU, _
JOIN_DOMAIN + ACCT_CREATE + DOMAIN_JOIN_IF_JOINED)
Select Case ReturnValue
Case 0 Status = "Success"
Case 2 Status = "Missing OU"
Case 5 Status = "Access denied"
Case 53 Status = "Network path not found"
Case 87 Status = "Parameter incorrect"
Case 1326 Status = "Logon failure, user or pass"
Case 1355 Status = "Domain can not be contacted"
Case 1909 Status = "User account locked out"
Case 2224 Status = "Computer Account already exists"
Case 2691 Status = "PC already on domain"
Case Else Status = "UNKNOWN ERROR " & ReturnValue
' Show Status
WScript.Echo "Join domain status: " & Status
End Select

Answer 1

You are setting the variable Status inside the case but the line to output it via the WScript.Echo will only show on the Case Else. To fix this move that line after the End Select so you can see the value of Status for all instances of Case.
Select Case ReturnValue
Case 0
Status = "Success"
Case 2
Status = "Missing OU"
Case 5
Status = "Access denied"
Case 53
Status = "Network path not found"
Case 87
Status = "Parameter incorrect"
Case 1326
Status = "Logon failure, user or pass"
Case 1355
Status = "Domain can not be contacted"
Case 1909
Status = "User account locked out"
Case 2224
Status = "Computer Account already exists"
Case 2691
Status = "PC already on domain"
Case Else
Status = "UNKNOWN ERROR " & ReturnValue
End Select
' Show Status
WScript.Echo "Join domain status: " & Status