How to allow an Applescript to be exited at any time - applescript

Question

I am trying to write a script which presses the "w" and "q" keys rapidly for a prolonged period (the purpose is to perform a repetitive activity in a game's practice mode).
I know next to nothing about Applescripts, but I was able to piece together the following which kind of gets the job done:
tell application "System Events"
delay 5
repeat with i from 1 to 50
delay 0.25
keystroke "w"
delay 0.25
keystroke "q"
end repeat
end tell
Basically I press "run", alt-tab to the game, and let the script run.
The problem is that I have no way to force-exit the script. I tried the recommendation here to use command+option+escape, but I can't manage to click "force quit" and it won't close.
I'm looking at the documentation for handlers, but I'm not sure exactly what I'm supposed to do. I don't want to close the game application, just stop the script.
Ideally, I could implement some sort of "on key pressed" listener that kills the Applescript.
edit with the suggestion in the comment I now have:
use sys : application "System Events"
use framework "Cocoa"
tell application "System Events"
delay 5
repeat with i from 1 to 50
delay 0.25
keystroke "w"
delay 0.25
keystroke "q"
if modifierKeydown() then exit repeat # Exit on keypresswq
end repeat
end tell
# Returns true if any of
# { function, control, option, command }
# are depressed; false otherwise
on modifierKeydown()
set __m to current application's ¬
NSEvent's modifierFlags() as any
return (__m > 262143)
end modifierKeydown
This raises:
error "System Events got an error: Can’t continue modifierKeydown." number -1708

Answer 1

Using my answer to a similar question, here's a semi-tailored solution to your specific situation:
use sys : application "System Events"
use framework "Cocoa"
# Bring your game window into focus
tell application "The Name of Your Game" to activate
# Might be needed if your game window takes a long time to
# enter focus. But if it's already running, it should be instant
# and this little loop won't be needed.
# repeat while process "The Name of Your Game" is not frontmost
# end
# Get frontmost window of the frontmost application
set P to a reference to (the first process whose frontmost is true)
set W to the front window of P
repeat with i from 1 to 50
# Terminate loop if the focus changes to another window
if the front window of P is not equal to W then exit repeat
delay 0.25
tell sys to keystroke "w"
delay 0.25
tell sys to keystroke "q"
if modifierKeydown() then exit repeat # Terminate loop if modifier key is pressed
end repeat
return
# Returns true if any of
# { function, control, option, command }
# are depressed; false otherwise
on modifierKeydown()
set __m to current application's ¬
NSEvent's modifierFlags() as any
return (__m > 262143)
end modifierKeydown