Variable.1 unexpected at this time - windows

Question

I'm just trying to figure out why this block of code is giving me an unexpected variable..
#echo off
FOR /F "Skip=1Delims=" %%a IN (
'"wmic nic where (MacAddress="00:00:00:00:00:00") GET NetConnectionId"'
) DO FOR /F "Tokens=1" %%b IN ("%%a") DO SET nicName=%%b
echo Adding all IP ranges for X in 10.10.X.118 on adapter %nicName%
netsh interface ipv4 set address name=%nicName% static 192.168.1.118 255.255.255.0 192.168.1.1
FOR /L %A IN (0,1,255) DO netsh interface ipv4 add address %nicName% 10.10.%A%.118 255.255.255.0 10.10.%A%.1
netsh interface ipv4 add dnsserver %nicName% address=208.67.222.222 index=1
netsh interface ipv4 add dnsserver %nicName% address=208.67.220.220 index=2
exit
I think it has something to do with the first FOR loop interfering with the second, but I'm very new to using this type of search in a batch file.
The output I get is:
Adding all IP ranges for X in 10.10.X.118 on adapter Local Area Connection
nicNameAA.1 was unexpected at this time.
Thanks in advance!

Answer 1

FOR /L %A IN (0,1,255) DO netsh interface ipv4 add address %nicName% 10.10.%A%.118 255.255.255.0 10.10.%A%.1
As in the previous two for commands, the metavariable A must be specified as %%A.
As in the previous two for commands, the value substituted into the string must be specified as %%A - %A% is the value of an unspecified environment variable A.
The result of your code is this
FOR /L
%A IN (0,1,255) DO netsh interface ipv4 add address %
nicName
% 10.10.%
A
%.118 255.255.255.0 10.10.%
A
%.1
each %...% is interpreted as a non-existent environment variable, hence it's replaced by nothing
So the code appears to be
FOR /L nicNameAA%.1
So cmd sees nicNameAA%.1 where it's expecting %%? and complains.
BTW- since nicname's value contains spaces, you probably need "%nicname%" so that cmd will see one string. Can't vouch for it since I rarely use netsh...just be prepared.

Answer 2

As answered by #Magoo,
The resulting full code is as follows(In case anyone needs to do this in the future)
#echo off
FOR /F "Skip=1Delims=" %%a IN (
'"wmic nic where (MacAddress="00:00:00:00:00:00") GET NetConnectionId"'
) DO FOR /F "Tokens=1" %%b IN ("%%a") DO SET nicName=%%b
echo Adding all IP ranges for X in 10.10.X.118 on adapter "%nicName%"
netsh interface ipv4 set address name="%nicName%" static 192.168.1.118 255.255.255.0 192.168.1.1
FOR /L %%c IN (0,1,255) DO netsh interface ipv4 add address "%nicName%" 10.10.%%c.118 255.255.255.0 10.10.%%c.1
netsh interface ipv4 add dnsserver "%nicName%" address=208.67.222.222 index=1
netsh interface ipv4 add dnsserver "%nicName%" address=208.67.220.220 index=2
exit
Thanks again #Magoo!