Using cscript to output "ipconfig /all" but text file is blank - vbscript

Question

I am trying to pull ipconfig /all output and put it into a text file. I have created a small VBScript that runs ipconfig without issues. Then I call it in another VBScript. All of this runs, but the output text file remains empty and the primary VBScript doesn't seem to write anything after the ipconfig.vbs runs.
Here is the sample from the primary .vbs script:
' Pulling network config
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("C:\Users\dsadmin\Desktop\LogNet\network_config.txt", 8)
set objFile = objFSO.OpenTextFile("C:\Users\dsadmin\Desktop\LogNet\network_config.txt")
objShell.Run("cscript //nologo C:\Users\dsadmin\Downloads\ipconfig.vbs >C:\Users\dsadmin\Desktop\LogNet\network_config.txt")
Here is the script it calls (ipconfig.vbs):
Set objShell = CreateObject("WScript.Shell")
objShell.Run("ipconfig /all")
I'm out of ideas when it comes to shuffling things around.

Answer 1

You have two problems with that approach
As #Ansgar-Wiechers points out the > redirection is part of CMD.
Once the redirection is working you have to retrieve the Standard Output from the executed command and redirect it to the cscript.exe output. Unfortunately .Run() doesn't provide access to the Standard Output Stream you have to use .Exec() instead.
Here is an example (assumes all files in same direction, but can be modified);
' Pulling network config
Set objShell = CreateObject("WScript.Shell")
Call objShell.Run("%COMSPEC% /c cscript //nologo ipconfig.vbs > network_config.txt")
in the ipconfig.vbs
Set objShell = CreateObject("WScript.Shell")
Set exec = objShell.Exec("ipconfig /all")
'Redirect output from executed command to the script output.
Call WScript.StdOut.Write(exec.StdOut.ReadAll)
Output in network_config.txt
Windows IP Configuration
Host Name . . . . . . . . . . . . :
Primary Dns Suffix . . . . . . . :
Node Type . . . . . . . . . . . . :
IP Routing Enabled. . . . . . . . : No
WINS Proxy Enabled. . . . . . . . : No
DNS Suffix Search List. . . . . . :
Wireless LAN adapter Local Area Connection* 2:
Media State . . . . . . . . . . . : Media disconnected
Connection-specific DNS Suffix . :
Description . . . . . . . . . . . : Microsoft Wi-Fi Direct Virtual Adapter
Physical Address. . . . . . . . . :
DHCP Enabled. . . . . . . . . . . : Yes
Autoconfiguration Enabled . . . . : Yes
...
... Truncated for readability and sensitive data removed

Answer 2

Redirection (>) is a CMD builtin feature. You need to run the statement in CMD to be able to use it:
objShell.Run "%COMSPEC% /c cscript //NoLogo C:\ipconfig.vbs >C:\network_config.txt"
Of course you need to ensure that the second script writes to STDOUT in the first place, as #Lankymart pointed out.
If all your second script does is running ipconfig /all there's not much point in wrapping that in a separate script, though. Just run it directly:
objShell.Run "%COMSPEC% /c ipconfig /all >C:\network_config.txt"