PLSQL Error : component must be declared - oracle

Question

It is probably a lame error but I do not find it.
In a procedure I have this :
PROCEDURE myProcedure(returnCode OUT NUMBER) IS
CURSOR myCursor IS
SELECT column1, column2, column3, column4 FROM MyTable WHERE columX IS NULL AND columnY = 'PS';
TYPE myType IS RECORD (
name1 MyTable.Column1%TYPE,
name2 MyTable.Column2%TYPE,
name3 MyTable.Column3%TYPE,
name4 MyTable.Column4%TYPE
);
myVar myType;
myVar2 typeA
BEGIN
FOR myVar IN myCursor
LOOP
myVar2 := myVar.name2;
END LOOP;
END;
ERROR :
PLS-00302 component name2 must be declared
What is wrong?
Ty

Answer 1

The myVar cursor loop variable is not related to your myVar record-type variable; it's scope effectively overrides the type definition. You'd get the same error if you removed that type.
From the documentation for cursor for loop:
The cursor FOR LOOP statement implicitly declares its loop index as a record variable of the row type that a specified cursor returns.
and from a related section:
The cursor FOR LOOP statement implicitly declares its loop index as a %ROWTYPE record variable of the type that its cursor returns. This record is local to the loop and exists only during loop execution.
With this syntax, myVar is implicitly the same rowtype as the cursor itself, and has a column2 field rather than a name2 field; so this works:
BEGIN
FOR myVar IN myCursor
LOOP
myVar2 := myVar.column2;
END LOOP;
END;
and the both the myVar variable declaration and myType type declaration are redundant.
To use your record type instead you would need more explicit cursor handling:
BEGIN
OPEN myCursor;
LOOP
FETCH myCursor INTO myVar;
EXIT WHEN myCursor%NOTFOUND;
myVar2 := myVar.name2;
END LOOP;
CLOSE myCursor;
END;
Now myVar is still your myType record type variable - nothing is overriding that - so it has the field names you specified.
You could also explicitly define myVar as myCursor%rowType to avoid needing your own record type, but then it's just a longer way of writing the first loop, and you'd need to go back to referencing myVar.column2.