Need help creating/using variables in Oracle PL/SQL - oracle

Question

I just have a simple code and I hope a simple solution. I just want to create a variable in oracle and use it later on. I'm getting errors about needing a into clause or asking me to enter binds. I've been messing with this for 2 days now. Can someone please explain.
DECLARE
BEGIN_DATE VARCHAR2 (20) := '12/31/2017';
END_DATE VARCHAR2 (20) := '01/01/2019';
BEGIN
SELECT
STATUS
, EQUIPMENT_ID "Eq_ID"
FROM CYNFLEET.V_EQUIPMENT_INFO
WHERE
1=1
AND STATUS Not In ('T','N')
AND SOLD_DATE BETWEEN TO_DATE(:BEGIN_DATE, 'MM/DD/YYYY') AND TO_DATE(:END_DATE, 'MM/DD/YYYY')
AND IN_SERVICE_DATE < TO_DATE(:BEGIN_DATE, 'MM/DD/YYYY') OR STATUS Not In ('T','N')
AND SOLD_DATE Is Null
AND IN_SERVICE_DATE < TO_DATE(:END_DATE, 'MM/DD/YYYY');
END;
Error starting at line : 1 in command -
Error report -
ORA-06550: line 7, column 1:
PLS-00428: an INTO clause is expected in this SELECT statement
06550. 00000 - "line %s, column %s:\n%s"
*Cause: Usually a PL/SQL compilation error.
*Action:

Answer 1

You need stock the result of your selection in a variable with INTO clause.
DECLARE
BEGIN_DATE VARCHAR2 (20) := '12/31/2017';
END_DATE VARCHAR2 (20) := '01/01/2019';
VAR1 varchar2(100);
VAR2 VARCHAR2(100);
BEGIN
SELECT
STATUS
, EQUIPMENT_ID "Eq_ID"
INTO VAR1, VAR2
FROM CYNFLEET.V_EQUIPMENT_INFO
WHERE
1=1
AND STATUS Not In ('T','N')
AND SOLD_DATE BETWEEN TO_DATE(:BEGIN_DATE, 'MM/DD/YYYY') AND TO_DATE(:END_DATE,
'MM/DD/YYYY')
AND IN_SERVICE_DATE < TO_DATE(:BEGIN_DATE, 'MM/DD/YYYY') OR STATUS Not In ('T','N')
AND SOLD_DATE Is Null
AND IN_SERVICE_DATE < TO_DATE(:END_DATE, 'MM/DD/YYYY') AND ROWNUM <= 1;
END;
But this works when the selection returns one column, if you need more columns, your variable must be a table type.

Answer 2

The error you have shown is fairly select-explanatory; as shown in the documentation, you need to select into something - which is what the error says. You will need to declare additional variables to accept the query results; but only if your query returns a single row. If it returns multiple rows you will need to select into a collection, or use a cursor and iterate over those results.
You will get messages about bind variables because... you are using bind variables in your query. You should not prefix local PL/SQL variables with a colon. Bind variables are set by the client, not within the PL/SQL block.
DECLARE
BEGIN_DATE VARCHAR2 (20) := '12/31/2017';
END_DATE VARCHAR2 (20) := '01/01/2019';
BEGIN
FOR rec IN (
SELECT
STATUS
, EQUIPMENT_ID "Eq_ID"
FROM CYNFLEET.V_EQUIPMENT_INFO
WHERE
1=1
AND STATUS Not In ('T','N')
AND SOLD_DATE BETWEEN TO_DATE(BEGIN_DATE, 'MM/DD/YYYY') AND TO_DATE(END_DATE, 'MM/DD/YYYY')
AND IN_SERVICE_DATE < TO_DATE(BEGIN_DATE, 'MM/DD/YYYY') OR STATUS Not In ('T','N')
AND SOLD_DATE Is Null
AND IN_SERVICE_DATE < TO_DATE(END_DATE, 'MM/DD/YYYY')
)
LOOP
-- do some thing with each row's rec.status and rec."Eq_ID"
dbms_output.put_line('Got status ' || rec.status || ' for ' || rec."Eq_ID");
END LOOP;
END;
/
Or with date-type variables and literal values:
DECLARE
BEGIN_DATE DATE := DATE '2017-12-31';
END_DATE DATE := DATE '2019-01-01';
BEGIN
FOR rec IN (
SELECT
STATUS
, EQUIPMENT_ID "Eq_ID"
FROM CYNFLEET.V_EQUIPMENT_INFO
WHERE
1=1
AND STATUS Not In ('T','N')
AND SOLD_DATE BETWEEN BEGIN_DATE AND END_DATE
AND IN_SERVICE_DATE < BEGIN_DATE OR STATUS Not In ('T','N')
AND SOLD_DATE Is Null
AND IN_SERVICE_DATE < END_DATE
)
LOOP
-- do some thing with each row's rec.status and rec."Eq_ID"
dbms_output.put_line('Got status ' || rec.status || ' for ' || rec."Eq_ID");
END LOOP;
END;
/
You need to be careful as between is inclusive; given your values you might actually want:
AND SOLD_DATE > BEGIN_DATE
AND SOLD_DATE < END_DATE
though it's hard to tell. As dates include times it would be more common on set your begin date to the first date you want information from (not, as it appears, the day before) and then use SOLD_DATE >= BEGIN_DATE.
You also need to be careful about operator precedence and evaluation order, as you are mixing and and or. It's better to be explicit about which bits of logic are tied together; it looks like you might want:
AND STATUS Not In ('T','N')
AND (
(
SOLD_DATE > BEGIN_DATE
AND SOLD_DATE < END_DATE
AND IN_SERVICE_DATE < BEGIN_DATE
)
OR
(
SOLD_DATE Is Null
AND IN_SERVICE_DATE < END_DATE
)
)
If you did actually want to use bind variables and just display the output then you would set those in your client and use plain SQL; e.g. in SQL*Plus, SQL Developer, SQLcl and possibly others:
-- client variables
var BEGIN_DATE VARCHAR2(10);
var END_DATE VARCHAR2(10);
-- set variables via a PL/SQL block
BEGIN
BEGIN_DATE := '2017-12-31';
END_DATE := '2019-01-01';
END;
/
-- plain SQL query
SELECT
STATUS
, EQUIPMENT_ID "Eq_ID"
FROM CYNFLEET.V_EQUIPMENT_INFO
WHERE
1=1
AND STATUS Not In ('T','N')
AND STATUS Not In ('T','N')
AND (
(
SOLD_DATE > TO_DATE(:BEGIN_DATE, 'YYYY-MM-DD')
AND SOLD_DATE < TO_DATE(:END_DATE, 'YYYY-MM-DD')
AND IN_SERVICE_DATE < TO_DATE(:BEGIN_DATE, 'YYYY-MM-DD')
)
OR
(
SOLD_DATE Is Null
AND IN_SERVICE_DATE < TO_DATE(:END_DATE, 'YYYY-MM-DD')
)
);
Now those variable references in the query are actually bind variables, so they do have the colon prefix.

Answer 3

You declare and use variables like this:
declare
someVar varchar2(20) := 'Hello, world!';
begin
dbms_output.put_line(someVar);
end;
You populate variables from a query using
select a, b, c into x, y, z
from ...
where x, y and z are variables.