How to access submenu item under subheading group with AppleScript - applescript

Question

I can't access the "library-test" submenu item (see screenshot). My guess is that it has to do with the fact that the item is grouped/offset from the other items in the menu with the "Symbols" heading.
I tried treating "Symbols" as its own menu item and that didn't work.
Has anyone run into this before? Thanks!
AppleScript:
tell application "System Events"
tell process "Sketch"
set frontmost to true
click menu item "Rectangle" of menu of menu item "library-test" of menu "Insert" of menu bar 1
end tell
end tell
Error message in Script Editor:
"Can’t get menu item "library-test" of menu "Insert" of menu bar 1 of process "Sketch".
Edit: UI Browser Screen Reader tool suggests that the path is correct:

Answer 1

I'm afraid it's bad news: I just downloaded Sketch and had a play around with the menu hierarchy. Your reference is correct, but it appears it's only valid for a short amount of time after the menu closes. For whatever reason, Sketch seems to hot load particular menu items on the fly, and unload them again when the menu is closed.
I obviously don't have your exist menu combinations, because I don't have those particular symbols, but here's one that you're probably familiar with:
menu item "Document" of menu "Insert" of menu bar item "Insert" of menu bar 1 of process "Sketch"
I had the menu open initially, and then closed it to go into Script Editor and bash out that menu item reference. It worked fine, and I got a bunch of properties and attribute names for it:
{UIProperties:{minimum value:missing value ¬
, orientation:missing value, position:{195, 264} ¬
, class:menu item, accessibility description:missing value ¬
, role description:"menu item", focused:missing value ¬
, title:"Document", size:{173, 19}, help:missing value ¬
, entire contents:{}, enabled:true, maximum value:missing value ¬
, role:"AXMenuItem", value:missing value, subrole:missing value ¬
, selected:true, name:"Document", description:"menu item"} ¬
, UIAttributes:{"AXEnabled", "AXFrame", "AXParent", "AXChildren", ¬
"AXSize", "AXMenuItemCmdGlyph", "AXRole", "AXMenuItemPrimaryUIElement", ¬
"AXServesAsTitleForUIElements", "AXMenuItemCmdModifiers", "AXPosition", ¬
"AXTitle", "AXHelp", "AXMenuItemCmdChar", "AXRoleDescription", ¬
"AXSelected", "AXMenuItemCmdVirtualKey", "AXMenuItemMarkChar"} ¬
, UIActions:{"AXCancel", "AXPress"}}
About 20-30 seconds later, the exact same menu item reference threw an error, reporting that menu item "Document" wasn't found. So I ran this:
name of menu items of menu "Insert" of menu bar item "Insert" of menu bar 1 of process "Sketch"
You can probably infer that this will return the names of all the menu items within the "Insert" menu, and one would expect "Document" to be in there:
{"New Page", missing value, "Shape", "Vector", "Pencil", missing value, "Text", ¬
"Image…", missing value, "Artboard", "Slice", "Hotspot", missing value, missing value}
Nope. For comparison, here's what the menu looks like on screen:
The missing value items are fine—they correspond to a horizontal divider, except the last one, which corresponds to the "Symbol" sub-section header. What's curious is that the list terminates there; there's not even a placeholder for the additional menu items that literally do not exist an anymore (until I open the menu back up again).
I would guess that the only way to get access to menu items like that is to have your script click the menu to open it up, then click the menu item, and so on... Very inelegant, and I personally would rather throw my computer into the sun than do that, but I don't see another option here.
The application is apparently scriptable, but it doesn't come with a terminology dictionary, so there's not a lot we can do there, either.

Answer 2

A peculiarity of AppleScript GUI scripting is that elements of objects are always a to-many relationship, even when we might naturally presume a to-one relationship. You and I know that a menu item can only have one menu attached to it, but AppleScript doesn't, so we still have to specify an index for the menu. Things should work correctly if you write:
click menu item "Rectangle" of menu 1 of menu item "library-test" [...]

Answer 3

There may be some strange character in the menu name, such as a soft hyphen, non-breaking hyphen, non-breaking space, etc. One solution would be to try to get the particular menu item by its index, whatever the name is. A handler to do that would be something like:
on run -- example
clickMenu at {"Sketch", "Insert", 18, "Rectangle"}
end run
to clickMenu at menuList -- {application, menu, menu/item/index, menu/item/index, ...}
try
set itemCount to (count menuList)
if itemCount < 3 then error "clickMenu handler: menu item list contains too few items"
set {appName, menuName} to items 1 thru 2 of menuList
set {menuItem, found} to {last item of menuList, false}
tell application appName to activate
tell application "System Events" -- set up the menu path
set appName to (name of application processes whose frontmost is true) as text -- process name might be different
set menuPath to menu menuName of menu bar item menuName of menu bar 1 of application process appName
if itemCount > 3 then repeat with i from 3 to (itemCount - 1) -- add sub menu items
set menuName to item i of menuList
if class of menuName is integer then set menuName to item menuName of (get name of menu items of menuPath)
set menuPath to menu menuName of menu item menuName of menuPath
end repeat
if class of menuItem is not integer then -- go for a a partial name match of the last item
repeat with anItem in (get name of menu items of menuPath)
if anItem begins with menuItem then -- can also use 'contains', etc
set {menuItem, found} to {anItem, true}
exit repeat
end if
end repeat
if not found then error "clickMenu handler: menu item " & quoted form of menuItem & " not found"
end if
if (enabled of menu item menuItem of menuPath) then -- or filter for other desired property
click menu item menuItem of menuPath
delay 0.5
return true -- success
end if
return false -- menu item not clicked
end tell
on error errorMessage number errorNumber
-- error errorMessage number errorNumber -- uncomment to pass error up the chain
log errorMessage
return false
end try
end clickMenu