How to delimit fixed width text file based upon column number - windows

Question

I have text file which is fixed width. I need to delimit the contents based upon the Column number ( Column 100-120 ) into a variable and need to check length of the variable.
There are chance that variable has more than 20 character and i need to remove that particular line
Eg :
0 1 2 3 4 5 6 7 8 9 0
01234567890123456789012345678901234567890123456789012345678901234567890123456789012345678901234567890
short_name des_shrt px
BOS1111 ALTIC 6.62 2_23 106.37500000
BOS2222 AMA 47.26000000
BOS3333 AMB 12.898000
BOS4444 AMEX Express 10.09780000
BOS5555 BBC 111.2233
BOS6666 CNN 123.123445
BOS7777 STACK OVERFLOW 344.9090
BOS8888 STACT 12.0 2/1988 10.99999999
BOS9999 ABC 20
Output :
px
106.375
47.26
12.898
10.0978
111.2233
123.123445
344.909
10.99999999 -> it exceeds 10 digit and should throw error
20

Answer 1

Here is a pure batch-file solution – see all the explanatory remarks in the code:
#echo off
setlocal EnableDelayedExpansion
rem // Define constants here:
set "_FULL_LINES_OUT=#"
rem // Initialise variables:
set "HEAD=#"
rem // Read text file line by line:
for /F "usebackq delims=" %%L in ("%~1") do (
rem // Store current line into environment variable:
set "LINE=%%L"
rem // Extract 12 characters at character position 58:
set "LINE=!LINE:~58,12!"
rem // Remove trailing spaces, if any:
for /F %%K in ("!LINE!") do set "LINE=%%K"
rem // Check whether line is the first one (header):
if defined HEAD (
rem // Return header line:
if defined _FULL_LINES_OUT (echo %%L) else (echo !LINE!)
set "HEAD="
) else (
rem // Split numbers into integer and fractional parts:
for /F "tokens=1* delims=." %%I in ("!LINE!") do (
set "INT=%%I" & set "FRACT=%%J"
)
rem // Remove trailing zeros from fractional part:
set "FLAG=#"
for /L %%J in (1,1,12) do (
if defined FLAG (
if "!FRACT:~-1!"=="0" (
set "FRACT=!FRACT:~,-1!"
) else (
set "FLAG="
)
)
)
rem // Reassemble truncated decimal number:
if defined FRACT (
set "LINE=!INT!.!FRACT!"
) else (
set "LINE=!INT!"
)
rem // Check whether string length of number exceeds 10:
if not "!LINE:~10!"=="" (
rem // Number is longer than 10 characters:
>&2 (if defined _FULL_LINES_OUT (echo %%L) else (echo !LINE!))
) else (
rem // Number is not too long, so return original line:
if defined _FULL_LINES_OUT (echo %%L) else (echo !LINE!)
)
)
)
endlocal
exit /B
Supposing you name the script check-px-numbers.bat and your data file is called D:\Data\data.txt, run the script like this:
check-px-numbers.bat "D:\Data\data.txt" 2> nul
To write the output into another file D:\Data\filtered.txt, call the script like this:
check-px-numbers.bat "D:\Data\data.txt" > "D:\Data\filtered.txt"
This would return the following output file when using your sample data:
short_name des_shrt px
BOS1111 ALTIC 6.62 2_23 106.37500000
BOS2222 AMA 47.26000000
BOS3333 AMB 12.898000
BOS4444 AMEX Express 10.09780000
BOS5555 BBC 111.2233
BOS6666 CNN 123.123445
BOS7777 STACK OVERFLOW 344.9090
BOS9999 ABC 20
And the following error message would appear in the console window:
BOS8888 STACT 12.0 2/1988 10.99999999
Change the line set "_FULL_LINES_OUT=#" to set "_FULL_LINES_OUT=" (or remove it) if you want your output data to look like this:
px
106.375
47.26
12.898
10.0978
111.2233
123.123445
344.909
20
In case you want to overwrite the original file, you need to do that in two steps:
check-px-numbers.bat "D:\Data\data.txt" > "D:\Data\filtered.txt"
> nul move /Y "D:\Data\filtered.txt" "D:\Data\data.txt"
To write the erroneous lines into a file, use this:
check-px-numbers.bat "D:\Data\data.txt" 2> "D:\Data\errors.txt"
You can combine this to write the filtered and the error lines at once like this:
check-px-numbers.bat "D:\Data\data.txt" > "D:\Data\filtered.txt" 2> "D:\Data\errors.txt"