Shortcut target path via VBScript [duplicate] - vbscript

Question

This question already has an answer here:
How to create shortcuts having two target
(1 answer)
Closed 4 years ago.
I am trying correct a shortcut target path for MS Access using a registry key and the file location on a network share.
App Path of MS Access via Registry:
C:\Program Files\Microsoft Office 15\Root\Office 15\MSACCESS.EXE
Network location of Database:
\\H00t0000vfsrv03\Share\Folder\Database.MDB
I can not get shortcut path to take, gives me
Invalid procedure call or argument, 800A0005.
Code:
Set WSHShell = CreateObject("WScript.Shell")
ServerPath = Chr(32) & "\\H00t0000vfsrv03\Share\Folder\Database.MDB"
If Not WSHShell Is Nothing Then
DesktopPath = WSHShell.SpecialFolders("Desktop")
InstallRoot = Chr(34) & WSHShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\MSACCESS.EXE\") & Chr(34)
TargetName = InstallRoot & ServerPath
WScript.Echo TargetName
CommandName = TargetName
wscript.echo CommandName
Set MyShortcut = WSHShell.CreateShortCut(DesktopPath & "\Shorcut" & ".lnk")
MyShortcut.TargetPath = TargetName
WScript.Echo MyShortcut.TargetPath
MyShortcut.WindowStyle = 1
MyShortcut.Arguments = ""
MyShortcut.Save
Set MyShortcut = Nothing
End If
I have added
shortcut.Targetpath = """C:\Program Files\Microsoft Office 15\Root\Office 15\MSACCESS.EXE"" H00t0000vfsrv03\Share\Folder\Database.MDB"
and this last line does not work. The App Path can vary depending on the MS Access Office version. Trying to get the correct number of double quotes so that the shortcut can be mapped.

Answer 1

Although the .MDB extension is probably associated to MsAccess, I understand you want a shortcut to explicitely use the installed MsAccess.exe to avoid getting into trouble where a user has changed this to some other application.
When creating a shortcut like this, you need to fill in the correct values for the different properties.
The shortcuts TargetPath should be "C:\Program Files\Microsoft Office 15\Root\Office 15\MSACCESS.EXE"
The shortcuts Arguments should be "\\H00t0000vfsrv03\Share\Folder\Database.MDB"
As you are doing it now, you are trying to set the TargetPath to
"C:\PROGRA~2\MICROS~1\Office15\MSACCESS.EXE" \\H00t0000vfsrv03\Share\Folder\Database.MDB
Try this
Option Explicit
Dim WSHShell
Set WSHShell = CreateObject("WScript.Shell")
If Not WSHShell Is Nothing Then
Dim ServerPath, DesktopPath, InstallRoot, MyShortcut
ServerPath = Chr(34) & "\\H00t0000vfsrv03\Share\Folder\Database.MDB" & Chr(34)
DesktopPath = WSHShell.SpecialFolders("Desktop")
'get the long path for MSACCESS.EXE
InstallRoot = WSHShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\MSACCESS.EXE\Path")
'there SHOULD be a backslash at the end, but check anyway
If Right(InstallRoot, 1) <> "\" Then InstallRoot = InstallRoot & "\"
'add "MSACCESS.EXE" to this path and surround with double quotes
InstallRoot = Chr(34) & InstallRoot & "MSACCESS.EXE" & Chr(34)
'create the shortcut on the desktop
Set MyShortcut = WSHShell.CreateShortCut(DesktopPath & "\ShorcutToDatabase" & ".lnk")
MyShortcut.TargetPath = InstallRoot
MyShortcut.WindowStyle = 1
MyShortcut.Arguments = ServerPath
MyShortcut.Save
Set MyShortcut = Nothing
Set WSHShell = Nothing
End if