Get windows with same process name but different pid in AppleScript - applescript

Question

I have know how to get pid from same application process
set pidList to the unix id of (every process whose name contains "MyApplication")
The pidList will get all the process id which have same process name "MyApplication"
How can I get different window with pid that gotten before?
The windows have same name "MyApplication Window" ,so I can't use below simply.
The application is open by cmd open -n(Separate instances of the same application)
eg:
set position of window "MyApplication Window" of (application process whose unix id is theItem) to {39, 578}
Thanks for any help.

Answer 1

I'm attempting to understand what you're trying to achieve, but it is difficult given lack of clear context and knowing where those code snippets have been taken from and how they're being used.
However, I'm answering on my assumption that you have two (or more) windows with the same name or title, and wish to know how to isolate one of these windows in order to set its position.
Proceeding along this basis, you can use AppleScript to reference windows not only by their title (name), but also by a property called the window id.
Firstly, don't use System Events for this. Send your commands directly to the application in question using tell application "MyApplication" to...
So, for example, I have two open Finder windows both called "Pictures". But when I run this:
tell application "Finder" to get every window
it returns this:
{Finder window id 10557 of application "Finder",
Finder window id 10786 of application "Finder"}
Get the properties of one of these windows like this:
tell application "Finder" to get properties of window id 10557
A useful property in this list is index: this determines the front-to-back order of the windows, with index 1 being the front window, and index 2 being the one behind it, and so on.
You can isolate the window you want by choosing any of these properties, and setting its position like this:
tell application "Finder" to set position of window id 10557 to {39, 578}
or like this:
tell application "Finder" to set position of window index 1 to {39, 578}
Bear in mind that a window's index will change according to which is at the front at any given time. However, the id will remain unique and the same, until the window is closed and re-opened, at which point it gets issued a new id.
It may also be helpful to know the id (which is an integer) will have a value that tells you the order in which the windows were created: the window created most recently will have an id of greater numeric value than those that came into existence before it.

Answer 2

You must use a tell (first process whose unix id is someID) block.
Here's an example:
set thePosition to {39, 578}
tell application "System Events"
set pidList to the unix id of (processes whose name contains "MyApplication")
repeat with someID in pidList -- loop
tell (first process whose unix id is someID)
set position of window "MyApplication Window" to thePosition
end tell
set item 1 of thePosition to (item 1 of thePosition) + 200 -- add 200 to the left (for the next window)
end repeat
end tell

Answer 3

I'm adding a second answer as I gather now what you wish to achieve is to obtain references to the windows that belong to separate, concurrently running instances of a single application, opened using open -n from Terminal
So I just went ahead and did the same thing. I launched a second instance of Script Editor from Terminal, and each of them have a window called "Untitled". I've opened up another document in one of the instances (so one instance has two windows, and the other has just one). I've retrieved the windows of both instances like this:
tell application "System Events" to get every window of ¬
(every process whose name is "Script Editor")
--> {{window "Untitled" of application process "Script Editor" of application "System Events", ¬
window "Import To Photos" of application process "Script Editor" of application "System Events"}, ¬
{window "Untitled" of application process "Script Editor" of application "System Events"}}
It returns a list, but inside this list are nested two separate lists—one for each instance of Script Editor—and inside those lists are the windows belonging to each instance. As you'd expect, one list has one item (because on instance of the application has just a single window, called "Untitled"), and the other list has two items (for its two windows, one of which is also called "Untitled").
But if I'm only interested in the windows called "Untitled", then I could run this:
tell application "System Events" to get window "Untitled" of ¬
(every process whose name is "Script Editor")
--> {window "Untitled" of application process "Script Editor" of application "System Events", ¬
window "Untitled" of application process "Script Editor" of application "System Events"}
Just a single list this time, with my two seemingly-identical windows.
Distinguishing between them can be done as you hinted at in your original question by using the unix id of the application processes:
tell application "System Events" to get [window "Untitled", unix id] of ¬
(every process whose name is "Script Editor")
--> {{window "Untitled" of application process "Script Editor" of application "System Events", ¬
window "Untitled" of application process "Script Editor" of application "System Events"}, ¬
{73822, 73913}}
You can also use the processes' id property instead of their unix id, which has the benefit of being easily referenced if you want to target one of the windows in a single line. id and unix id are distinct properties, and unique:
tell application "System Events" to get [id, unix id] of ¬
(processes whose name is "Script Editor")
--> {{42006541, 42100772}, {73822, 73913}}
So I can target a specific window of a specific instance like this:
tell application "System Events" to ¬
get window "Untitled" of process id 42006541
--> window "Untitled" of application process "Script Editor" of application "System Events"