Mathematica: Using CheckboxBar to generate a string as a combination of phrases - wolfram-mathematica

Question

I started out with something really long and annoying to write like this
Manipulate[
thetext = Switch[Total[obj],
0, Text["", {0, 5}],
1, Text["How", {0, 5}],
2, Text["Does One", {0, 5}],
4, Text["Use CheckboxBar", {0, 5}],
8, Text["=A=", {0, 5}],
3, Text["How Does One", {0, 5}],
5, Text["How Use CheckboxBar", {0, 5}],
9, Text["How =A=", {0, 5}],
6, Text["Does One Use CheckboxBar", {0, 5}],
10, Text["Does One =A=", {0, 5}],
12, Text["Use CheckboxBar =A=", {0, 5}],
7, Text["How Does One Use CheckboxBar", {0, 5}],
11, Text["How Does One =A=", {0, 5}],
13, Text["How Use CheckboxBar =A=", {0, 5}],
14, Text["Does One Use CheckboxBar =A=", {0, 5}],
15, Text["How Does One Use CheckboxBar =A=", {0, 5}]];
Graphics[thetext],
{{obj, {1, 2, 4, 8}, "Text"}, {1 -> "How", 2 -> "Does One",
4 -> "Use CheckBoxBar", 8 -> "=A="}, CheckboxBar}]
But I quickly realized that I could probably replace 1,2,4,8 with four binary digits, ie 0000 = 0, 1101 = 11 etc. So I wrote this function:
g[{d_, f_, g_, h_}] :=
StringJoin[
If[d == 1, "d", ""], If[f == 1, "f", ""], If[g == 1, "g", ""], If[h == 1, "h", ""]];
which works fine. However, CheckboxBar generates a list that only includes entries that are checked. In Addition to that, the order of the checked entries changes based on which one you check first.
Question: How should i make a function that is much shorter/more concise than what I have right now. preferably with checkboxbar, since it was a requirement in my assignment. Without checkboxbar is ok too, since my assignment isnt graded on how concise my code is. I just want to improve it for the sake of improvement.

Answer 1

CheckboxBar has the (sometimes annoying) property that is will add elements to a list in the order you click the boxes. In order to overcome this limitation, you can add some numbers to the list elements you throw into CheckboxBar and use those number to order the phases. So suppose I have the phases phrases = {"I ", "guess ", "this ", "works?"}, then I want to call CheckboxBar like this:
CheckboxBar[
Dynamic[stringList],
{
{{1}, "I "} -> "I ",
{{2}, "guess "} -> "guess ",
{{3}, "this "} -> "this ",
{{4}, "works?"} -> "works?"
}
]
Next, you can get your string by sorting stringList by the first element (i.e, SortBy[stringList, First]) and then stringing the elements together by Applying (##) StringJoin to the list of strings you want to combine. Putting that all together, I propose this solution:
DynamicModule[{
stringList = {},
phrases = {"I ", "guess ", "this ", "works?"}
},
Column[{
CheckboxBar[
Dynamic[stringList],
MapIndexed[{#2, #1} -> #1 &, phrases]
],
Dynamic[StringJoin ## SortBy[stringList, First][[All, 2]]]
}]
]
edit
You can also handle the sorting in the 2nd argument of Dynamic if you want. That's probably a bit cleaner (though a bit more difficult to understand):
DynamicModule[{
stringList = {},
phrases = {"I ", "guess ", "this ", "works?"}
},
Column[{
CheckboxBar[
Dynamic[
stringList,
Function[{val, expr}, stringList = SortBy[val, First]]
],
MapIndexed[{#2, #1} -> #1 &, phrases]
],
Dynamic[StringJoin ## stringList[[All, 2]]]
}]
]