Windows Script (VBS) to always make an application stay open - windows

Question

So an application vital to my business and employees is our Time Clock. It is an exe part of a larger RMS system designed years ago. When you clock in or out, the application automatically closes. I created a Desktop shortcut to make it quicker to open, but I was wondering if there was a way to do this with a Windows Script.
Basic parameters:
Upon startup of the computer, the script is run and the clock.exe application opens
If at any point, clock.exe closes or stops; clock.exe will be reopened by the script.
I messed around with the script myself and managed to have the script open the application, but I tried to use a loop to make it monitor the process which led to many clock applications opening and finally the computer shut down because of overload.
option explicit
DIM strComputer,strProcess
strComputer = "." ' local computer
strProcess = "clock.exe"
' Check if Calculator is running on specified computer (. = local computer)
if isProcessRunning(strComputer,strProcess) then
CreateObject("WScript.Shell").Run("""C:\Users\FrontDesk1\Documents\alwaysClock.vbs""")
else
CreateObject("WScript.Shell").Run("""C:\RMS\pos\clock.exe""")
end if
' Function to check if a process is running
function isProcessRunning(byval strComputer,byval strProcessName)
Dim objWMIService, strWMIQuery
strWMIQuery = "Select * from Win32_Process where name like '" & strProcessName & "'"
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" _
& strComputer & "\root\cimv2")
if objWMIService.ExecQuery(strWMIQuery).Count > 0 then
isProcessRunning = true
else
isProcessRunning = false
end if
end function
CreateObject("WScript.Shell").Run("""C:\Users\FrontDesk1\Documents\alwaysClock.vbs""")

Answer 1

Instead of polling to ask if it's running, track events raised when processes stop, watch for clock.exe stopping and restart it. This should use fewer resources ("tell me when we get there" vs. "are we nearly there yet? are we nearly there yet? are we nearly there yet?"), and respond more quickly (without waiting for the next poll to start).
' Monitor process stop trace events.
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\.\root\cimv2")
Set colProcessStopTrace = objWMIService.ExecNotificationQuery _
("SELECT * FROM Win32_ProcessStopTrace")
Do
Set objLatestEvent = colProcessStopTrace.NextEvent
Wscript.Echo "Test message: process stopped: " & objLatestEvent.ProcessName
if objLatestEvent.ProcessName = "clock.exe" then
CreateObject("WScript.Shell").Run("""C:\RMS\pos\clock.exe""")
end if
Loop
( Adapted from http://www.vbsedit.com/scripts/misc/events/scr_1218.asp )

Answer 2

object.Run(strCommand, [intWindowStyle], [bWaitOnReturn])
So
Set oShell = WScript.CreateObject ("WSCript.shell")
Do
oShell.Run "C:\Folder\Program.exe", 1, true
Loop

Answer 3

You can get inspired by this code from Chancity
A Vbscript to checks the launch of a .bat and .exe programs
Option Explicit
If AppPrevInstance() Then
MsgBox "Instance already running",VbExclamation,"Instance already running"
WScript.Quit
Else
Do
Call Main(Array("c:\toto1.bat","c:\toto2.bat","c:\toto3.bat","%ProgramFiles%\Internet Explorer\iexplore.exe"))
Call Pause(15) 'Pause de 15 minutes
Loop
End If
'**************************************************************************
Sub Main(colProcessPaths)
Dim ProcessPath
For Each ProcessPath In colProcessPaths
CheckProcess(ProcessPath)
Next
End Sub
'**************************************************************************
Sub CheckProcess(ProcessPath)
Dim ProcessName : ProcessName = StripProcPath(ProcessPath)
With GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2")
With .ExecQuery("SELECT * FROM Win32_Process WHERE Commandline LIKE " & CommandLineLike(ProcessName))
If .Count = 0 Then
With CreateObject("WScript.Shell")
.Run DblQuote(ProcessPath)
End With
Else
Exit Sub
End if
End With
End With
End Sub
'**************************************************************************
Function AppPrevInstance()
With GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2")
With .ExecQuery("SELECT * FROM Win32_Process WHERE CommandLine LIKE " & CommandLineLike(WScript.ScriptFullName) & _
" AND CommandLine LIKE '%WScript%' OR CommandLine LIKE '%cscript%'")
AppPrevInstance = (.Count > 1)
End With
End With
End Function
'**************************************************************************
Sub Pause(Minutes)
Wscript.Sleep(Minutes*1000*60)
End Sub
'**************************************************************************
Function StripProcPath(ProcessPath)
Dim arrStr : arrStr = Split(ProcessPath, "\")
StripProcPath = arrStr(UBound(arrStr))
End Function
'**************************************************************************
Function CommandLineLike(ProcessPath)
ProcessPath = Replace(ProcessPath, "\", "\\")
CommandLineLike = "'%" & ProcessPath & "%'"
End Function
'**************************************************************************
'Fonction pour ajouter les doubles quotes dans une variable
Function DblQuote(Str)
DblQuote = Chr(34) & Str & Chr(34)
End Function
'**************************************************************************