I'm new to AppleScript and I'm trying to make a simple AppleScript that will pop-up a dialog asking for user input and based on the input it will open one application or another. To do this I've used:
tell application "atom"
activate
end tell
One of the applications is stored on an external hard drive called Tardis. The problem with my code below is that it automatically opens Atom every time I run the script AND the dialog window at the same time. I only want it to open Atom when the input a is given. Thanks for the help! Code is below:
on run {input, parameters}
set inputText to text returned of (display dialog "Options: p - a - j" default answer "")
set p to "p"
set a to "a"
set j to "j"
if (inputText = p) then
tell application "Terminal"
if it is running then
do script "cd Python_Workspace; source ~/tensorflow/bin/activate"
end if
activate
end tell
tell application "Finder" to open POSIX file "/Volumes/Tardis/EXTRA Applications/Sublime Text.app"
end if
if (inputText = a) then
tell application "Atom"
activate
end tell
tell application "Terminal"
if it is running then
do script ""
end if
activate
end tell
end if
if (inputText = j) then
tell application "Terminal"
if it is running then
do script "cd /Java_Workspace"
end if
activate
end tell
tell application "IntelliJ IDEA CE"
activate
end tell
end if
return input
end run
So some applications that support Applescript do - or did, require the application to launch to compile the Applescript at all (if I remember correctly these are applications that support Applescript poorly, which I'm betting is Atom).
This may not be exactly what's happening, especially since if you are launching a compiled Applescript, but maybe you are running a .applescript (text) file.
What I would do, instead of tell application "Atom" to activate (a one line version of what you have), instead: activate application "Atom".
If that does work for you, activate vs tell here's what's going on:
Applescript notices you're talking about Atom. It needs a dictionary to translate your typing into... events.
Applecript can't find the dictionary, so it launches the application, hoping that it can get more information from it when it launches
Atom launches, Applescript realizes that every application supports activate.
Where activate application you're not trying to do anything Atom specific... just activate an app. No dictionary lookup required.
(It's also worth noting that I've been doing this a very long time. I could actually be quoting you information that's a decade or more out of date, or "new" in 10.4 - not 10.14, but 10.4)
I am get the following error when I try to set miniaturized of a window to false/true for an application whose name I supply as a variable.
set x to "Safari"
tell application x to set miniaturized of the front window to false
ERROR
miniaturized-safari.scpt:40:85: execution error: Safari got an error:
Can’t make |miniaturized| of window 1 into type specifier. (-1700)
while I don't get any error when I try the following
tell application "Safari" to set miniaturized of the front window to false
AppleScript terminology is evaluated at compile time.
This is the reason why applications specified in tell blocks must be constants.
I have found this solution that is working for me:
tell application (path to frontmost application as text)
reopen -- unminimizes the first minimized window or makes a new default window
end tell
Works for Finder as well. Anyway there are apps it is not working for (eg. Office).
I have a function where I pass in the name of an application. Within the function, one of the things I'd like to do is restore the windows of the application:
on test(applicationName)
-- do some work
-- restore all windows
-- do some more work
end test
I've found references on how to restore the windows of an application by setting the miniaturized property, ala:
tell application "Maps"
set miniaturized of windows to false
end tell
(see Un-minimizing an app with Applescript)
But this requires one to specify the name of the app at compile time - I have to hard code the name of the app into the code - I can't use "tell application applicationName" even though applicationName is a string:
on test(applicationName)
-- do some work
-- restore all windows
tell application applicationName
set miniaturized of windows to false
end tell
--- do some more work
end test
(see tell application - string vs. string?)
Is it possible to restore the windows of an application, when I reference the name of the application as a variable?
There must be another way to do this, but the only examples I've found to do this is the "tell application/set miniaturized of windows" approach.
You might have more success using System Events to access the attributes of application process windows to control their miniaturised states.
Unlike trying to do it via the application objects themselves, the applications in question do not need to be AppleScript-able. I believe all processes running under System Events that contain windows have a set of attributes that are accessible via AppleScript, including one called AXMiniaturized, whose value is either true or false.
Although I didn't attempt to diagnose the problem with your method, I did draft this method (albeit on MacOS 10.13), which appears to corroborate what I've said. Hopefully the script is pretty self-explanatory:
use application id "com.apple.systemevents"
to getProcessesWithMiniaturizedWindows()
return the name of (every process whose value of ¬
attribute "AXMinimized" of every window ¬
contains true)
end getProcessesWithMiniaturizedWindows
to restoreAllWindowsForProcess:(procName as text)
local procName
set value of attribute "AXMinimized" of (every window ¬
of the process named procName whose value of ¬
attribute "AXMinimized" = true) to false
end restoreAllWindowsForProcess:
on run
repeat with processName in getProcessesWithMiniaturizedWindows()
restoreAllWindowsForProcess_(processName)
end repeat
end run
NB. You may need to grant Assistive Access Rights for System Events in System Preferences > Security & Privacy > Privacy > Accessibility (High Sierra).
The simple and straightforward solution would be this:
on test(applicationName)
-- do some work
-- restore all windows
tell application "System Events"
tell process applicationName
tell every window
set value of attribute "AXMinimized" to false
end tell
end tell
end tell
--- do some more work
end test
Running: OSX 10.11.3
So I have the script below. It is a naive hack to build an html link string based on the selected text and current url of a Firefox window. It's fragile but works ok.
However if I have Tor Browser running in addition to Firefox and open the script in Script Editor, I see that the code has been changed to reference Tor Browser:
tell application "TorBrowser" to activate
Yikes! I know Tor Browser is based on Firefox – but it seems to have its own process ID (confirmed in Activity Monitor). Even if it didn't why and how is the code being changed? I've tested this numerous times:
Without Tor Browser running: code doesn't change
Based on its "modified date" it is not being changed after I close it in Script Editor. (i.e. save it at 11:10, leave the window open until 11:12)
Duplicate script. Launch one copy with Tor Browser running: script is changed. Quit Tor Browser and launch second copy: script is not changed. There is no prompt to save the changed file when closing it.
Does anyone know what is going on? This seems very bizarre. Is there a workaround?
tell application "Firefox" to activate
delay 0.3
tell application "System Events"
tell process "Firefox"
keystroke "c" using command down
delay 0.1
end tell
set theHeadline to the clipboard
delay 1
tell process "Firefox"
keystroke "l" using command down
delay 0.1
keystroke "c" using command down
delay 0.1
set theUrl to the clipboard
end tell
set tagStart to "<a href ="
set tagMiddle to "><b><u>"
set tagEnd to "</u></b></a>"
set tag to tagStart & "\"" & theUrl & "\"" & tagMiddle & theHeadline & tagEnd
set the clipboard to tag
end tell
From the info.plist files, the CFBundleExecutable of these applications is "firefox", and the CFBundleSignature is "MOZB", maybe this causes this issue.
To avoid this, use the bundle identifier of the application in your script:
tell application id "org.mozilla.firefox" to activate
-- the bundle identifier of the "Tor Browser" application is "org.mozilla.tor browser"
Since the name of the processes is the same, use this:
tell application "System Events"
tell (first process whose its bundle identifier is "org.mozilla.firefox")
keystroke "c" using command down
delay 0.1
end tell
end tell
First I would recommend a couple of simple changes to your script. When you're working with system events, there is no need to use tell process within the system events block.
tell application "Firefox" to activate
delay 0.3
tell application "System Events"
keystroke "c" using command down
delay .1
set theHeadline to the clipboard
keystroke "l" using command down
delay 0.1
keystroke "c" using command down
delay 0.1
set theUrl to the clipboard
end tell
set tagStart to "<a href ="
set tagMiddle to "><b><u>"
set tagEnd to "</u></b></a>"
set tag to tagStart & "\"" & theUrl & "\"" & tagMiddle & theHeadline & tagEnd
set the clipboard to tag
end tell
Back to your original question, your compiler (Script Editor) is trying to correct your mistake. It assumes that your are meaning Tor since it sees that running. You and I know you really mean FireFox, but it assumes you've made a mistake. The good news is once you compile it and save it as an app, this shouldn't be an issue. Just make sure when you compile and save that you don't have Tor running and I believe you should be fine.
Btw... You'll see similar behavior if you were to change FireFox to to FoxFire or something else. It will usually prompt you to select the application, then you'd have to navigate to FireFox.
please forgive formatting, writing this on my phone
Consider the following AppleScript:
on is_running(appName)
tell application "System Events" to (name of processes) contains appName
end is_running
set safRunning to is_running("Safari")
if safRunning then
tell application "Safari"
-- Stuff I only want executed if Safari is running goes here.
end tell
return "Running"
else
return "Not running"
end if
The problem: when I run this via the osascript command line utility, if Safari is not running, it gets launched and the script reports "Running". This is not the behaviour I desire or would expect. Note that it works as desired/expected when run within AppleScript Editor.
Is this an osascript bug / known issue? Or is it somehow intended behaviour for reasons I'm missing? Can anyone get it to work as desired? (BTW I'm running OSX 10.7.5; I can't see how to get osascript to report a version number).
If you comment out the tell / end tell lines, it behaves as I'd expect: if Safari is not running, it doesn't launch it, and prints "Not running". So it seems to me like the tell is what's causing Safari to be launched, but it doesn't need to be actually executed, just present in the script...? For a while I wondered if maybe this was just how tell is supposed to work, but since it doesn't work like this in AppleScript Editor, I guess not...
In fact, here's another, madder, version with similar behaviour:
on is_running(appName)
tell application "System Events" to (name of processes) contains appName
end is_running
set safRunning to is_running("Safari")
return safRunning
if false then
tell application "Safari"
end tell
end if
This still always launches Safari, even though tell is inside an if false block after the return statement! (But again, this is fine in AppleScript Editor.)
BTW, this behaviour isn't limited to Safari, but it also isn't universal:
Affected apps include: Safari, TextEdit, iPhoto, AppleScript Editor, iTerm, ...
Non-affected apps include: Google Chrome, iTunes, Preview, Mail, Terminal, Address Book, Echofon, ...
So, does anyone have any ideas about how I might fix or route around this? Is it an osascript bug? Or am I missing something about AppleScript's semantics?
For context: I'm trying to write a script (to be embedded/called from some python) which queries open browsers for the URLs of any tabs they have open; I've got it all working fine except that it always launches Safari, whether it's open or not. I've boiled down that undesirable behaviour to the simple test case shown above. I'm not aware of any way to run this script from python without using osascript, other than appscript, which I don't want to use because it's no longer developed/supported/recommended.
Many thanks for all inputs / insights!
I suspect the reason you are getting this is because each time you call the script from the command line with osascript the script is being compiled.
The act of compiling on a tell application will afaik make the app launch.
Calling the script from the command line with osascript from a pre-compiled file i.e .scpt does not cause this behaviour because the is no compiling to be done.
But calling it from a plain text (.txt,.sh ) file will so the app will launch.
If you do not want to use a .scpt file and want to use a plain text file then you could try the trick of putting a run script command in the applescript.
on is_running(appName)
tell application "System Events" to (name of processes) contains appName
end is_running
set safRunning to is_running("Safari")
if safRunning then
run script "tell application \"Safari\"
open location \"http://google.com\"
end tell"
return "Running"
else
return "Not running"
end if
The script in the run script is only compiled when needed. You will need to escape any characters like quotes as in my example.
It will be easier if you write the script in a normal applescript document first and compiled it to check for errors.
Then copy it to the plain text file.
UPDATE **
The method I used above was from a old script I had used to solved this issue a while before I answered here.
The answer works and is not trying to be elegant. ;-)
I actually like user1804762 method below. As it does work but feel the Answer is not clear enough so I will give an example on using it.
set appName to "Safari"
if application appName is running then
tell application id (id of application appName)
open location "http://google.com"
end tell
return "Running"
else
return "Not running"
end if
This script can be run from the command line with osascript
example:
osascript /Users/USERNAME/Desktop/foo.scpt
Notice that the script is saved as a compiled script. This will work ok and you can also save and use it as a plain text script.
i.e.
osascript /Users/USERNAME/Desktop/foo.applescript
Some Info:
"Enhanced Application Object Model":
tell application "iTunes"
if it is running then
pause
end if
end tell
You can also do it that way:
if application "iTunes" is running then
tell application "iTunes" to quit
end if
You can also do this:
get name of application "iTunes"
get version of application "iTunes"
And to complete the journey:
get id of application "TextEdit" --> "com.apple.TextEdit"
tell application id "com.apple.TextEdit"
make new document
end tell
That was the "Enhanced Application Object Model". If an app still launches (for example, the first time you compile & execute the script) I assume it is because AS has to get some info from the app which it did not found in the dictionary (or something like that...?).
OK, I know this question is really old, but I stumbled on it looking for a different issue and had to pipe in considering how complicated some of these responses are.
The simple code to achieve what you want(ed) is:
tell application "System Events"
if application process "Safari" exists then
-- do stuff you want to do only if Safari exists
end if
end tell
On older systems, the syntax used to be:
tell application "System Events"
if exists of application process "Safari" is true then
-- do stuff you want to do only if Safari exists
end if
end tell
One of these should definitely work for you, intrepid searcher of Applescript solutions for action only when an app is running.
Oh! Bonus tip: And if you're not sure what the application process name is exactly (it is usually but not always the app name), before coding your final script run…
tell application "System Events"
get every application process
end tell
And find your app process name in the results.
Here's a screen grab of running that command. (Note the zillions of Google Chrome Helper instances. Thanks Google!)
HTH!
tell application "Finder"
set applicationsnames to get the name of every process whose visible is true
end tell
set appName to "Safari"
if applicationsnames does not contain appName then
say (appName & " is not running")
--add here what you want to happen
end if
return applicationsnames
This is returning {"Finder", "JavaAppLauncher", "firefox", "Microsoft Word", "iTunes", "AppleScript Editor"} for me
Hope this helps
All the previously made answers suffer from the same issue, though:
They look for the app by its name. However, the user may rename the app, and then the script will believe the app does not run, when in fact it does.
To properly check for a running app, it should be found by its bundle ID, which the user cannot change.
The bundle ID can be inquired with this command, for instance, when the app is already running:
tell application "System Events"
get bundle identifier of application process "Safari"
end tell
Or like this for any installed app:
get id of application "Safari"
To check whether an app with a particular bundle ID is running, use this code:
tell application "System Events"
set ids to bundle identifier of every application process
if ids contains "com.apple.safari" then
return "Running"
else
return "Not running"
end if
end tell
Furthermore, here's an example to check if an app is running, then quit it, then relaunch it, ensuring that the very same app is relaunched that was running before, and not some other copy that may also exist:
set bundleID to "com.apple.safari"
set apps to runningApps(bundleID)
set appCount to length of apps
if appCount is not 0 then
quit application id bundleID
repeat while length of runningApps(bundleID) = appCount
-- wait for the app to quit
end repeat
open first item of apps
end if
on runningApps(bundleID)
-- The try block is to catch the rare case of having more than one
-- copy of an app running at the same time. Unfortunately, in that
-- case this code will not run as expected, because we don't get the
-- correct list of multiple items back then. But at least the script
-- will not crash from it but handle it gracefully.
tell application "System Events"
try
return application file of (every application process whose bundle identifier = bundleID)
end try
end tell
return {}
end runningApps
I had the same problem as described here trying to set up an AppleScript (triggered by a BetterTouchTool gesture) that plays/pauses VLC or iTunes, but only iTunes if VLC is not running (due to my workflow) and, naturally, only VLC while it's running. (I use the automatic pause/play trigger for iTunes in VLC's settings, for launch and quit of the app.)
VLC was always launched on the first use of the BetterTouchTool-trigger after every relaunch of BTT as the dictionary-cache is deleted at that point and the AppleScript handler has to launch every scripted application if a tell is aimed at it in order to call its dictionary.
I didn't find anything that avoided this anywhere; there were some attempts, but none worked for me as the dictionary-call by the script handler is nothing we can influence. I came up with this dirty workaround:
Create a separate AppleScript file only containing the line that includes the tell for VLC
Save it at some place where it won't annoy you
Replace the line containing the tell in the original AppleScript with a line that runs that script
This will lead to the first compilation of the script not calling the application (VLC, in my case) directly, only the script, which means that the application will not need to launch.
VLC will need to launch once that separate file is called, but, well, if you call that file in order to tell VLC something, you will have VLC already opened (or will want it open) anyway.
The AppleScript I call through my BetterTouchTool-trigger (a specific tap on the trackpad, in my case) looks like this:
if application "iTunes" is running and not application "VLC" is running then
tell application "iTunes" to playpause
end if
if application "VLC" is running then
run script "/Users/jannis/bin/PlayVLC.scpt"
end if
The separate AppleScript file ("PLayVLC.scpt, saved in a folder called "bin" in my user folder which I created manually ages ago for such purposes) is just this:
tell application "VLC" to play
If you open that script manually, it will of course also launch VLC. But that hopefully won't be necessary often, or ever.
I actually have no idea if this creates any deeper problems I don't know of as I'm not a pro coder; if so, please notify me. I hope this helps anyone!