Jenkins pipeline usage without chaining the jobs - jenkins-pipeline

Question

I want to get a chained job from start to the end. But these jobs are also needed for separate execution.
I want a scheduled build and need those jobs chained.
When running manually, not running the Jobs in cascaded mode.
I don't want to click configure, remove downstream run and re-add the downstream in case of manual execution.
What is the best solution for this?
Thanks in advance.

Answer 1

So this can be done, however I do recommend putting the functions I have outlined below in a Jenkins Shared Library. Doing it this way will cause at least 4 sandbox security approvals, which will require your jenkins administrator to approve. 1 of which warns it is a security vulnerability.... so assess the impact for your environment and your risk profile.
#!groovy
List jobparameters = [
booleanParam(name: 'CHECKBOX', defaultValue: true, description: 'Tick a checkbox'),
string(name: 'STRING', defaultValue: 'stringhere', description: 'Enter a string')
]
properties([
pipelineTriggers([cron('''TZ=Australia/Victoria
H 1 * * *''')]),
buildDiscarder(logRotator(numToKeepStr: '20')),
parameters(jobparameters),
])
stage('Stage') {
node {
// do something always
echo(params.STRING)
}
}
if ( hasAutomatedCauses() ) {
stage('folder1/reponame/branch') {
//do something conditionally
build(job: "folder1/reponame/branch", parameters: jobparameters, propagate: true)
}
} else {
stage('folder1/reponame/branch') {
node {
echo("Not running downstream job")
}
}
}
/**
* Checks if job causes contain automated causes
* Return true if automated cause found
*
* #return boolean
*/
boolean hasAutomatedCauses() {
List automatedCauses = ['UpstreamCause', 'TimerTriggerCause']
List intersection = []
intersection = automatedCauses.intersect(getCauses())
// if no automated causes are found means intersection is empty and then return false
return !intersection.isEmpty()
}
/**
* Retrieves list of causes that generated job execution
*
* #return list
*/
List getCauses() {
return currentBuild.rawBuild.getCauses().collect { it.getClass().getCanonicalName().tokenize('.').last() }
}