Create list of available times (availability calendar) using Applescript - applescript

Question

I am trying to create an availability calendar using applescript for my mac. This would query application "Calendar", get all events for the day (ideally would like it to be for multiple days), and then give me the times between the events so that I can send that via email, chat, etc.
I've gotten as far as being able to find events, but haven't been able to find the "inverse" times of the events.
set hours of theStartDate to 0
set minutes of theStartDate to 0
set seconds of theStartDate to 0
set theEndDate to theStartDate + (1 * days) - 1
tell application "Calendar"
tell calendar "GENERIC CALENDAR"
every event where its start date is greater than or equal to theStartDate and end date is less than or equal to theEndDate
end tell
end tell

Answer 1

This is an approach which creates the range (startDate/endDate) and then populates a list with available start/end date pairs
-- set startDate and endDate to todays's midnight and tomorrow's midnight
tell (current date) to set startDate to it - (its time)
set endDate to startDate + 86400
-- availableTimes is the result which contains a list of startDate/endDate pairs
set availableTimes to {}
-- temporary variable which is set to the current start date
set currentStartDate to startDate
tell application "Calendar"
tell calendar "GENERIC CALENDAR"
set todaysEvents to every event where its start date ≥ startDate and end date ≤ endDate
repeat with anEvent in todaysEvents
set end of availableTimes to {currentStartDate, anEvent's start date}
set currentStartDate to anEvent's end date
end repeat
set end of availableTimes to {currentStartDate, endDate}
end tell
end tell

Answer 2

The start and end times of each event can be expressed as an interval comprised of two integer values, each representing the number of minutes since midnight between which you are unavailable. These intervals are then simply numbers on a number line between 0 and 1440 (the number of minutes in a day), which are easy to invert and convert back to dates to obtain your availability.
use application "Calendar"
use scripting additions
property calendar : a reference to calendar "GENERIC CALENDAR"
--------------------------------------------------------------------------------
tell (current date) to set midnight to (it - (its time))
set _E to a reference to (events of my calendar ¬
whose start date ≥ midnight and ¬
end date ≤ (midnight + 1 * days))
set {|d₁|, |d₂|} to {start date, end date} of _E
repeat with i from 1 to length of |d₁|
set |t₁| to (a reference to item i of |d₁|)
set |t₂| to (a reference to item i of |d₂|)
set |t₁|'s contents to (|t₁| - midnight) / minutes
set |t₂|'s contents to (|t₂| - midnight) / minutes
end repeat
set ranges to flatten({0, transpose(|d₁|, |d₂|), days / minutes})
set availability to {}
repeat with i from 1 to length of ranges by 2
set {|t₁|, |t₂|} to {item i, item (i + 1)} of ranges
set end of availability to {¬
midnight + |t₁| * minutes, ¬
midnight + |t₂| * minutes}
end repeat
return availability
--------------------------------------------------------------------------------
# HANDLERS:
to transpose(A, B)
local A, B
tell {}
repeat with i from 1 to A's length
set its end to {item i of A, item i of B}
end repeat
it
end tell
end transpose
to flatten(L)
local L
if L = {} then return {}
if L's class ≠ list then return {L}
flatten(L's first item) & flatten(rest of L)
end flatten
---------------------------------------------------------------------------❮END❯