A Vbscript question re filesystem detection output to Variable? (OS XPHome NTFS) - vbscript

Question

I am hoping that someone with Vbscripting experience will be able to help me with a Vbscript (My OS is XP Home with NTFS filesystem please I cannot use WMI within the Vbs code due to OS)
I have looked on the w.w.w & found two snippets of VBscript that will (1) find the current filesystem on C:\ (%systemdrive%) drive & the second snippet of code will identify the OS fileSystem however I am really wanting to combine the two parts of the code & (2) the output would preferably be a variable not a msgbox to be acquired later in a batch file. The code snippets are as follows.
set shell = createobject("wscript.shell")
set environ = shell.environment("process")
systemdrive = environ("systemdrive")
msgbox systemdrive
set fso = CreateObject("Scripting.FileSystemObject")
set drive = fso.GetDrive("C")
Wscript.Echo "FileSystem =", drive.FileSystem
The first set of code creates a variable called systemdrive & outputs to a message box. The second (within a message box) outputs the "Filesystem" in my case "NTFS".
My question is when I interchange the systemdrive info into the line
set drive = fso.GetDrive("C") - like so set drive = fso.GetDrive("systemdrive") instead of ("C")
I get error code messages. Also instead of a message box output I am looking for a %variable% output instead e.g. "FAT32, NTFS or whatever". I hope what I am trying to convey makes sense? In essence I am trying to use the systemdrive variable usually "C:" instead of the hard coded c: path find the OS filesystem & output that only to a variable?

Answer 1

From what I understand you want to detect the filesystem of a drive and store it in an environment variable for later use in a batch file.
This would mean you are planning to call the VBScript from within that batch file and can use the batch file to resolve any environment variables such as %SYSTEMDRIVE%, and there is no need to do that from within the VBS file (which would be possible, but it's going to be more flexible when we can pass in the drive letter as a parameter to the script).
Let's make a VBS that accepts one argument and looks up the filesystem type, if it can.
Option Explicit
Dim shell, fso, drive, driveletter
' we expect a single argument - a drive letter in the form X:
If WScript.Arguments.Unnamed.Count = 0 Then Die "Please specify drive letter."
driveletter = WScript.Arguments.Unnamed(0)
Set shell = CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
' try to get the drive object for that drive letter, die on error
On Error Resume Next
Set drive = fso.GetDrive(driveletter)
If Err.Number <> 0 Then Die "Could not detect filesystem type for " + driveletter + " (" + Err.Description + ")"
Wscript.StdOut.Write drive.FileSystem
Sub Die(message)
WScript.StdErr.WriteLine message
WScript.Quit 1
End Sub
Now this can be called stand-alone (for command line purposes, use the command line script interpreter, cscript.exe):
cscript /nologo filesystem.vbs %SYSTEMDRIVE%
Or it can be called from a Batch file (we'll use a for loop to assign the script's output to a variable):
#echo off
for /f "usebackq delims=" %%s in (`cscript /nologo filesystem.vbs %SYSTEMDRIVE%`) do (
set FILESYSTEM=%%s
)
echo The filesystem in %SYSTEMDRIVE% is %FILESYSTEM%.
The above prints this for me:
The filesystem in C: is NTFS.