VB Script for Automating File Creation (On-Demand Opportunity!) - vbscript

Question

I'm a Financial person and not quite the VB scripting guru, but I'm wondering if someone could create a sample vb script based on my requirements.
Whoever provides the solution first and the solution works on my end will have an opportunity (paid of course) to create more of these custom solutions where I work at. It wouldn't be full-time position, but more of an On-Demand opportunity.
Requirements:
To be able to read a text file that is delimited by comma and has various entries
For example, in text file...
SEC_E_All_Entities,HSII,SL_DIMENSION,READWRITE,#IDESCENDANTS,N
SEC_E_ENT_Americas,Americas,SL_DIMENSION,READ,MEMBER,N
And perform the following...
Create an XML file per entry, based on the first value
For example:
Create SEC_E_All_Entities.XML and SEC_E_ENT_Americas.XML
Within each file, write the contents where you can see how the values match each tag.
For example:
In the SEC_E_All_Entities.XML file, write...
<?xml version="1.0" encoding="UTF-8" ?>
<acls>
<acl>
<name>SEC_E_All_Entities</name>
<objectName>HSII</objectName>
<objectType>SL_DIMENSION</objectType>
<accessMode>READWRITE</accessMode>
<flag>#IDESCENDANTS</flag>
<isUser>N</isUser>
</acl>
</acls>
In the SEC_E_All_Americas.XML file, write...
<?xml version="1.0" encoding="UTF-8" ?>
<acls>
<acl>
<name>SEC_E_ENT_Americas</name>
<objectName>Americas</objectName>
<objectType>SL_DIMENSION</objectType>
<accessMode>READ</accessMode>
<flag>MEMBER</flag>
<isUser>N</isUser>
</acl>
</acls>
Regards,
Judy

Answer 1

Sample script
'Step 1 - Read the file and store the content in memory (an array)
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("C:\Users\pankaj.jaju\Desktop\StackOverflow\acls.txt", 1)
arrFile = Split(objFile.ReadAll, vbCrLf) 'will store one line in each array index
objFile.Close
'Step 2 - Load the XML template in memory
Set xmlTemplate = CreateObject("MSXML2.DOMDocument.6.0")
With xmlTemplate
.ValidateOnParse = True
.Async = False
.LoadXML "<?xml version=""1.0"" encoding=""UTF-8"" ?>" & _
"<acls>" & _
"<acl>" & _
"<name></name>" & _
"<objectName></objectName>" & _
"<objectType></objectType>" & _
"<accessMode></accessMode>" & _
"<flag></flag>" & _
"<isUser></isUser>" & _
"</acl>" & _
"</acls>"
End With
'Step 3 - Load the relevant fields for which the data is to be set from csv file
Set nodeFields = xmlTemplate.DocumentElement.SelectNodes("/acls/acl/*")
'Step 4 - Read each line of text and create XML
For i = LBound(arrFile) To UBound(arrFile)
arrLine = Split(arrFile(i), ",") 'will split the line into various fields (to be used to create the xml)
For j = LBound(arrLine) To UBound(arrLine) 'set values for each field
nodeFields(j).Text = arrLine(j)
Next
Set xmlNew = xmlTemplate
xmlNew.Save objFSO.BuildPath("C:\Users\pankaj.jaju\Desktop\StackOverflow\", nodeFields(0).Text & ".xml") 'copy modified template as new xml file
Set xmlNew = Nothing
Next