comparing two files with common file name but want output from the both if matched, how using awk? - shell

Question

I want to compare filenames of Today.txt with Main.txt.
If there is match, then print all 6 columns of matched file of Main.txt and Time column of Today.txt with a new file say matched.txt.
and the files which are not matched with Main.txt, then list the filename and time of TODAY.txt in a new file say unmatched.txt
NOTE: Plus sign(+) indicates files are from inprogress directory,sometimes filenames are appended with "+".
Main.txt
date filename timestamp space count status
Nov 4 +CHCK01_20161104.txt 06:39 2.15M 17153 on_time
Nov 4 TRIPS11_20161104.txt 09:03 0.00M 24 On_Time
Nov 4 AR02_20161104.txt 09:31 0.00M 7 On_Time
Nov 4 AR01_20161104.txt 09:31 0.04M 433 On_Time
Today.txt
filename time
CHCK01_20161104.txt 06:03
CHCK05_20161104.txt 11:10
CHCK09_20161104.txt 21:46
AR01_20161104.txt 09:36
AR02_20161104.txt 09:36
ifs01_20161104.txt 21:16
TRIPS11_20161104.txt 09:16
Required Output:
matched.txt
Nov 4 +CHCK01_20161104.txt 06:39 06:03 2.15M 17153 on_time
Nov 4 TRIPS11_20161104.txt 09:03 09:16 0.00M 24 On_Time
Nov 4 AR02_20161104.txt 09:31 09:36 0.00M 7 On_Time
Nov 4 AR01_20161104.txt 09:31 09:36 0.04M 433 On_Time
unmatched.txt
CHCK05_20161104.txt 11:10
CHCK09_20161104.txt 21:46
ifs01_20161104.txt 21:16
Below command gives me proper output except the 2nd column output of Today.txt, kindly help me on this please ?
awk 'FNR==1{next}
NR==FNR{a[$1]=$2; next}
{k=$3; sub(/^\+/,"",k)} k in a{print; delete a[k]}
END{for(k in a) print k,a[k] > "unmatched.txt"}' Today.txt Main.txt > matched.txt
Thanks a lot in advance !

Answer 1

Assuming that the filenames in today.txt occur only once in the main.tx, you can write an awk script as
$ cat prog.awk
NR==FNR && NR>1{file[$1]=$2; next}
$3 in file{$4 = $4" "file[$3]; print > "matched.txt"; delete file[$3]}
END{for (filename in file) print filename, file[filename] > "unmatched.txt"}
$ awk -F"[ +]*" -f prog.awk today main
-F"[ +]*" Set the field separator as space or +. This will be use full to remove the + from the filenames.