xls to csv automate - vbscript

Question

I'm using a script that takes all the xls files in a directory and saves them as a CSV file. I wanted to try and add two modifications to it but not sure how.
First, I'd like to select the save directory as it currently just saves in the workingdir.
Second, I'd like to delete the xls file at the end. I would be ok with this not happening.
Here is the code I'm using:
WorkingDir = "C:\test\excel"
Extension = ".XLS"
Dim fso, myFolder, fileColl, aFile, FileName, SaveName
Dim objExcel, objWorkbook
Set fso = CreateObject("Scripting.FilesystemObject")
Set myFolder = fso.GetFolder(WorkingDir)
Set fileColl = myFolder.Files
Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = False
objExcel.DisplayAlerts = False
For Each aFile In fileColl
ext = Right(aFile.Name,4)
If UCase(ext) = UCase(extension) Then
'open excel
FileName = Left(aFile,InStrRev(aFile,"."))
Set objWorkbook = objExcel.Workbooks.Open(aFile)
SaveName = FileName & "csv"
objWorkbook.SaveAs SaveName, 23
objWorkbook.Close
End If
Next
Set objWorkbook = Nothing
Set objExcel = Nothing
Set fso = Nothing
Set myFolder = Nothing
Set fileColl = Nothing

Answer 1

#Wezel: Please find the code which I change a bit below for your requirement below(The changes which I have done is commented in the name of changed after REM.). The Filename variable which is present is already with the entire path and the mistake which you did is trying to concatenate the a new path with the old one and result the value like this "C:\test\csv\C:\test\excel\samplefile1.xls". So it is throwing a error that path not found. In addition to this I have added a code for your second requirement. Kindly let me know if it works
`WorkingDir = "C:\Test\Excel"
savedir="C:\Test\" REM changed
Extension = ".xls"
Dim fso, myFolder, fileColl, aFile, FileName, SaveName
Dim objExcel, objWorkbook
Set fso = CreateObject("Scripting.FilesystemObject")
Set myFolder = fso.GetFolder(WorkingDir)
Set fileColl = myFolder.Files
Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = False
objExcel.DisplayAlerts = False
For Each aFile In fileColl
ext = Right(aFile.Name,4)
name= Left(aFile.Name,Len(aFile.Name)-3) REM changed
If UCase(ext) = UCase(extension) Then
'open excel
FileName = Left(aFile,InStrRev(aFile,"."))
Set objWorkbook = objExcel.Workbooks.Open(aFile)
SaveName = savedir & name & "csv" REM changed
objWorkbook.SaveAs SaveName, 23
objWorkbook.Close
End If
Next
Set objWorkbook = Nothing
Set objExcel = Nothing
Set myFolder = Nothing
Set fileColl = Nothing
fso.DeleteFile(WorkingDir&"\*"&Extension) REM changed
Set fso = Nothing`