PictureBox scaling horrifically in VB6 - vb6

Question

I'm programming in Visual Basic 6.0 at the moment, just for fun.
I've come across an annoying issue that if I try and scale my pictures at all at runtime then it blurs and I can't read the text on the picture. If I scale it at design time then it scales just fine.
The picture is in 24-bit Bitmap file type, the same results come with using .gif or .jpeg also. VB6 doesn't handle PNG's as far as I'm aware. PictureBox's don't anyway.
Code for drawing at runtime: (correct aspect ratio)
Picture1.PaintPicture map, 0, 0, 700, 547
Can anyone tell me why this is happening or if I'm doing it wrong?
I realise VB6 is out-dated and not supported, but as I say I am using it for a fun project.
Design time quality:
Run time quality:
Run time quality in VS2017 (C#):

Answer 1

Here is a UserControl implementation that you can use instead of a PictureBox control that uses StretchBlt for better quality:
VERSION 5.00
Begin VB.UserControl ImageBox
ClientHeight = 648
ClientLeft = 0
ClientTop = 0
ClientWidth = 720
ClipControls = 0 'False
ForwardFocus = -1 'True
ScaleHeight = 54
ScaleMode = 3 'Pixel
ScaleWidth = 60
Begin VB.PictureBox picBuffer
AutoRedraw = -1 'True
AutoSize = -1 'True
BorderStyle = 0 'None
Height = 372
Left = 120
ScaleHeight = 31
ScaleMode = 3 'Pixel
ScaleWidth = 36
TabIndex = 0
Top = 120
Visible = 0 'False
Width = 432
End
End
Attribute VB_Name = "ImageBox"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
'###############################################################################
'#
'# ImageBox
'#
'###############################################################################
Option Explicit
'###############################################################################
'### Constants #################################################################
'###############################################################################
Private Const STRETCH_ANDSCANS = 1
Private Const STRETCH_DELETESCANS = 3
Private Const STRETCH_HALFTONE = 4
Private Const STRETCH_ORSCANS = 2
Private Const SRCCOPY = &HCC0020
'###############################################################################
'### APIs ######################################################################
'###############################################################################
Private Declare Function StretchBlt Lib "gdi32" (ByVal hdc As Long, _
ByVal x As Long, _
ByVal y As Long, _
ByVal nWidth As Long, _
ByVal nHeight As Long, _
ByVal hSrcDC As Long, _
ByVal xSrc As Long, _
ByVal ySrc As Long, _
ByVal nSrcWidth As Long, _
ByVal nSrcHeight As Long, _
ByVal dwRop As Long) _
As Long
Private Declare Function SetStretchBltMode Lib "gdi32" (ByVal hdc As Long, _
ByVal nStretchMode As Long) _
As Long
'###############################################################################
'### Data ######################################################################
'###############################################################################
'###############################################################################
'### Events ####################################################################
'###############################################################################
Event Click()
Event DblClick()
Event MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
Event MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
Event MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
'###############################################################################
'### Public Methods ############################################################
'###############################################################################
'*******************************************************************************
Public Property Get BackColor() As OLE_COLOR
Attribute BackColor.VB_Description = "Returns/sets the background color used to display text and graphics in an object."
BackColor = UserControl.BackColor
End Property
Public Property Let BackColor(ByVal New_BackColor As OLE_COLOR)
UserControl.BackColor() = New_BackColor
PropertyChanged "BackColor"
End Property
'*******************************************************************************
Public Property Get Enabled() As Boolean
Attribute Enabled.VB_Description = "Returns/sets a value that determines whether an object can respond to user-generated events."
Enabled = UserControl.Enabled
End Property
Public Property Let Enabled(ByVal New_Enabled As Boolean)
UserControl.Enabled() = New_Enabled
PropertyChanged "Enabled"
End Property
'*******************************************************************************
Public Property Get BorderStyle() As Integer
Attribute BorderStyle.VB_Description = "Returns/sets the border style for an object."
BorderStyle = UserControl.BorderStyle
End Property
Public Property Let BorderStyle(ByVal New_BorderStyle As Integer)
UserControl.BorderStyle() = New_BorderStyle
PropertyChanged "BorderStyle"
End Property
'*******************************************************************************
Public Sub Refresh()
Attribute Refresh.VB_Description = "Forces a complete repaint of a object."
Call UserControl.Refresh
End Sub
'*******************************************************************************
Public Property Get Picture() As Picture
Set Picture = picBuffer.Picture
End Property
Public Property Set Picture(ByVal New_Picture As Picture)
Set picBuffer.Picture = New_Picture
PropertyChanged "Picture"
Me.Refresh
End Property
'###############################################################################
'### GUI Events ################################################################
'###############################################################################
'*******************************************************************************
Private Sub UserControl_Click()
RaiseEvent Click
End Sub
'*******************************************************************************
Private Sub UserControl_DblClick()
RaiseEvent DblClick
End Sub
'*******************************************************************************
Private Sub UserControl_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
RaiseEvent MouseDown(Button, Shift, x, y)
End Sub
'*******************************************************************************
Private Sub UserControl_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
RaiseEvent MouseMove(Button, Shift, x, y)
End Sub
'*******************************************************************************
Private Sub UserControl_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
RaiseEvent MouseUp(Button, Shift, x, y)
End Sub
'*******************************************************************************
Private Sub UserControl_Paint()
Dim lSave As Long
'set the stretchblit mode (saving the previous value)
lSave = SetStretchBltMode(UserControl.hdc, STRETCH_HALFTONE)
'perform blit
Call StretchBlt(UserControl.hdc, 0, 0, UserControl.ScaleWidth, _
UserControl.ScaleHeight, picBuffer.hdc, 0, 0, _
picBuffer.ScaleWidth, picBuffer.ScaleHeight, SRCCOPY)
'restore previous mode
Call SetStretchBltMode(UserControl.hdc, lSave)
End Sub
'###############################################################################
'### UserControl Events ########################################################
'###############################################################################
'*******************************************************************************
' Initialize Properties for User Control
'*******************************************************************************
Private Sub UserControl_InitProperties()
'Set any defaults that should be saved from design-time to run-time here
UserControl.Enabled = True
End Sub
'*******************************************************************************
' Load property values from storage
'*******************************************************************************
Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
'Set any values that were saved from design-time to run-time
UserControl.BackColor = PropBag.ReadProperty("BackColor", &H8000000F)
UserControl.Enabled = PropBag.ReadProperty("Enabled", True)
UserControl.BackStyle = PropBag.ReadProperty("BackStyle", 1)
UserControl.BorderStyle = PropBag.ReadProperty("BorderStyle", 0)
Set Picture = PropBag.ReadProperty("Picture", Nothing)
End Sub
'*******************************************************************************
' Write property values to storage
'*******************************************************************************
Private Sub UserControl_WriteProperties(PropBag As PropertyBag)
'Store any values that should be saved from design-time to run-time here
Call PropBag.WriteProperty("BackColor", UserControl.BackColor, &H8000000F)
Call PropBag.WriteProperty("Enabled", UserControl.Enabled, True)
Call PropBag.WriteProperty("BackStyle", UserControl.BackStyle, 1)
Call PropBag.WriteProperty("BorderStyle", UserControl.BorderStyle, 0)
Call PropBag.WriteProperty("Picture", Picture, Nothing)
End Sub
'*******************************************************************************
' Terminate fires when the form unloads.
'*******************************************************************************
Private Sub UserControl_Terminate()
'
End Sub
'###############################################################################
'### Private Methods ###########################################################
'###############################################################################
'###############################################################################
'###############################################################################
'###############################################################################