Dynamic where clause in ORACLE - oracle

Question

The requirement is to fetch results from STUDENTS table.
If zero is passed in as student id,no more filtering on the studentid is required.
PROCEDURE getResults (
inStudentId IN NUMBER,
inSectionId IN NUMBER,
inRowLimit IN NUMBER,
outResultsData OUT gphResultsData
) AS
stStudentId VARCHAR2(50) := '';
BEGIN
outResultsData := gphResultsData();
IF inStudentId = '0' THEN
stStudentId := '%';
ELSE
stStudentId := TO_CHAR(inStudentId);
END IF;
FOR rResults IN (
SELECT
RESULTS.STUDENT_ID,
RESULTS.STUDENT_NAME
FROM
RESULTS
WHERE
RESULTS.STUDENT_ID LIKE stStudentId AND -- not a good idea
RESULTS.SECTION_ID = inSectionId AND
ROWNUM <= inRowLimit
) LOOP
outResultsData.extend;
outResultsData(outResultsData.last).studentId := rResults.STUDENT_ID;
outResultsData(outResultsData.last).studentName := rResults.STUDENT_NAME;
END LOOP;
EXCEPTION
WHEN others THEN
...
I have come up with the above solution - which is definitely not ideal as
inStudentId is converted to STRING using TO_CHAR and then subjected to LIKE.
I guess the better way would be to dynamically generate and execute the where clause. That is -
if inStudentId = 0 ,
SELECT
RESULTS.STUDENT_ID,
RESULTS.STUDENT_NAME
FROM
RESULTS
WHERE
RESULTS.SECTION_ID = inSectionId AND
ROWNUM <= inRowLimit
if inStudentId is not zero,
SELECT
RESULTS.STUDENT_ID,
RESULTS.STUDENT_NAME
FROM
RESULTS
WHERE
RESULTS.STUDENT_ID = inStudentId AND
RESULTS.SECTION_ID = inSectionId AND
ROWNUM <= inRowLimit
Any pointer on how to best solve this problem will be a great help.

Answer 1

Assuming you have the types:
CREATE TYPE gphResult IS OBJECT(
student_id INT,
student_name VARCHAR2(50)
);
/
CREATE TYPE gphResultsData IS TABLE OF gphResult;
/
Then you can avoid the loop using BULK COLLECT INTO like this:
PROCEDURE getResults (
inStudentId IN NUMBER,
inSectionId IN NUMBER,
inRowLimit IN NUMBER,
outResultsData OUT gphResultsData
) AS
stStudentId VARCHAR2(50) := '';
BEGIN
SELECT gphResult( STUDENT_ID, STUDENT_NAME )
BULK COLLECT INTO outResultsData
FROM RESULTS
WHERE ( inStudentId = 0 OR student_id = inStudentId )
AND SECTION_ID = inSectionId
AND ROWNUM <= inRowLimit;
EXCEPTION
WHEN others THEN
...

Answer 2

I think the easiest way to do it is the following:
PROCEDURE getResults (
inStudentId IN NUMBER,
inSectionId IN NUMBER,
inRowLimit IN NUMBER,
outResultsData OUT gphResultsData
) AS
BEGIN
outResultsData := gphResultsData();
FOR rResults IN (
SELECT
RESULTS.STUDENT_ID,
RESULTS.STUDENT_NAME
FROM
RESULTS
WHERE
(RESULTS.STUDENT_ID = inStudentId OR inStudentId = 0) AND
RESULTS.SECTION_ID = inSectionId AND
ROWNUM <= inRowLimit
) LOOP
outResultsData.extend;
outResultsData(outResultsData.last).studentId := rResults.STUDENT_ID;
outResultsData(outResultsData.last).studentName := rResults.STUDENT_NAME;
END LOOP;
EXCEPTION
WHEN others THEN
...