Oracle nested cursor with for loop - oracle

Question

I am trying to make this work but no matter what I do the od_total var is always empty. I just cannot make it work.
I am trying to run a cursor to get a list of ordersid and save it into o_id every loop. Then, I use the second cursor to use the value stored into o_id to do another query that stores the result into od_total. While o_id seems to be storing the values, od_total for some reason is always empty.
CREATE OR REPLACE PROCEDURE p_practicum2_practice IS
o_id CHAR(5);
od_total NUMBER := 0;
CURSOR ordersid IS
SELECT DISTINCT orderdetails.orderid FROM orderdetails
INNER JOIN orders ON orderdetails.orderid = orders.orderid
INNER JOIN customers ON orders.customerid = customers.customerid
WHERE orders.customerid = 'LILAS';
CURSOR total IS
SELECT SUM(unitprice*quantity) FROM orderdetails WHERE orderid = o_id;
BEGIN
OPEN ordersid;
OPEN total;
LOOP
FETCH ordersid INTO o_id;
EXIT WHEN ordersid%notfound;
LOOP
FETCH total INTO od_total;
EXIT WHEN total%notfound;
END LOOP;
dbms_output.put_line(o_id || ' ---- ' || od_total);
END LOOP;
CLOSE ordersid;
CLOSE total;
END;
this is what I get as result:
enter image description here

Answer 1

As far i could understand your question you wanted to display od_total for all od_id passed from cursor ordersid. You are not getting anything because od_id is not getting passed to your second cursor. Read the code below inline comments how to pass the argument to cursor.
CREATE OR REPLACE PROCEDURE p_practicum2_practice
IS
o_id CHAR(5);
od_total NUMBER := 0;
CURSOR ordersid
IS
SELECT DISTINCT orderdetails.orderid
FROM orderdetails
INNER JOIN orders
ON orderdetails.orderid = orders.orderid
INNER JOIN customers
ON orders.customerid = customers.customerid
WHERE orders.customerid = 'LILAS';
CURSOR total(v_oid char)
IS
SELECT SUM(unitprice*quantity)
FROM orderdetails
WHERE orderid = v_oid;
BEGIN
OPEN ordersid;
LOOP
FETCH ordersid INTO o_id;
EXIT WHEN ordersid%notfound;
OPEN total(o_id); --<--This is how you pass the paramater to your cursor
LOOP
FETCH total INTO od_total;
EXIT WHEN total%notfound;
dbms_output.put_line(o_id || ' ---- ' || od_total);
END LOOP;
CLOSE total;
--If you print here then only the last od_total value will be printed.
--dbms_output.put_line(o_id || ' ---- ' || od_total);
END LOOP;
CLOSE ordersid;
END;
Output:
17465 ---- 6
12345 ---- 3
14435 ---- 4
19045 ---- 6
19345 ---- 8