How can I run redis lua scripts in windows - windows

Question

I came across this article on how to run lua scripts against redis. But this article is geared towards those running on *nix. How can I execute a redis lua script from a windows environment?

Answer 1

Read First:
After doing this and fighting with this script for nearly a week, I decided to try and use one of the java libraries to do the scripting instead. I've created a public repo with that project in it. The benefits are that you are not limited to a ~8000 character input variable and it runs much much faster. I'm going to leave the batch script here for people who absolutely need to do it this way, but I would highly recommend using the java code instead:
Redis Scripting Project
Actual Answer:
Using a batch file I was able to replicate the bash script from that article.
#echo off
setlocal EnableDelayedExpansion
echo Starting removal of keys from redis.
echo KeyMatch: %1
echo Field: %2
echo Script: %3
echo Host: %4
echo Port: %5
REM set the cursor to 0 to begin iterating over matching keys
set cursor=0
:loop
REM call redis scan and output the result to temp.txt
call redis-cli -h %4 -p %5 scan !cursor! match %1 count 180 > temp.txt
REM set the first line of the temp file to the new cursor variable
set /p cursor=<temp.txt
REM outer loop variables
set /A i=0
set keyString=
REM loop through the text file to build the key string
for /F "usebackq delims=" %%a in ("temp.txt") do (
set /A i+=1
REM if we are not on the first line save the key to a space delimted string
if NOT !i! == 1 (
call set keyString=!keyString! %%a
)
)
rem if there is only one line in the file skip the script execution
if !i! LEQ 1 (
goto :checkCursor
)
rem check that the length of keyString will not likely violate the 8192 character limit to command line calls
ECHO !keyString!> strlength.txt
FOR %%? IN (strlength.txt) DO ( SET /A strlength=%%~z? - 2 )
if !strlength! GTR 8000 (
echo.
echo.
echo ****Error processing script. Key string is too long. Reduce the count in call to scan.****
echo.
echo.
GOTO :end
)
REM call the script with the keys from the scan task, output to result.txt to prevent writing to the command line each iteration.
call redis-cli -h %4 -p %5 --eval %3 !keyString:~1! , %2 > result.txt
REM output '.' to the commandline to signify progress
<nul set /p=.
:checkCursor
if not !cursor!==0 (
goto :loop
)
:end
set fileToDelete=temp.txt
if exist !fileToDelete! del /F !fileToDelete!
set fileToDelete=result.txt
if exist !fileToDelete! del /F !fileToDelete!
set fileToDelete=strlength.txt
if exist !fileToDelete! del /F !fileToDelete!
echo Completed script execution
endlocal
you can call this script from the command line like:
batchScriptName keyMatch field luaScriptName.lua host port
batchScriptName myKey* us luaScriptName.lua localhost 6379
If your batch script is not on your path then you will have to call the command from the directory where your file is located. Also with the lua scripts you will need to give the full file path reference or call the batch script from the directory where the lua script is located.
This script is set up to work with hashed values in redis. If you need to alter that, you will likely want to change this line:
call redis-cli -h %4 -p %5 --eval %3 !keyString:~1! , %2 > result.txt
The '%2' passes in the field value to the ARGV array in the lua script and you can remove this if you do not need it. You can also add additional ARGV parameters as needed.