delete first 5 lines and last 2 lines from txt - windows

Question

Need to delete the first 5 lines and the last 2 lines of a txt file using a bat, been trying with a script that works on win 10 but not on win server 2012 r2.
Any idea why?
heres the script, i have
#echo off
setlocal EnableDelayedExpansion
set "FileToModify=getdoc.txt"
if not exist "%FileToModify%" goto:leavenow
set "TempFile=%TEMP%\FileUpdate.txt"
if exist "%TempFile%" del "%TempFile%"
if exist newFile.txt del newFile.txt
if exist Testfinal.txt del Testfinal.txt
if exist Test1.txt del Test1.txt
if exist myOriginalFile.txt del myOriginalFile.txt
set "Line=0"
for /F "useback delims=" %%L in ("%FileToModify%") do (
if !Line! GTR 4 (
echo %%L>>"%TempFile%"
) else (
set /A Line+=1
if !Line! GTR 4 echo %%L>>"%TempFile%"
)
)
copy /Y "%TempFile%" "%FileToModify%" >nul
set row=
for /F "delims=" %%j in (%FileToModify%) do (
if defined row echo.!row!>>Test1.txt
set row=%%j
)
set row=
for /F "delims=" %%j in (Test1.txt) do (
if defined row echo.!row!> Testfinal.txt
set row=%%j
)
echo { > newFile.txt
type %FileToModify% >> newFile.txt
type newFile.txt > getdoc.txt
del FileUpdate.txt
del newFile.txt
del Testfinal.txt
del Test1.txt
:leavenow
echo no file to clean!!!!
pause
exit
Ps- im sure there is a simple way to do this thanks

Answer 1

I suggest to use the following commented batch file for this task:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "FileToModify=getdoc.txt"
if not exist "%FileToModify%" (
set "ErrorMessage=No file "%FileToModify%" to clean"
goto ErrorOutput
)
rem Get number of lines in file to modify by searching with FINDSTR for begin
rem of line which is true for every line in the file. Output by FINDSTR is the
rem line number a colon and the line itself for each line in file. For interest
rem is here just the line number left to first colon from last output line.
for /F "delims=:" %%I in ('%SystemRoot%\System32\findstr.exe /N /R "^" "%FileToModify%"') do set "LastLineNumber=%%I"
rem Has the file at least 8 lines to remove five lines at top and two
rem lines at bottom and have finally a file with at least one line?
if %LastLineNumber% LSS 8 (
set "ErrorMessage=File "%FileToModify%" has less than 8 lines"
goto ErrorOutput
)
rem Decrement the number of last line because the
rem last two lines should be removed from the file.
set /A LastLineNumber-=1
rem Derive name of temporary file to create in folder for temporary files
rem from name of file to modify by replacing its file extension by "tmp".
for %%I in ("%FileToModify%") do set "TempFile=%TEMP%\%%~nI.tmp"
rem Make sure the temporary file does not already exist from a previous
rem run of this batch file broke during processing by command interpreter.
del "%TempFile%" 2>nul
for /F "skip=5 tokens=1* delims=:" %%I in ('%SystemRoot%\System32\findstr.exe /N /R "^" "%FileToModify%"') do (
if %%I == %LastLineNumber% goto ReplaceFile
echo/%%J>>"%TempFile%"
)
:ReplaceFile
move /Y "%TempFile%" "%FileToModify%" 2>nul
if errorlevel 1 (
del "%TempFile%"
set "ErrorMessage=File "%FileToModify%" is write-protected"
goto ErrorOutput
)
endlocal
exit /B
:ErrorOutput
cls
echo %~f0
echo/
echo Error: %ErrorMessage%.
echo/
pause
Note: This batch file does not produce the right output for a file containing lines starting with 1 or more : because on second FOR option delims=: is used which results in splitting up such lines in line number output by FINDSTR assigned to loop variable I and everything after 1 or more colons assigned to loop variable J being the next character in ASCII table after specified loop variable I.
But this batch file handles files containing command line critical characters like &()[]{}^=;!'+,`~|<> well.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
call /? ... explains %~f0 (name of batch file with file extension and full path).
cls /?
del /?
echo /?
endlocal /?
exit /?
findstr /?
for /?
goto /?
if /?
move /?
pause /?
rem /?
set /?
setlocal /?
See DosTips forum topic ECHO. FAILS to give text or blank line - Instead use ECHO/ to understand why echo/ is used instead of echo. in batch file.