How to copy a file depending on file size comparison? - windows

Question

There are the subdirectories S and F containing files with the same names but different file sizes (< 2 MB).
I want to copy a file from S to F, exactly if the file from S is smaller than the file from F.
FOR /R %%F IN ( >>THE_FILES_IN_S<< ) DO (
set fileS="S/%%~nF"
FOR /F "usebackq" %%A IN ('%fileS%') DO set sizeS=%%~zA
set fileF="F/%%~nF"
FOR /F "usebackq" %%A IN ('%fileF%') DO set sizeF=%%~zA
if %sizeS% LSS %sizeF% (copy /V /Y %fileS% %fileF%)
)
The code above
does not work because >>THE_FILES_IN_S<< is pseudo-code.
What is the right expression?
Are there other mistakes (and what is the correct form)?

Answer 1

The 32bit signed integer size limitation of ~2GB does not apply
when comparing numbers in strings left padded with zeroes to equal length.
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "BaseFolder=C:\Temp"
for %%S in ("%BaseFolder%\S\*") do (
if exist "%BaseFolder%\F\%%~nxS" (
for %%F in ("%BaseFolder%\F\%%~nxS"
) do Call :Check %%~zS %%~zF || copy /Y "%%S" "%%F" >nul
)
)
endlocal
Goto :Eof
:Check
Set "S=00000000000000000000%1"
Set "F=00000000000000000000%2"
If %S:~-20% LSS %F:~-20% exit /B 1
The above batch avoids delayed expansion by passing the sizes to a subroutine and comparing strings with 20 decimal places returning an errorlevel on a less result to copy on this fail condition.

Answer 2

The usage of environment variables defined/modified within a command block and referenced in same command block would require the usage of delayed expansion. The help of command SET output on running in a command prompt window set /? explains usage of delayed expansion on an IF and a FOR example.
Best is avoiding usage of delayed expansion by using the loop variables directly instead of assigning their values to environment variables and next reference the values of the environment variables in a command block starting with ( and ending with matching ).
#echo off
setlocal EnableExtensions DisableDelayedExpansion
set "BaseFolder=C:\Temp"
for %%S in ("%BaseFolder%\S\*") do (
if exist "%BaseFolder%\F\%%~nxS" (
for %%F in ("%BaseFolder%\F\%%~nxS") do (
if %%~zS LSS %%~zF copy /Y "%%S" "%%F" >nul
)
)
)
endlocal
Replace C:\Temp in third line by real path to base folder. If the batch file is stored in base folder, the third line could be replaced by:
rem Base folder is the directory containing the batch file.
set "BaseFolder=%~dp0"
rem Remove the backslash at end from batch file path.
set "BaseFolder=%BaseFolder:~0,-1%"
The outer FOR searches for any non hidden file in subdirectory S of base folder matching the wildcard pattern * (any name) and assigns the full qualified file name to loop variable S.
If a file with same file name and file extension exists also in subdirectory F of base folder, one more FOR loop is executed which just assigns the already known full qualified file name of current file in subdirectory F to loop variable F and then runs one more IF comparison.
The inner IF compares with a 32-bit signed integer comparison the file sizes of the two files and copies a smaller file in subdirectory S to subdirectory F with suppressing the success message output by COPY to handle STDOUT by redirecting it to device NUL.
Please note that this batch file works only for files with less than 2 GiB because of 32-bit signed integer limitation of Windows command processor on processing integer values.
The entire batch code above could be written also as a single command line:
#for %%S in ("C:\Temp\S\*") do #if exist "C:\Temp\F\%%~nxS" for %%F in ("C:\Temp\F\%%~nxS") do #if %%~zS LSS %%~zF copy /Y "%%S" "%%F" >nul
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
call /? ... explains %~dp0 (drive and path of argument 0 – the batch file)
copy /?
echo /?
endlocal /? ... is not really needed here and could be removed.
for /?
if /?
rem /?
set /?
setlocal /? ... is not really needed here and could be removed.