read copy last line from text file - applescript

Question

How to read the last line from a text file and copy part of this line to another text file?
To be more clear lets say that we have a text file (a.txt) containing the text below:
11:22:33 : first line text
11:22:35 : second line text
My need is to copy from the last line "11:22:35 : second line text" only the "second line text" and paste this string to another txt file (b.txt).
Before the paste b.txt file must first be cleared.

Answer 1

It's easiest do delegate this task to a shell command invoked with do shell script:
# Determine input and output file paths.
# Note: Use POSIX-format paths ('/' as the separator).
set inFile to "/path/to/a.txt"
set outFile to "/path/to/b.txt"
# Use a shell command to extract the last line from the input file using `sed`
# and write it to the output file.
do shell script "sed -n '$ s/.*: \\(.*\\)/\\1/p' " & quoted form of inFile & ¬
" > " & quoted form of outFile
Note: The embedded sed command looks like this, with the extra \ instances that are required by embedding it in an AppleScript string removed:
sed -n '$ s/.*: \(.*\)/\1/p'
Using the shell makes for a concise, but somewhat arcane solution.
Here's the AppleScript equivalent, which is easier to read, but also much more verbose:
This variant reads the input file line by line:
# Determine input and output file paths.
# Note: Use POSIX-format paths ('/' as the separator).
set inFile to "/path/to/a.txt"
set outFile to "/path/to/b.txt"
# Read the input file line by line in a loop.
set fileRef to open for access POSIX file inFile
try
repeat while true
set theLine to read fileRef before linefeed
end repeat
on error number -39 # EOF
# EOF, as expected - any other error will still cause a runtime error
end try
close access fileRef
# theLine now contains the last line; write it to the target file.
set fileRef to open for access POSIX file outFile with write permission
set eof of fileRef to 0 # truncate the file
write theLine & linefeed to fileRef # Write the line, appending an \n
close access fileRef
If reading the input file as a whole is acceptable, a much simpler solution is possible:
set inFile to "/path/to/a.txt"
set outFile to "/path/to/b.txt"
# Read the input file into a list of paragraphs (lines) and get the last item.
set theLastLine to last item of (read POSIX file inFile using delimiter linefeed)
# Write it to the target file.
do shell script "touch " & quoted form of outFile
write theLastLine to POSIX file outFile
Note the simplified way of writing to the target file, without needing to open and close the file explicitly.
Also, unlike when using write with a file reference, a trailing newline (\n) is added automatically when you target a file [object] directly.
However, this only works if the target file already exists, which is what the auxiliary do shell script command ensures (via standard utility touch).
If the file didn't exist yet, "casting" the file path to POSIX file would fail.

Answer 2

It's really handy to learn the ins and outs of "open for access". Here's your script:
set sourcePath to (path to desktop as string) & "a.txt"
set destinationPath to (path to desktop as string) & "c.txt"
-- set lastParagraph to last paragraph of (read file sourcePath) -- could error on unix text files
set lastParagraph to last item of (read file sourcePath using delimiter linefeed)
set fileReference to open for access file destinationPath with write permission
try
set eof of fileReference to 0 -- erases the file
write lastParagraph to fileReference
close access fileReference
on error
close access fileReference
end try