printing to file only prints last line - processing

Question

I'm creating a program in Processing.js to help me make color ramps for pixel art. The ramp generator works, so now I need the program to convert the HSV colors I'm working in to RGB so I can input them into the program I'm using (it doesn't allow me to use the HSV color space for some reason, but I'm ok with that because I'm comfortable with this program).
Here's the function that's causing problems
void convert(float h,float s,float v){
// h will be 0-360, s and v are 0-100
PrintWriter output;
output = createWriter("value.txt");
float S = s/100;
float V = v/100;
//the conversion algorithm I found expects s and v to be 0-1
float c = S*V;
float x = c*(1-abs(((h/60)%2)-1));
float e = V-c;
float R = 0.0;
float G = 0.0;
float B = 0.0;
if(0 <= h && h <= 60) {
R = c;
G = x;
B = 0;
} else if(60 <= h && h <= 120) {
R = x;
G = c;
B = 0;
} else if(120 <= h && h <= 180) {
R = 0;
G = c;
B = x;
} else if(180 <= h && h <= 240) {
R = 0;
G = x;
B = c;
} else if(240 <= h && h <= 300){
R = x;
G = 0;
B = c;
} else if(300 <= h && h <= 360) {
R = c;
G = 0;
B = x;
} else {
}
float r = R + e;
float g = G + e;
float b = B + e;
println(round(r*255)+","+round(g*255)+","+round(b*255));
output.println(round(r*255)+","+round(g*255)+","+round(b*255));
output.flush();
output.close();
}
The println that doesn't write to the file displays just fine in the console, but output.println only writes the last line to the file. I'm expecting 220 lines of output. If needed I can edit the question to have the rest of the code, but this is the only function that's causing problems right now. Here's the source for the conversion algorithm I'm using.

Answer 1

In the future, please try to narrow your problem down to a MCVE like this:
void draw() {
point(mouseX, mouseY);
PrintWriter output = createWriter("positions.txt");
output.println(mouseX);
output.flush();
output.close();
}
This program shows the same problem you're having, but it's much easier to work with.
The problem is that you're creating a new PrintWriter every frame. Instead, you need to create it once at the beginning and continually write to it as your program runs.
From the reference:
PrintWriter output;
void setup() {
// Create a new file in the sketch directory
output = createWriter("positions.txt");
}
void draw() {
point(mouseX, mouseY);
output.println(mouseX); // Write the coordinate to the file
}
void keyPressed() {
output.flush(); // Writes the remaining data to the file
output.close(); // Finishes the file
exit(); // Stops the program
}