Applescript. Get properties of all instances - applescript

Question

I have many instances of VLC open. I want to check the playing status of every instance like:
tell application "VLC"
if playing = true then return
end tell
But it checks only one instance of VLC. How can I check all instances?

Answer 1

This is a workaround answer based on your comment "I want to prevent a scheduled applescript to execute if a VLC instance is playing." and the other information that has been presented in other comments and answer posted prior to this one. Also, by execute, I'm assuming you mean execute any additional code in the script that started on schedule.
Also note, this may not be perfect however its being presented to give it a try.
On my system, when an occurrence of VLC is open and without content loaded, after the initial percent of CPU usage spikes it quickly settles to 0% and with content loaded but not playing it's less than 5% and typically less than 3%. If it's playing it's typically always greater than 5%.
This of course may vary on your system, so you'll need to monitor over a period of time polling CPU usage to see how it fluctuates on your system to see what the sweet spot is.
The following example AppleScript code when placed at the beginning of the code in the scheduled AppleScript, prior to code in your script to trigger whatever with VLC, will abort processing the rest of the script if the percent of CPU usage of other instances of VLC is equal to or greater than 5%.
set |VLC%CPU| to paragraphs of text of ¬
(do shell script "ps -Ac -o %cpu -o command | grep [V]LC ; exit 0")
repeat with thisItem in |VLC%CPU|
if first word of thisItem as integer ≥ 5 then return
end repeat

Answer 2

Another method could be to rename the instances by making copies of the application, and giving them new names such as VLC1, VLC2. You can do this by going to the applications folder and copying the VLC Application. Then paste it within the same folder to create the app "VLC copy". Then rename each copy you create. The copies will now show in the applescript dictionaries.
You can now use a tell block for each instance to check if it's playing. You just need to make sure that you open the correct instance numbers for the number you have playing. E.g. don't open "VLC1" and "VLC3" if you only have 2 instances, or close a lower instance number. By having the if c is equal to statement it won't open that instance of the application by executing the tell block.
If you have all instances open you could remove the loop and the if statements and just check if they're playing or not.
on getCount()
tell application "System Events"
set p to processes whose name contains "VLC"
set theCount to count of p
return theCount
end tell
end getCount
set appCount to my getCount()
if appCount is greater than 0 then
repeat with c from 1 to appCount
if c is equal to 1 then
tell application "VLC1"
if playing is true then
log ("playing 1")
end if
end tell
end if
if c is equal to 2 then
tell application "VLC2"
if playing is true then
log ("playing 2")
end if
end tell
end if
end repeat
end if

Answer 3

So far the half solution I do is:
tell application "System Events"
if (name of application processes whose frontmost is true) = {"VLC"} then return
end tell
So I check is it frontmost. Usually if I run a movie it is frontmost. I would prefer the "is playing" variation but... ok, what can I do.

Answer 4

I think I'm understanding the nature of your query more now. I was previously a little confused about what your objective was, but now I'm gathering it's simply to determine whether any VLC instance is playing or not. Is that correct ?
But that you do not need to know what is playing or in which window it's playing ?
And am I correct in saying that you only need to discover that a single instance out of many is playing, in which case this is sufficient to prevent some other AppleScript from executing ? Or, put another way, that other AppleScript will execute if and only if no instance of VLC is playing ?
I believe that's achievable. Although we can't use the playing property of the VLC application object, we can use properties/attributes of VLC processes/windows to determine whether or not each instance of VLC is playing.
tell application "System Events"
set _W to a reference to window 1 of (every process whose name is "VLC")
set _title to the value of attribute "AXTitle" of _W
end tell
That is literally all you need, as the AXTitle attribute returns very predictable data depending on the state of VLC:
▸ If VLC is playing and NOT fullscreen: _title evaluates to a non-empty string (specifically, it contains the name of the video file or the path to the internet stream).
▸ If VLC is NOT playing: _title evaluates to "VLC media player".
▸ If VLC is playing and IS fullscreen: _title evaluates to an empty string ("").
Therefore:
If _title = "VLC media player", then VLC is not playing; otherwise, VLC is playing.
Utilising this fact, in order for your other AppleScript to be allowed to execute, we want every _title value representing each instance of VLC to be equal to "VLC media player". If there is even one value in _title that is anything other than that, then the assertion fails and the script can terminate, or do whatever it needs to do to prevent the execution of some other script.
I chose to simply count the number of attributes returned with the name "AXTitle" and a value other than "VLC media player". The number returned is equal to the number of VLC instances currently playing:
tell application "System Events" to count ¬
(the attributes of window 1 of ¬
(every process whose name is "VLC") whose ¬
name is "AXTitle" and ¬
value is not "VLC media player")
if result is not 0 then return