How to create an artificial circular dependency between targets - visual-studio

Question

I have an executable (game engine) which exports symbols (I've used set_target_properties(game PROPERTIES ENABLE_EXPORTS ON)).
I have a bunch of plugins that link to that executable:
foreach(plugin ${PLUGINS})
target_link_libraries(${plugin} game)
endforeach()
They are loaded dynamically with LoadLibrary/dlopen by the executable.
When I press F5 in Visual Studio and I start the game I don't get the changed plugins rebuilt because the game does not depend on them - it's the other way around.
I wanted to do the following:
foreach(plugin ${PLUGINS})
add_dependencies(game ${plugin})
endforeach()
but it introduces a circular dependency between each plugin and the game. How can I solve my F5 problem?

Answer 1

That's a "chicken-and-egg" problem since the game build will generate the import libraries needed by plugin. So you can't build plugin before game.
I've given your scenario a try and
If I force a rebuild in a POST_BUILD step, I get obviously a recursive build call:
add_custom_command(
TARGET game
POST_BUILD
COMMAND ${CMAKE_COMMAND} --build . --target ALL_BUILD --config $<CONFIG>
)
If I construct a separate target as a "runner" target, I would probably confusing others using my project:
file(WRITE nobuild.cpp "")
add_executable(game_runner nobuild.cpp)
set_source_files_properties(nobuild.cpp PROPERTIES HEADER_FILE_ONLY 1)
set_target_properties(game_runner PROPERTIES OUTPUT_NAME "game")
foreach(plugin ${PLUGINS})
add_dependencies(game_runner ${plugin})
endforeach()
So probably your suggestion of re-using the ALL_BUILD target is the best one. And for auto-generating your required .user settings you may find the following interesting:
CMake add_custom_target(): Run custom command using 'Debug->Start Debugging'
I've used the following to test your scenario:
project(TestPlugins)
file(WRITE main.cpp "int main() { return 0; }")
file(WRITE empty.cpp "")
add_executable(game main.cpp)
set_target_properties(game PROPERTIES ENABLE_EXPORTS ON)
set_target_properties(game PROPERTIES WINDOWS_EXPORT_ALL_SYMBOLS ON)
add_executable(plugin1 empty.cpp)
add_executable(plugin2 empty.cpp)
set(PLUGINS plugin1 plugin2)
foreach(plugin ${PLUGINS})
target_link_libraries(${plugin} game)
endforeach()