My Awk command sorts, but unexpectedly omits duplicates - sorting

Question

Im trying to sort this file by a specific field, and I want to do it all in awk:
"firstName": "gdrgo", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "lastName": "222",dfg
"xxxxx": "John", "firstName": "beto", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "lastName": "111","xxxxx": "John",
"xxxxx": "John", "firstName": "beto", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "lastName": "111","xxxxx": "John",
"xxxxx": "John", "xxxxx": "John", "firstName": "beto2", "xxxxx": "John","lastName": "555", "xxxxx": "John","xxxxx": "John",
"xxxxx": "John", "xxxxx": "John", "firstName": "beto2", "xxxxx": "John","lastName": "444", "xxxxx": "John","xxxxx": "John",
"firstName": "gdrgo", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "xxxxx": "John", "lastName": "222",dfg
"xxxxx": "John", "xxxxx": "John", "firstName": "beto2", "xxxxx": "John","lastName": "444", "xxxxx": "John","xxxxx": "John",
I use this command:
awk -F'.*"firstName": "|",.*"lastName": "|",' '{b[$3]=$0} END{for(i in b){print i}}' sumacomando
which outputs:
111
222
444
555
but I expected:
111
111
222
222
444
444
555
That is, while the actual output is seemingly sorted, as desired, it is unexpectedly missing duplicate values.

Answer 1

The ordering of keys/indices in awk's arrays, which are always associative arrays (dictionaries), is an implementation detail - no particular order is guaranteed; in your case the output just happened to be sorted.
keys are unique, so if $3 in more than 1 input row has the same value, the b[$3]=... assignments overwrite each other - the last one wins.
You therefore:
have to use a sequentially indexed array to store your 3rd field values ($3)
have to sort the resulting array by its values later.
Per the POSIX Awk spec, Awk has no built-in sort functions, but GNU awk does, enabling the following solution with its asort() function:
awk -F'.*"firstName": "|",.*"lastName": "|",' '
{ b[++n]=$3 } END{ asort(b); for(i=1;i<=n;++i) print b[i] }
' sumacomando
Note that this doesn't include storing the associated full lines ($0).
If you also want to store the associated full lines while still performing the sorting in (GNU) Awk, it gets more complicated:
awk -F'.*"firstName": "|",.*"lastName": "|",' '
# Use a compound key to store the value of $3 plus a sequential index
# to disambiguate, and store the input row ($0) as the value.
{ vals[$3,++n]=$0 }
END{
# Sort by compound key using the helper function defined below.
asorti(vals, names, "cmp_func");
# Output the first half of the compound key, i.e., the value of $3,
# followed by the associated input row.
for(i=1;i<=n;++i) print gensub(SUBSEP ".*$", "", 1, names[i]), vals[names[i]]
}
# Helper sort function that splits the compound key into its components
# - $3 value and sequential index - and compares the $3 values alphabetically
# and the indices numerically.
function cmp_func(i1, v1, i2, v2) {
split(i1, tokens1, SUBSEP)
split(i2, tokens2, SUBSEP)
if (tokens1[1] < tokens2[1]) return -1
if (tokens1[1] > tokens2[1]) return 1
i1 = int(tokens1[2])
i2 = int(tokens2[2])
if (i1 < i2) return -1
if (i1 > i2) return 1
return 0
}
' sumacomando
Piping to sort as an alternative solution greatly simplifies matters:
awk -F'.*"firstName": "|",.*"lastName": "|",' '{ print $3, $0 }' sumacomando | sort -k1,1
Note, however, that the pure Awk solution above preserves the input order among duplicate $3 values, which the sort-assisted solution does not.
Conversely, the pure Awk solution needs to store all input in memory at once, whereas the sort utility is optimized to work with large input sets and uses temporary files on demand.

Answer 2

your choice of field separator is unconventional, perhaps better use this instead
awk -F'[:,]' '{for(i=1;i<=NF;i++)
if($i~"\"lastName\"")
{gsub(/"/,"",$(i+1));
print $(i+1)}}' file | sort
if your awk has asort function you can do this instead
awk -F'[:,]' '{for(i=1;i<=NF;i++)
if($i~"\"lastName\"")
{gsub(/"/,"",$(i+1));
a[++c]=$(i+1)}}
END {asort(a);
for(k=1;k in a;k++) print a[k]}' file

Answer 3

#victorhernandezzero: #try: I tried with a different approach, I hope it may help you/all too. With only single awk(no other commands).
awk '/lastName/{getline;while(!$0){getline};A[$0]} END{num=asorti(A, B);for(i=1;i<=num;i++){print B[i]}}' RS='[: ",]' Input_file
EDIT1: Above solution will not give the duplicates which you need, special thanks to mklement0 for letting me know, following may help you in same too.
awk '/lastName/{getline;while(!$0){getline};A[++j]=$0} END{num=asort(A, B);for(i=1;i<=num;i++){print B[i]}}' RS='[: ",\n]' Input_file