Checking for a file on remote computers via Batch file - windows

Question

So I have set up an MSI software installation to happen on startup, however, i have noticed certain machines for whatever reason are not installing the package. I followed Microsoft's setup on the MSI install so everything in theory should be fine.
What I want to do is check to see if a specific file is located on a machine or not. I have created a txt file with all of the machines IP addresses and i have tried a for each loop to run through the IP's in the text file and if it exists to output to a log file.
The problem I am running into however, is that all are returning as if the file does not exist and echoing out the else command into my log file. I know for a fact the majority of these IP's (computers) have the file in the directory I specified.
Edit: now it gets stuck if that IP isn't there (I.E. the computer is turned off). Is there anyway to check for that?
ECHO ON
for /F %%a in (ips.txt) do (
set host=%%a
if exist \\%host%\c$\ProgramData\dvsAnalytics\Encore\Config\Encore.ScreenRecording.ClientService.exe.config (
rem file exists
ECHO %%a>>"C:\some location\encore-install-success.log"
) else (
rem file does not exist
ECHO %%a>>"C:\some location\encore-install-fail.log"
)
)
pause

Answer 1

There is no need to use an interim variable host to hold the value of %%a, simply use %%a directly:
for /F %%a in (ips.txt) do (
if exist "\\%%a\c$\ProgramData\dvsAnalytics\Encore\Config\Encore.ScreenRecording.ClientService.exe.config" (
rem ...rest of your code...
)
)
If you insist on the interim variable, you need to use delayed expansion for it as it is set and read in the same block of code; otherwise, you will read the value present when the entire block is parsed. The changed code would look like this:
setlocal EnableDelayedexpansion
for /F %%a in (ips.txt) do (
set "host=%%a"
if exist "\\!host!\c$\ProgramData\dvsAnalytics\Encore\Config\Encore.ScreenRecording.ClientService.exe.config" (
rem ...rest of your code...
)
)
endlocal
In addition, there is a trailing space after set host=%%a in the code in your question; if it is also present in your actual scipt, it becomes part of the variable value and will most likely disturb; to avoid that, the syntax set "host=%%a" should be used.
To check whether a host is available in advance you could use the ping command.
This works reliably for IPv4 addresses:
ECHO ON
for /F %%a in (ips.txt) do (
ping -n 1 -4 %%a 2> nul | find "TTL=" > nul && (
if exist "\\%%a\c$\ProgramData\dvsAnalytics\Encore\Config\Encore.ScreenRecording.ClientService.exe.config" (
rem file exists
ECHO %%a>>"C:\some location\encore-install-success.log"
) else (
rem file does not exist
ECHO %%a>>"C:\some location\encore-install-fail.log"
)
)
)
pause
And this is for IPv6 addresses:
ECHO ON
for /F %%a in (ips.txt) do (
ping -n 1 -6 %%a > nul 2>&1 && (
rem ...rest of your code...
)
)
pause