How to display current month as text and pass the value? - visualforce

Question

I have tried the second option first without considering your valuable advice but now I have over complicated the idea. I have tried passing the values as a date picker and then split them but that did not help me. I tried the below code and I will explain you the challenge I face now.
// I created a Map to store the values as you specified for different languages.
public map<integer,string> monthmaps(){
map<integer, string> monthMapStatic = new map<integer, string>();
monthMapStatic.put(1, Label.PD_General_Month_Jan);
monthMapStatic.put(2, Label.PD_General_Month_Feb);
monthMapStatic.put(3, Label.PD_General_Month_Mar);
monthMapStatic.put(4, Label.PD_General_Month_Apr);
monthMapStatic.put(5, Label.PD_General_Month_May);
monthMapStatic.put(6, Label.PD_General_Month_Jun);
monthMapStatic.put(7, Label.PD_General_Month_Jul);
monthMapStatic.put(8, Label.PD_General_Month_Aug);
monthMapStatic.put(9, Label.PD_General_Month_Sep);
monthMapStatic.put(10, Label.PD_General_Month_Oct);
monthMapStatic.put(11, Label.PD_General_Month_Nov);
monthMapStatic.put(12, Label.PD_General_Month_Dec);
return monthMapStatic;
}
// Then I ran the below logic but it only runs for current Month.//
for(Integer i=1; i<date.today().month()+1; i++){
this.monthList.add(new SelectOption(String.valueOf(i), monthmaps().get(i)));
}
// I am passing the value as a string to the UI
monthSelection = String.valueOf(date.today().month());
Question: I can't give a Year or I have by default Year passing through, I need past 2 years. Hence the two dropdown option was asked
VF Page:
<apex:selectList value="{!monthSelection}"
multiselect="false" size="1"
styleClass="form-control pull-left monthlyDropDown"
style="height: 33px;">
<apex:selectOptions value="{!monthList}" />
</apex:selectList>
So the question still lies, how can give the option from the Map to the user for selecting Month from previous year.
Here is how they have previously passed the value to string SQL we are trying to pass.
joinQueryMonth += 'AND ((mcc.processing_year__c=\''+ thisMonthDate.year() +'\' AND mcc.processing_month__c=' + thisMonthDate.month() + ') \n';
I hope I am clear this time.

Answer 1

I have considered eyescream first answer and have come up with the following logic
DateTime d = System.now();
for(Integer i = 1; i < 13; ++i){
String label = d.format('MMMM yyyy');
this.monthList.add(new SelectOption(String.valueOf(i), label));
d = d.addMonths(-1);
}
The logic I used to pass it to my SQL query
Integer month_Sel = date.today().month()-(Integer.valueOf(monthSelection)-1);
Integer year_Sel = date.today().year();
if(month_Sel <= 0){
month_Sel = 12+month_Sel;
year_Sel = year_Sel-1;
}
Date thisMonthDate = date.newInstance(year_Sel, month_Sel, 1);
Output for this would be like below
September 2017
August 2017
.
.
October 2016
Now my Query would take the values of year_sel and month_sel and return the year and month selection.
Thanks eyescream for your logic.

Answer 2

The SelectOption function accepts value and label parameters. So you can have more human-friendly label for month but still pass it as a number to Apex.
Here's quite complex demo. See edit history for previous versions & explanation of some of the tricks.
<apex:page controller="StackOverflow45934022">
<apex:form >
<fieldset>
<legend>Single dropdown</legend>
<apex:selectList value="{!monthAndYear}" multiselect="false" size="1">
<apex:selectOptions value="{!monthAndYearOptions}" />
<apex:actionSupport action="{!submitSingle}" event="onchange" reRender="results" />
</apex:selectList>
</fieldset>
<fieldset>
<legend>Two dropdowns</legend>
<apex:selectList value="{!year}" multiselect="false" size="1">
<apex:selectOptions value="{!yearOptions}" />
</apex:selectList>
<apex:selectList value="{!month}" multiselect="false" size="1">
<apex:selectOption itemValue="1" itemLabel="January"/> <!-- You can use itemLabel="{!$Label.PD_General_Month_Jan}" -->
<apex:selectOption itemValue="2" itemLabel="February"/>
<apex:selectOption itemValue="3" itemLabel="March"/>
<apex:selectOption itemValue="11" itemLabel="November"/>
<apex:selectOption itemValue="12" itemLabel="December"/>
</apex:selectList>
<apex:commandButton value="Submit" action="{!submitMultiple}" reRender="results" />
</fieldset>
</apex:form>
<hr/>
<apex:outputPanel id="results">
Month (as integer) : {!m}<br/>
Year : {!y}
</apex:outputPanel>
</apex:page>
public with sharing class StackOverflow45934022{
public Integer m {get;private set;}
public Integer y {get; private set;}
public StackOverflow45934022(){
m = System.today().month();
y = System.today().year();
}
// Single dropdown version start
public String monthAndYear {get;set;}
public List<SelectOption> getMonthAndYearOptions(){
List<SelectOption> ret = new List<SelectOption>();
Date thisMonth = System.today().toStartOfMonth(), januaryLastYear = Date.newInstance(System.today().year() -1, 1, 1);
DateTime d = DateTime.newInstance(thisMonth, Time.newInstance(0,0,0,0));
while(d >= januaryLastYear){
ret.add(new SelectOption(d.format('MM-YYYY'), d.format('MMMM YYYY'))); // you will use your map with month names to build labels
d = d.addMonths(-1);
}
return ret;
}
public void submitSingle(){
if(String.isNotBlank(monthAndYear) && monthAndYear.contains('-')){
List<String> temp = monthAndYear.split('-');
m = Integer.valueOf(temp[0]);
y = Integer.valueOf(temp[1]);
}
}
// Single dropdown version end
public String year {get;set;}
public String month {get; set;}
public List<SelectOption> getYearOptions(){
Date today = System.today();
String y0 = String.valueOf(today.year()), y1 = String.valueOf(today.year() -1);
return new List<SelectOption>{
new SelectOption(y0, y0),
new SelectOption(y1, y1)
};
}
public void submitMultiple(){
m = Integer.valueOf(month);
y = Integer.valueOf(year);
}
}