PIC18 How to make the dot move on a 8x8 matrix display? - pic

Question

I am trying to make a dot move up and down an 8x8 matrix display of column RA1. I use switches on a microcontroller to make the dot to move Up(RB5) and Down (RB0). I have the dot start in the position 0x08. The code works fine but the dot moves down when both switches are on. I was thinking that something like XORWF would help? Any ideas?
#include "p18F4520.inc"
;:::::CONFIG::::::::::::::::::::::::
CONFIG OSC = HS
CONFIG PWRT = OFF
CONFIG WDT = OFF
CONFIG PBADEN = OFF
CONFIG LVP = OFF
org 0x000000
PORST GOTO MAIN
org 0x000020
;:::::DELAY:::::::::::::::::::::::::
IDSHORT equ 0x20
IDLONG equ 0x21
ED10MS CLRF IDSHORT
MOVLW 0XFF
MOVWF IDLONG
LDLOOP DECFSZ IDSHORT
GOTO LDLOOP
DECFSZ IDLONG
GOTO LDLOOP
RETURN
;:::::::::::::::::::::::::::::::::::
MAIN CLRF TRISD
CLRF PORTD
CLRF TRISA
CLRF PORTA
BCF PORTA,RA1
BSF PORTA,RA1
SETF TRISB
MOVLW 0X08
MOVWF PORTD
LOOP BSF PORTA,RA1
CALL ED10MS
BCF PORTA,RA1
BTFSS PORTB,RB0 ;CHECKS IF SWHITCH IS ON - MOVE DOWN IF TRUE
GOTO DOWN
BTFSS PORTB,RB5 ;CHECKS IF SWHITCH IS ON - MOVE UP IF TRUE
GOTO UP
GOTO LOOP
UP MOVLW 0X80
CPFSEQ PORTD,W ;CHECKS IF IT REACHED THE TOP
RLNCF PORTD
GOTO LOOP
DOWN MOVLW 0X01
CPFSEQ PORTD,W ;CHECKS ID IT REACHED THE BOTTOM
RRNCF PORTD
GOTO LOOP
END

Answer 1

You can copy the bits in the PORTB reg and use XORLW. If all your other bits on PORTB are zero, ignore the ANDLW. If not, clear the other bits (other than RB0 and RB5) by using the ANDLW line. In LOOP, replace your bit tests with this. Whenever your switches are either both off or both on, this code will simply fall through and loop. STATUS and Z should be defined in the INC file, but you'll define TEMP. Note, this will work on one "snapshot" of PORTB, if you will. And this maintains your use of GOTOs for UP and DOWN:
MOVF PORTB,W ; put PORTB bits in w
ANDLW b'00100001' ; clr unused bits
MOVWF TEMP ; save w in TEMP
XORLW 0X20 ; look for RB0 'on', RB5 'off'
BTFSC STATUS,Z ; if untrue, Z bit clr, skip
GOTO DOWN ; if true, goto DOWN
MOVF TEMP,W ; get saved copy of PORTB bits
XORLW 0X01 ; look for RB0 'off', RB5 'on'
BTFSC STATUS,Z ; if untrue, Z bit clr, skip
GOTO UP ; if true, goto UP
GOTO LOOP ; any other case, goto LOOP